SCClassLibrary/Common/Control/SystemActions.sc

   1 AbstractSystemAction {
   2
   3         *init {
   4                 this.objects = List.new;
   5         }
   6
   7         *add { arg object;
   8                 if(this.objects.isNil) { this.init }; // lazy init
   9                 if(this.objects.includes(object).not) { this.objects.add(object) }
  10         }
  11
  12         *remove { arg object;
  13                 this.objects.remove(object)
  14         }
  15
  16         *removeAll {
  17                 this.init
  18         }
  19
  20
  21         *objects { ^this.shouldNotImplement(thisMethod) }
  22         *objects_ { arg obj; ^this.shouldNotImplement(thisMethod) }
  23 }
  24
  25
  26
  27 // things to clear when hitting cmd-.
  28
  29 CmdPeriod : AbstractSystemAction {
  30         classvar <>objects;
  31         classvar <era = 0;
  32         classvar <>clearClocks = true;
  33         classvar <>freeServers = true;
  34         classvar <>freeRemote = false;
  35
  36
  37
  38         *doOnce { arg object;
  39                 var f = { this.remove(f); object.doOnCmdPeriod  };
  40                 this.add(f);
  41         }
  42         *run {
  43                 if(clearClocks, {
  44                         SystemClock.clear;
  45                         AppClock.clear;
  46         //              TempoClock.default.clear;
  47                 });
  48
  49                 objects.copy.do({ arg item; item.doOnCmdPeriod;  });
  50
  51                 if(freeServers, {
  52                         Server.freeAll(freeRemote); // stop all sounds on local, or remote servers
  53                         Server.resumeThreads;
  54                 });
  55
  56                 era = era + 1;
  57
  58         }
  59
  60         *hardRun {
  61
  62                 SystemClock.clear;
  63                 AppClock.clear;
  64                 TempoClock.default.clear;
  65
  66                 objects.copy.do({ arg item; item.doOnCmdPeriod;  });
  67
  68
  69
  70                 Server.hardFreeAll; // stop all sounds on local servers
  71                 Server.resumeThreads;
  72                 era = era + 1;
  73
  74         }
  75
  76
  77 }
  78
  79
  80 // things to do after startup file executed
  81
  82 StartUp : AbstractSystemAction {
  83
  84
  85         classvar <>objects, <done=false;
  86
  87
  88         *run {
  89                 done = true;
  90                 objects.copy.do({ arg item; item.doOnStartUp  });
  91                 // "StartUp done.".postln;
  92         }
  93
  94
  95         *defer { arg object;
  96                  if(done) { object.doOnStartUp } { this.add(object) }
  97         }
  98
  99
 100 }
 101
 102
 103 // things to do before system shuts down
 104
 105 ShutDown : AbstractSystemAction {
 106
 107         classvar <>objects;
 108
 109         *run {
 110                 objects.copy.do({ arg item; item.doOnShutDown;  });
 111         //      "ShutDown done.".postln;
 112         }
 113
 114 }
 115
 116 // things to do on a system reset
 117 OnError : AbstractSystemAction {
 118         classvar <>objects;
 119
 120         *run {
 121                 objects.copy.do({ arg item; item.doOnError;  });
 122         }
 123 }
 124
 125
 126 AbstractServerAction : AbstractSystemAction {
 127
 128         *init {
 129                 this.objects = IdentityDictionary.new;
 130         }
 131
 132         *performFunction { arg server, function;
 133                 if (this.objects.notNil) {
 134                         this.objects.at(server).copy.do(function);
 135                         if(server === Server.default) {
 136                                 this.objects.at(\default).copy.do(function)
 137                         };
 138                         this.objects.at(\all).copy.do(function);
 139                 }
 140         }
 141
 142         *run { arg server;
 143                 var selector = this.functionSelector;
 144                 // selector.postln;
 145                 this.performFunction(server, { arg obj; obj.perform(selector, server) });
 146         }
 147
 148         *functionSelector {
 149                 ^this.subclassResponsibility(thisMethod)
 150         }
 151
 152         *add { arg object, server;
 153                 var list;
 154                 if (server.isNil)  { server = \all };
 155                 if (this.objects.isNil) { this.init };
 156                 list = this.objects.at(server);
 157                 if (list.isNil) { list = List.new; this.objects.put(server, list) };
 158                 if (list.includes(object).not) { list.add(object) };
 159         }
 160
 161         *addToAll { arg object;
 162                 Server.all.do({ arg s; this.add(object, s) });
 163         }
 164
 165         *remove { arg object, server;
 166                 if(server.isNil) { server = \default };
 167                 this.objects !? { this.objects.at(server).remove(object) };
 168         }
 169
 170         *removeServer { arg server;
 171                 this.objects.removeAt(server)
 172         }
 173 }
 174
 175 // things to do after server has booted
 176
 177
 178 ServerBoot : AbstractServerAction {
 179
 180         classvar <>objects;
 181
 182         *functionSelector {
 183                 ^\doOnServerBoot
 184         }
 185 }
 186
 187 // things to do after server has quit
 188
 189
 190 ServerQuit : AbstractServerAction {
 191
 192         classvar <>objects;
 193
 194         *functionSelector {
 195                 ^\doOnServerQuit
 196         }
 197 }
 198
 199
 200 // things to do after server has booted and initialised
 201
 202
 203 ServerTree : AbstractServerAction {
 204
 205         classvar <>objects;
 206
 207         *functionSelector {
 208                 ^\doOnServerTree
 209         }
 210 }