HelpSource/Classes/AllpassN.schelp

   1 class:: AllpassN
   2 summary:: All pass delay line with no interpolation.
   3 related:: Classes/AllpassC, Classes/AllpassL, Classes/BufAllpassN
   4 categories::  UGens>Delays
   5
   6
   7 Description::
   8
   9 All pass delay line with no interpolation. See also
  10 link::Classes/AllpassL::  which uses linear interpolation, and
  11 link::Classes/AllpassC::  which uses cubic interpolation.
  12 Cubic interpolation is more computationally expensive than linear,
  13 but more accurate.
  14
  15
  16 classmethods::
  17
  18 method::ar, kr
  19
  20 argument::in
  21 The input signal.
  22
  23 argument::maxdelaytime
  24 The maximum delay time in seconds. Used to initialize the delay buffer size.
  25
  26 argument::delaytime
  27 Delay time in seconds.
  28
  29 argument::decaytime
  30 Time for the echoes to decay by 60 decibels. If this time is negative then the feedback coefficient will be negative, thus emphasizing only odd harmonics at an octave lower.
  31
  32 argument::mul
  33 Output will be multiplied by this value.
  34
  35 argument::add
  36 This value will be added to the output.
  37
  38 Examples::
  39
  40 code::
  41
  42 // Since the allpass delay has no audible effect as a resonator on
  43 // steady state sound ...
  44
  45 { AllpassC.ar(WhiteNoise.ar(0.1), 0.01, XLine.kr(0.0001, 0.01, 20), 0.2) }.play;
  46
  47 // ...these examples add the input to the effected sound and compare variants so that you can hear
  48 // the effect of the phase comb:
  49
  50 (
  51 {
  52         z = WhiteNoise.ar(0.2);
  53         z + AllpassN.ar(z, 0.01, XLine.kr(0.0001, 0.01, 20), 0.2)
  54 }.play)
  55
  56 (
  57 {
  58         z = WhiteNoise.ar(0.2);
  59         z + AllpassL.ar(z, 0.01, XLine.kr(0.0001, 0.01, 20), 0.2)
  60 }.play)
  61
  62 (
  63 {
  64         z = WhiteNoise.ar(0.2);
  65         z + AllpassC.ar(z, 0.01, XLine.kr(0.0001, 0.01, 20), 0.2)
  66 }.play)
  67
  68 // used as an echo - doesn't really sound different than Comb,
  69 // but it outputs the input signal immediately (inverted) and the echoes
  70 // are lower in amplitude.
  71 { AllpassN.ar(Decay.ar(Dust.ar(1,0.5), 0.2, WhiteNoise.ar), 0.2, 0.2, 3) }.play;
  72
  73 ::
  74