HelpSource/Classes/Gendy3.schelp

   1 class:: Gendy3
   2 summary:: Dynamic stochastic synthesis generator.
   3 related:: Classes/Gendy1, Classes/Gendy2
   4 categories::  UGens>Generators>Stochastic
   5
   6
   7 Description::
   8
   9 See  link::Classes/Gendy1::  help file for background. This variant of
  10 GENDYN normalises the durations in each period to force oscillation at
  11 the desired pitch. The breakpoints still get perturbed as in
  12 link::Classes/Gendy1:: .
  13
  14 There is some glitching in the oscillator caused by the stochastic
  15 effects - control points as they vary cause big local jumps of amplitude.
  16 Put  code::ampscale::  and  code::durscale::
  17 low to minimise the rate of this.
  18
  19 SuperCollider implementation by Nick Collins
  20
  21 classmethods::
  22
  23 method::ar, kr
  24
  25 discussion::
  26 All parameters can be modulated at control rate except for code::initCPs:: which is used only at initialisation.
  27
  28 argument::ampdist
  29
  30 Choice of probability distribution for the next perturbation of
  31 the amplitude of a control point.
  32
  33 The distributions are (adapted from the GENDYN program in Formalized Music):
  34
  35 table::
  36 ## 0: || LINEAR.
  37 ## 1: || CAUCHY.
  38 ## 2: || LOGIST.
  39 ## 3: || HYPERBCOS.
  40 ## 4: || ARCSINE.
  41 ## 5: || EXPON.
  42 ## 6: || SINUS.
  43 ::
  44
  45 Where the sinus (Xenakis' name) is in this implementation taken
  46 as sampling from a third party oscillator. See example below.
  47
  48
  49 argument::durdist
  50
  51 Choice of distribution for the perturbation of the current inter
  52 control point duration.
  53
  54
  55 argument::adparam
  56
  57 A parameter for the shape of the amplitude probability
  58 distribution, requires values in the range 0.0001 to 1 (there are
  59 safety checks in the code so don't worry too much if you want to
  60 modulate!).
  61
  62
  63 argument::ddparam
  64
  65 A parameter for the shape of the duration probability
  66 distribution, requires values in the range 0.0001 to 1.
  67
  68
  69 argument::freq
  70
  71 Oscillation frquency.
  72
  73
  74 argument::ampscale
  75
  76 Normally 0.0 to 1.0, multiplier for the distribution's delta
  77 value for amplitude. An ampscale of 1.0 allows the full range
  78 of  -1 to 1 for a change of amplitude.
  79
  80
  81 argument::durscale
  82
  83 Normally 0.0 to 1.0, multiplier for the distribution's delta
  84 value for duration. An ampscale of 1.0 allows the full range of
  85 -1 to 1 for a change of duration.
  86
  87
  88 argument::initCPs
  89
  90 Initialise the number of control points in the memory.
  91 Xenakis specifies 12. There would be this number of control
  92 points per cycle of the oscillator, though the oscillator's
  93 period will constantly change due to the duration distribution.
  94
  95
  96 argument::knum
  97
  98 Current number of utilised control points, allows modulation.
  99
 100
 101 Examples::
 102
 103 code::
 104
 105 //LOUD! defaults like a rougher Gendy1
 106 {Pan2.ar(Gendy3.ar(mul:0.5))}.play
 107
 108 {Pan2.ar(Gendy3.ar(freq:MouseX.kr(220,880,'exponential'), durscale:0.01, ampscale:0.02, mul:0.2))}.play
 109
 110 //stochastic waveform distortion- also play me at the same time as the previous example...
 111 {Pan2.ar(Gendy3.ar(1,2,0.3,-0.7,MouseX.kr(55,110,'exponential'),0.03,0.1))}.play
 112
 113
 114 (
 115 {Pan2.ar(
 116 Normalizer.ar(
 117 RLPF.ar(
 118 RLPF.ar(Mix.new(Gendy3.ar(freq:[230, 419, 546, 789])),
 119 MouseX.kr(10,10000,'exponential'),0.05),
 120 MouseY.kr(10,10000,'exponential'),0.05)
 121 ,0.9)
 122 ,Lag.kr(LFNoise0.kr(1),0.5))}.play
 123 )
 124
 125
 126 //concrete pH?
 127 (
 128 {Pan2.ar(
 129 Mix.new(Gendy3.ar(freq:([1,1.2,1.3,1.76,2.3]*MouseX.kr(3,17,'exponential')),mul:0.2)))}.play
 130 )
 131
 132 //glitch low, mountain high
 133 (
 134 {Pan2.ar(
 135 Mix.new(Gendy3.ar(3,5,1.0,1.0,(Array.fill(5,{LFNoise0.kr(1.3.rand,1,2)})*MouseX.kr(100,378,'exponential')),MouseX.kr(0.01,0.05),MouseY.kr(0.001,0.016),5,mul:0.1)))}.play
 136 )
 137
 138 //play me
 139 {Pan2.ar(RLPF.ar(Gendy3.ar(1,3,freq:MouseX.kr(100,1000), durscale:0.0, ampscale:MouseY.kr(0.0,0.1), initCPs:7, knum: MouseY.kr(7,2)), 500,0.3, 0.2), 0.0)}.play
 140
 141
 142
 143 //used as an LFO
 144 (
 145 {Pan2.ar(SinOsc.ar(Gendy3.kr(2,5,SinOsc.kr(0.1,0,0.49,0.51),SinOsc.kr(0.13,0,0.49,0.51), 0.34, SinOsc.kr(0.17,0,0.49,0.51), SinOsc.kr(0.19,0,0.49,0.51),10,10,mul:50, add:350), 0, 0.3), 0.0)}.play
 146 )
 147
 148 //buzzpipes
 149 {Pan2.ar(Mix.new(Gendy3.ar(0, 0, SinOsc.kr(0.1, 0, 0.1, 0.9),1.0, [100,205,410], 0.011,0.005, 12, 12, 0.12)), 0.0)}.play
 150
 151
 152 //modulate distributions
 153 //change of pitch as distributions change the duration structure and spectrum
 154 {Pan2.ar(Gendy3.ar(MouseX.kr(0,7),MouseY.kr(0,7),mul:0.2), 0.0)}.play
 155
 156
 157 //modulate num of CPs
 158 {Pan2.ar(Gendy3.ar(knum:MouseX.kr(2,13),mul:0.2), 0.0)}.play
 159
 160
 161 //Gendy1 into Gendy2 into Gendy3...with cartoon side effects
 162 (
 163 {Pan2.ar(Gendy3.ar(1,2,freq:Gendy2.ar(maxfreq:Gendy1.kr(5,4,0.3, 0.7, 0.1, MouseY.kr(0.1,10), 1.0, 1.0, 5,5, 25,26),minfreq:24, knum:MouseX.kr(1,13),mul:150, add:200), durscale:0.01, ampscale:0.01, mul:0.1), 0.0)}.play
 164 )
 165
 166 //use SINUS to track any oscillator and take CP positions from it, use adparam and ddparam as the inputs to sample
 167 {Pan2.ar(Gendy3.ar(6,6,LFPulse.kr(LFNoise0.kr(19.0,0.5,0.6), 0, 0.4, 0.5), Gendy1.kr(durscale:0.01,ampscale:0.01), MouseX.kr(10,100),mul:0.2), 0.0)}.play
 168
 169
 170
 171 //wolf tones
 172 (
 173 {
 174 Mix.fill(10,{
 175 var freq;
 176
 177 freq= exprand(130,1160.3);
 178 Pan2.ar(SinOsc.ar(Gendy3.ar(6.rand,6.rand,SinOsc.kr(0.1,0,0.49,0.51),SinOsc.kr(0.13,0,0.49,0.51),freq, SinOsc.kr(0.17,0,0.0049,0.0051), SinOsc.kr(0.19,0,0.0049,0.0051), 12, 12, 200, 400), 0, 0.1), 1.0.rand2)
 179 });
 180 }.play
 181 )
 182
 183 //CAREFUL! mouse to far right causes explosion of sound-
 184 //notice how high frequency and num of CPs affects CPU cost
 185 (
 186 {Pan2.ar(
 187 CombN.ar(
 188 Resonz.ar(
 189 Gendy3.ar(2,3,freq:MouseX.kr(10,700), initCPs:100),
 190 MouseY.kr(50,1000), 0.1)
 191 ,0.1,0.1,5, 0.16
 192 )
 193 , 0.0)}.play
 194 )
 195
 196
 197 //storm
 198 (
 199 {
 200 var n;
 201 n=15;
 202
 203 0.5*Mix.fill(n,{
 204 var freq, numcps;
 205
 206 freq= rrand(130,160.3);
 207 numcps= rrand(2,20);
 208 Pan2.ar(Gendy3.ar(6.rand,6.rand,10.0.rand,10.0.rand,freq*exprand(1.0,2.0), 10.0.rand, 10.0.rand, numcps, SinOsc.kr(exprand(0.02,0.2), 0, numcps/2, numcps/2), 0.5/(n.sqrt)), 1.0.rand2)
 209 });
 210 }.play
 211 )
 212
 213
 214
 215 //another glitchy moment
 216 (
 217 {
 218 var n;
 219 n=10;
 220
 221 Resonz.ar(
 222 Mix.fill(n,{
 223 var freq, numcps;
 224
 225 freq= rrand(50,560.3);
 226 numcps= rrand(2,20);
 227 Pan2.ar(Gendy3.ar(6.rand,6.rand,1.0.rand,1.0.rand,freq, 1.0.rand, 1.0.rand, numcps, SinOsc.kr(exprand(0.02,0.2), 0, numcps/2, numcps/2), 0.5/(n.sqrt)), 1.0.rand2)
 228 })
 229 ,MouseX.kr(100,2000), MouseY.kr(0.01,1.0), 0.3)
 230 ;
 231 }.play
 232 )
 233 ::
 234