HelpSource/Classes/PV_ConformalMap.schelp

   1 class:: PV_ConformalMap
   2 summary:: Complex plane attack.
   3 related:: Classes/FFT, Classes/IFFT
   4 categories:: UGens>FFT
   5
   6 Description::
   7
   8 Applies the conformal mapping
   9
  10 formula::
  11
  12 z → (z - a) / (1 - za*)
  13
  14 ::
  15
  16 to the phase vocoder bins z with a given by the real and imag imputs to
  17 the UGen.
  18
  19
  20 Makes a transformation of the complex plane so the output is full of
  21 phase vocoder artifacts but may be musically fun. Usually keep
  22
  23 formula::
  24 |a| < 1
  25 ::
  26 but
  27 you can of course try bigger values to make it really noisy.
  28
  29 formula::
  30 a = 0
  31 ::
  32 should
  33 give back the input mostly unperturbed.
  34
  35
  36 See  link::http://mathworld.wolfram.com/ConformalMapping.html:: .
  37
  38
  39 classmethods::
  40
  41 method::new
  42
  43 argument::buffer
  44
  45 FFT buffer.
  46
  47
  48 argument::areal
  49
  50 Real part of a.
  51
  52
  53 argument::aimag
  54
  55 Imaginary part of a.
  56
  57
  58 Examples::
  59
  60 code::
  61
  62 //explore the effect
  63 (
  64 SynthDef("conformer1", {
  65         var in, chain;
  66         in = AudioIn.ar(1,0.5);
  67         chain = FFT(LocalBuf(1024), in);
  68         chain=PV_ConformalMap(chain, MouseX.kr(-1.0,1.0), MouseY.kr(-1.0,1.0));
  69         Out.ar(0, Pan2.ar(IFFT(chain),0));
  70 }).add;
  71 )
  72
  73 a = Synth("conformer1")
  74 a.free
  75
  76 (
  77 SynthDef("conformer2", {
  78         var in, chain, out;
  79         in = Mix.ar(LFSaw.ar(SinOsc.kr(Array.rand(3,0.1,0.5),0,10,[1,1.1,1.5,1.78,2.45,6.7]*220),0,0.3));
  80         chain = FFT(LocalBuf(2048), in);
  81         chain=PV_ConformalMap(chain, MouseX.kr(0.01,2.0, 'exponential'), MouseY.kr(0.01,10.0, 'exponential'));
  82         out=IFFT(chain);
  83
  84         Out.ar(0, Pan2.ar(CombN.ar(out, 0.1, 0.1, 10, 0.5, out), 0, 0.3));
  85 }).add;
  86 )
  87
  88 a = Synth("conformer2")
  89 a.free
  90 ::
  91