SCClassLibrary/Common/Math/Polar.sc

   1 Polar : Number {
   2         var <>rho, <>theta;
   3
   4         *new { arg rho, theta;
   5                 ^super.newCopyArgs(rho, theta)
   6         }
   7
   8         magnitude { ^rho }
   9
  10         angle { ^theta }
  11         phase { ^theta }
  12
  13         real { ^rho * cos(theta) }
  14         imag { ^rho * sin(theta) }
  15
  16         asPolar { ^this }
  17         asComplex { ^Complex.new(this.real, this.imag) }
  18         asPoint { ^Point.new(this.real, this.imag) }
  19
  20         scale { arg scale;
  21                 ^Polar.new(rho * scale, theta)
  22         }
  23         rotate { arg angle; // in radians
  24                 ^Polar.new(rho, theta + angle)
  25         }
  26
  27         // do math as Complex
  28         + { arg aNumber;  ^this.asComplex + aNumber  }
  29         - { arg aNumber;  ^this.asComplex - aNumber  }
  30         * { arg aNumber;  ^this.asComplex * aNumber  }
  31         / { arg aNumber;  ^this.asComplex / aNumber  }
  32
  33         == { arg aPolar;
  34                 ^aPolar respondsTo: #[\rho, \theta] and: {
  35                         rho == aPolar.rho and: { theta == aPolar.theta }
  36                 }
  37         }
  38
  39         hash {
  40                 ^rho.hash bitXor: theta.hash
  41         }
  42
  43         neg { ^Polar.new(rho, theta + pi) }
  44
  45         performBinaryOpOnSomething { |aSelector, thing, adverb|
  46                 ^thing.asComplex.perform(aSelector, this, adverb)
  47         }
  48
  49         performBinaryOpOnUGen { arg aSelector, aUGen;
  50                 ^Complex.new(
  51                         BinaryOpUGen.new(aSelector, aUGen, this.real),
  52                         BinaryOpUGen.new(aSelector, aUGen, this.imag)
  53                 );
  54         }
  55
  56         printOn { arg stream;
  57                 stream << "Polar( " << rho << ", " << theta << " )";
  58         }
  59         storeArgs { ^[rho,theta] }
  60 }