HelpSource/Classes/OSCresponderNode.schelp

   1 class:: OSCresponderNode
   2 summary:: client side network responder
   3 related:: Classes/OSCFunc, Classes/OSCdef, Guides/OSC_communication, Classes/OSCpathResponder, Classes/NetAddr
   4 categories:: External Control>OSC
   5
   6 description::
   7 note:: As of SC 3.5 link::Classes/OSCFunc:: and link::Classes/OSCdef:: are the recommended way of registering for incoming OSC messages. They are faster, safer, and have more logical argument order than the old responder classes, and they support pattern matching and custom listening ports. Use of the older classes OSCresponder, OSCresponderNode, and OSCpathResponder can be unsafe, since responders in user and class code can override each other unintentionally. They are maintained for legacy code only.::
   8
   9 Register a function to be called upon receiving a specific command from a specific OSC address. Same interface like link::Classes/OSCresponder::, but allows strong::multiple responders to the same command::.
  10
  11 Note that OSCresponderNode evaluates its function in the system process.
  12 In order to access the application process (e.g. for GUI access ) use { ... }.defer;
  13
  14 Other applications sending messages to SuperCollider should distinguish between sending messages to the server or the language. Server messages are documented in the link::Reference/Server-Command-Reference:: and should be sent to the server's port - code::s.addr.port:: - which is strong::57110:: by default. Messages sent to the server will not be processed by any OSCresponder in the language.
  15
  16 Messages from external clients that should be processed by OSCresponders must be sent to the language port, strong::57120:: by default. Use code::NetAddr.langPort:: to confirm which port the SuperCollider language is listening on.
  17
  18 See link::Guides/OSC_communication:: for more details.
  19
  20 Examples::
  21
  22 subsection::Setting up OSCresponderNode for listening to a remote application
  23
  24 code::
  25 // example: two SuperCollider apps communicating
  26
  27 // application 1:
  28 n = NetAddr("127.0.0.1", 57120); // the url should be the one of computer of app 2 (or nil)
  29
  30 o = OSCresponderNode(n, '/chat', { |t, r, msg| ("time:" + t).postln; msg[1].postln }).add;
  31
  32 // application 2:
  33 m = NetAddr("127.0.0.1", 57120); // the url should be the one of computer of app 1
  34 m.sendMsg("/chat", "Hello App 1");
  35
  36 // sending bundles (including timestamps)
  37 (
  38 m.sendBundle(2.0, ["/chat", "Hello App 1"], ["/chat", "Hallo Wurld"]);
  39 m.sendBundle(0.0, ["/chat", "Hello App 1"], ["/chat", "Hallo Wurld"]);
  40 )
  41
  42 // end application 2:
  43 m.disconnect;
  44
  45 // end application 1:
  46 n.disconnect; o.remove;
  47 ::
  48
  49 subsection::Listening to data from _any_ client
  50
  51 code::
  52 // same as above, but we set the address to nil so we can receive from anywhere
  53 // no need for a NetAddr since we are just listening (and not sending)
  54
  55 o = OSCresponderNode(nil, '/test', { |t, r, msg| msg.postln }).add;
  56 o.remove;
  57 ::
  58
  59 subsection::Listening to data from _any_ client, but from a specific host
  60
  61 code::
  62 // same as above, but we use a NetAddr with a port of nil, so we can receive from a specific host, but from any port
  63
  64 n = NetAddr("127.0.0.1", nil); // the url should be the one of computer of app 2
  65 o = OSCresponderNode(n, '/test', { |t, r, msg| msg.postln }).add;
  66 o.remove;
  67 ::
  68
  69 subsection::Listening to data from the server
  70
  71 code::
  72 // example from SendTrig
  73
  74 (
  75 s = Server.local;
  76 s.boot;
  77 s.notify;
  78 )
  79
  80 (
  81 SynthDef("help-SendTrig",{
  82         SendTrig.kr(Dust.kr(1.0), 0, 0.9);
  83 }).send(s);
  84
  85 // register to receive this message
  86 a = OSCresponderNode(s.addr, '/tr', { arg time, responder, msg;
  87         [time, responder, msg].postln;
  88 }).add;
  89 b = OSCresponderNode(s.addr, '/tr', { arg time, responder, msg;
  90         "this is another call".postln;
  91 }).add;
  92 )
  93
  94 x = Synth.new("help-SendTrig");
  95 a.remove;
  96 b.remove;
  97 x.free;
  98 ::
  99
 100 subsection::Watching for something specific
 101
 102 code::
 103 // end of group message
 104
 105 s.boot;
 106
 107 a = OSCresponderNode(s.addr,'/n_end',{ arg time,responder,msg;
 108         [time, responder, msg].postln;
 109         if(msg[1] == g.nodeID,{
 110                 "g is dead !".postln;
 111                 // g = Group.new;
 112         });
 113 }).add;
 114
 115 g = Group.new;
 116
 117 g.free;
 118
 119 a.remove;
 120 ::
 121
 122 subsection::Watching for errors
 123
 124 code::
 125 // example from ServerErrorGui in crucial lib
 126
 127 f = OSCresponderNode(s.addr, '/fail', { arg time, responder, msg;
 128         {
 129                 var mins,secs;
 130                 mins = (time/60).round(1);
 131                 secs = (time%60).round(0.1);
 132                 if(secs<10,{ secs = "0"++secs.asString; },{ secs=secs.asString;});
 133                 // put this on a gui
 134                 //errors.label = "% % (%:%)".format(msg[1], msg[2], mins, secs);
 135                 //errors.stringColor = Color.white;
 136                 "% % (%:%)".format(msg[1], msg[2], mins, secs).postln;
 137         }.defer
 138 });
 139 f.add;
 140
 141 // cause a failure
 142 Synth("gthhhhppppppp!");
 143
 144 f.remove
 145 ::