HelpSource/Classes/Convolution2L.schelp

   1 class:: Convolution2L
   2 summary:: Real-time convolver with linear interpolation
   3 related:: Classes/Convolution, Classes/Convolution2, Classes/Convolution3, Classes/StereoConvolution2L
   4 categories::  UGens>FFT, UGens>Convolution
   5
   6 Description::
   7 Strict convolution with fixed kernel which can be updated using a trigger signal. There is a linear crossfade between the buffers upon change.
   8
   9 See emphasis:: Steven W Smith, The Scientist and Engineer's Guide to Digital Signal Processing: chapter 18:: -
  10 http://www.dspguide.com/ch18.htm
  11
  12 classmethods::
  13 private:: categories
  14
  15 method::ar
  16
  17 argument::in
  18 processing target
  19
  20 argument::kernel
  21 buffer index for the fixed kernel, may be modulated in combination with the trigger
  22
  23 argument::trigger
  24 update the kernel on a change from <=0 to >0
  25
  26 argument::framesize
  27 size of FFT frame, must be a power of two. Convolution uses twice this number internally, maximum value you can give this argument is 2^16=65536. Note that it gets progressively more expensive to run for higher powers! 512, 1024, 2048, 4096 standard.
  28
  29 argument::crossfade
  30 The number of periods over which a crossfade is made. The default is 1. This must be an integer.
  31
  32 argument::mul
  33
  34 argument::add
  35
  36 Examples::
  37
  38 code::
  39 (// allocate three buffers
  40 b = Buffer.alloc(s, 2048);
  41 c = Buffer.alloc(s, 2048);
  42 d = Buffer.alloc(s, 2048);
  43
  44 b.zero;
  45 c.zero;
  46 d.zero;
  47 )
  48
  49 (
  50 50.do({ |it| c.set(20*it+10, 1.0.rand); });
  51 3.do({ |it| b.set(400*it+100, 1); });
  52 20.do({ |it| d.set(40*it+20, 1); });
  53 )
  54 ::
  55 code::
  56 (
  57 SynthDef(\conv_test, { arg kernel, t_trig=0;
  58         var input;
  59
  60         input=Impulse.ar(1);
  61
  62         // must have power of two framesize
  63         Out.ar(0, Convolution2L.ar(input, kernel, t_trig, 2048, 1, 0.5));
  64 }).add
  65 )
  66
  67 x = Synth(\conv_test, [\kernel, b]);
  68
  69 // changing the buffer number:
  70 x.set(\kernel, c);
  71 x.set(\t_trig, 1); // after this trigger, the change will take effect.
  72 x.set(\kernel, d);
  73 x.set(\t_trig, 1); // after this trigger, the change will take effect.
  74
  75 d.zero;
  76 40.do({ |it| d.set(20*it+10, 1); });// changing the buffers' contents
  77 x.set(\t_trig, 1); // after this trigger, the change will take effect.
  78
  79 x.set(\kernel, b);
  80 x.set(\t_trig, 1); // after this trigger, the change will take effect.
  81
  82 x.free;
  83 ::
  84
  85 code::
  86 // longer crossfade
  87 (
  88 SynthDef( \conv_test2, { arg kernel, t_trig=0;
  89         var input;
  90
  91         input=Impulse.ar(1);
  92
  93         // must have power of two framesize
  94         Out.ar(0, Convolution2L.ar(input, kernel, t_trig, 2048, 5, 0.5));
  95 }).add
  96 )
  97
  98 x = Synth(\conv_test2, [\kernel, b]);
  99
 100 // changing the buffer number:
 101 x.set(\kernel, c);
 102 x.set(\t_trig, 1); // after this trigger, the change will take effect.
 103 x.set(\kernel, d);
 104 x.set(\t_trig, 1); // after this trigger, the change will take effect.
 105
 106 d.zero;
 107 40.do({ |it| d.set(20*it+10, 1); });// changing the buffers' contents
 108 x.set(\t_trig, 1); // after this trigger, the change will take effect.
 109
 110 x.set(\kernel, b);
 111 x.set(\t_trig, 1); // after this trigger, the change will take effect.
 112
 113 x.free;
 114 ::
 115
 116 code::
 117 // next example
 118
 119 b = Buffer.read(s, Platform.resourceDir +/+ "sounds/a11wlk01.wav");
 120
 121 (
 122         { var input, kernel;
 123
 124         input= SoundIn.ar(0);
 125
 126         // must have power of two framesize
 127         Convolution2L.ar(input, b, 0, 512, 1, 0.5);
 128         }.play;
 129
 130 )
 131 ::
 132
 133 code::
 134 // another example
 135
 136 (
 137 // must have power of two framesize- FFT size will be sorted by Convolution2 to be double this
 138 // maximum is currently a=8192 for FFT of size 16384
 139 a=2048;
 140 // kernel buffer
 141 g = Buffer.alloc(s, a, 1);
 142 )
 143
 144 (
 145 g.set(0, 1.0);
 146 100.do({arg i; g.set(a.rand, (i+1).reciprocal)});
 147 )
 148
 149 (
 150 // random impulse response
 151
 152         {
 153         var input, inputAmp, threshhold, gate;
 154
 155         input = SoundIn.ar(0);
 156         inputAmp = Amplitude.kr(input);
 157         threshhold = 0.02;      // noise gating threshold
 158         gate = Lag.kr(inputAmp > threshhold, 0.01);
 159
 160         Convolution2L.ar(input*gate, g, 0, a, 1, 0.5);
 161         }.play;
 162
 163 )
 164 ::
 165
 166 code::
 167 // one last example
 168 (
 169 b = Buffer.alloc(s, 512, 1);
 170 b.sine1(1.0/[1, 2, 3, 4, 5, 6], true, true, true);
 171 )
 172
 173 (
 174         { var input, kernel;
 175
 176         input=SoundIn.ar(0);
 177
 178         // must have power of two framesize
 179         Convolution2L.ar(input, b, 0, 512, 1, 0.5);
 180         }.play;
 181
 182 )
 183 ::
 184