SCClassLibrary/Platform/Platform.sc

   1 Platform
   2 {
   3         classvar defaultStartupFile;
   4
   5         // IDE actions
   6         classvar <>makeServerWindowAction, <>makeSynthDescWindowAction, <>openHelpFileAction, <>openHTMLFileAction;
   7
   8         var <classLibraryDir, <helpDir, <>recordingsDir, features;
   9         var <>devpath;
  10
  11         *initClass {
  12                 defaultStartupFile = this.userConfigDir +/+ "startup.scd"
  13         }
  14
  15         initPlatform {
  16                 classLibraryDir = thisMethod.filenameSymbol.asString.dirname.dirname;
  17                 helpDir = thisMethod.filenameSymbol.asString.dirname.dirname.dirname ++ "/Help";
  18                 features = IdentityDictionary.new;
  19                 recordingsDir = this.userAppSupportDir +/+ "Recordings";
  20         }
  21
  22         name { ^this.subclassResponsibility }
  23
  24         recompile { _Recompile }
  25         *case { | ... cases |
  26                 ^thisProcess.platform.name.switch(*cases)
  27         }
  28
  29         // directories
  30         *classLibraryDir { ^thisProcess.platform.classLibraryDir }
  31         *helpDir { ^thisProcess.platform.helpDir }
  32
  33         systemAppSupportDir { _Platform_systemAppSupportDir }
  34         *systemAppSupportDir { ^thisProcess.platform.systemAppSupportDir }
  35
  36         userAppSupportDir { _Platform_userAppSupportDir }
  37         *userAppSupportDir { ^thisProcess.platform.userAppSupportDir }
  38
  39         systemExtensionDir { _Platform_systemExtensionDir }
  40         *systemExtensionDir { ^thisProcess.platform.systemExtensionDir }
  41
  42         userExtensionDir { _Platform_userExtensionDir }
  43         *userExtensionDir { ^thisProcess.platform.userExtensionDir }
  44
  45         userConfigDir { _Platform_userConfigDir }
  46         *userConfigDir { ^thisProcess.platform.userConfigDir }
  47
  48         defaultTempDir { ^this.subclassResponsibility() }
  49         *defaultTempDir { ^thisProcess.platform.defaultTempDir }
  50
  51         // The "ideName" is for ide-dependent compilation.
  52         // From SC.app, the value is "scapp" meaning "scide_scapp" folders will be compiled and other "scide_*" ignored.
  53         ideName { _Platform_ideName }
  54         *ideName { ^thisProcess.platform.ideName }
  55
  56         platformDir { ^this.name.asString }
  57         *platformDir { ^thisProcess.platform.platformDir }
  58
  59         pathSeparator { ^this.subclassResponsibility }
  60         *pathSeparator { ^thisProcess.platform.pathSeparator }
  61
  62         isPathSeparator { |char| ^this.subclassResponsibility }
  63         *isPathSeparator { |char| ^thisProcess.platform.isPathSeparator(char) }
  64
  65         clearMetadata { |path| ^this.subclassResponsibility }
  66         *clearMetadata { |path| ^thisProcess.platform.clearMetadata(path) }
  67
  68         getMouseCoords { ^this.subclassResponsibility }
  69         *getMouseCoords { ^thisProcess.platform.getMouseCoords }
  70
  71         // startup/shutdown hooks
  72         startup { }
  73         shutdown { }
  74
  75         startupFiles {
  76                 ^[defaultStartupFile];
  77         }
  78
  79         *deprecatedStartupFiles {|paths|
  80                 var postWarning = false;
  81                 paths.do {|path|
  82                         if (File.exists(path.standardizePath)) {
  83                                 warn("Deprecated startup file found: %\n".format(path));
  84                                 postWarning = true;
  85                         }
  86                 };
  87                 if (postWarning) {
  88                         postln("Please use % as startup file.\nDeprecated startup files will be ignored in future versions.\n".format(defaultStartupFile));
  89                 }
  90         }
  91
  92         loadStartupFiles { this.startupFiles.do{|afile|
  93                 afile = afile.standardizePath;
  94                 if(File.exists(afile), {afile.load})
  95                 }
  96         }
  97
  98         // features
  99         declareFeature { | aFeature |
 100                 var str = aFeature.asString;
 101                 if (str.first.isUpper) {
 102                         Error("cannot declare class name features").throw;
 103                 };
 104                 if (str.first == $_) {
 105                         Error("cannot declare primitive name features").throw;
 106                 };
 107                 features.put(aFeature, true);
 108         }
 109         hasFeature { | symbol |
 110                 if (features.includesKey(symbol).not) {
 111                         features.put(
 112                                 symbol,
 113                                 symbol.asSymbol.asClass.notNil or: { symbol.isPrimitive }
 114                         )
 115                 };
 116                 ^features.at(symbol)
 117         }
 118         when { | features, ifFunction, elseFunction |
 119                 ^features.asArray.inject(true, { |v,x|
 120                         v and: { this.hasFeature(x) }
 121                 }).if(ifFunction, elseFunction)
 122         }
 123         *when {  | features, ifFunction, elseFunction |
 124                 ^thisProcess.platform.when(features, ifFunction, elseFunction)
 125         }
 126
 127         // Prefer qt but fall back to swing if qt not installed.
 128         defaultGUIScheme { if (GUI.get(\qt).notNil) {^\qt} {^\swing} }
 129         defaultHIDScheme { ^\none }
 130
 131         isSleeping { ^false } // unless defined otherwise
 132
 133         // used on systems to deduce a svn directory path, if system wide location is used for installed version. (tested on Linux).
 134         devLoc{ |inpath|
 135                 var outpath;
 136                 if ( devpath.isNil ){ ^inpath };
 137                 outpath = inpath.copyToEnd( inpath.find( "SuperCollider") );
 138                 outpath = outpath.replace( "SuperCollider", devpath );
 139                 ^outpath;
 140         }
 141
 142         // hook for clients to write frontend.css
 143         writeClientCSS {}
 144
 145         killAll { |cmdLineArgs|
 146                 ^this.subclassResponsibility(\killAll)
 147         }
 148 }
 149
 150 UnixPlatform : Platform
 151 {
 152         pathSeparator { ^$/ }
 153
 154         isPathSeparator { |char|
 155                 ^(char === this.pathSeparator)
 156         }
 157
 158         clearMetadata { |path|
 159                 "rm -f %\.*meta".format(path.splitext[0].escapeChar($ )).systemCmd;
 160         }
 161
 162         arch {
 163                 var pipe, arch;
 164                 pipe = Pipe("arch", "r");
 165                 arch = pipe.getLine;
 166                 pipe.close;
 167                 ^arch.asSymbol;
 168         }
 169
 170         killAll { |cmdLineArgs|
 171                 ("killall -9 " ++ cmdLineArgs).unixCmd;
 172         }
 173
 174         defaultTempDir {
 175                 // +/+ "" looks funny but ensures trailing slash
 176                 ^["/tmp/", this.userAppSupportDir +/+ ""].detect({ |path|
 177                         File.exists(path);
 178                 });
 179         }
 180 }