| blob | fcaa3a7a7c7c2384ca2c8f8dc4247e29b78e9a64 |
1 ;; -----------------------------------------------------------------------
2 ;;
3 ;; Copyright 1994-2006 H. Peter Anvin - All Rights Reserved
4 ;;
5 ;; This program is free software; you can redistribute it and/or modify
6 ;; it under the terms of the GNU General Public License as published by
7 ;; the Free Software Foundation, Inc., 53 Temple Place Ste 330,
8 ;; Boston MA 02111-1307, USA; either version 2 of the License, or
9 ;; (at your option) any later version; incorporated herein by reference.
10 ;;
11 ;; -----------------------------------------------------------------------
13 ;;
14 ;; comboot.inc
15 ;;
16 ;; Common code for running a COMBOOT image
17 ;;
19 section .text
21 ; Parameter registers definition; this is the definition
22 ; of the stack frame used by INT 21h and INT 22h.
23 %define P_FLAGS word [bp+44]
24 %define P_FLAGSL byte [bp+44]
25 %define P_FLAGSH byte [bp+45]
26 %define P_CS word [bp+42]
27 %define P_IP word [bp+40]
28 %define P_DS word [bp+38]
29 %define P_ES word [bp+36]
30 %define P_FS word [bp+34]
31 %define P_GS word [bp+32]
32 %define P_EAX dword [bp+28]
33 %define P_AX word [bp+28]
34 %define P_HAX word [bp+30]
35 %define P_AL byte [bp+28]
36 %define P_AH byte [bp+29]
37 %define P_ECX dword [bp+24]
38 %define P_CX word [bp+24]
39 %define P_HCX word [bp+26]
40 %define P_CL byte [bp+24]
41 %define P_CH byte [bp+25]
42 %define P_EDX dword [bp+20]
43 %define P_DX word [bp+20]
44 %define P_HDX word [bp+22]
45 %define P_DL byte [bp+20]
46 %define P_DH byte [bp+21]
47 %define P_EBX dword [bp+16]
48 %define P_BX word [bp+16]
49 %define P_HBX word [bp+18]
50 %define P_BL byte [bp+16]
51 %define P_BH byte [bp+17]
52 %define P_EBP dword [bp+8]
53 %define P_BP word [bp+8]
54 %define P_HBP word [bp+10]
55 %define P_ESI dword [bp+4]
56 %define P_SI word [bp+4]
57 %define P_HSI word [bp+6]
58 %define P_EDI dword [bp]
59 %define P_DI word [bp]
60 %define P_HDI word [bp+2]
62 ; Looks like a COMBOOT image but too large
63 comboot_too_large:
64 mov si,err_comlarge
65 call cwritestr
66 jmp enter_command
68 ;
69 ; Load a COMBOOT image. A COMBOOT image is basically a DOS .COM file,
70 ; except that it may, of course, not contain any DOS system calls. We
71 ; do, however, allow the execution of INT 20h to return to SYSLINUX.
72 ;
73 is_comboot_image:
74 and dx,dx
75 jnz comboot_too_large
76 cmp ax,0ff00h ; Max size in bytes
77 jae comboot_too_large
79 push si ; Save file handle
81 call make_plain_cmdline
83 call comboot_setup_api
85 mov cx,comboot_seg
86 mov es,cx
88 xor di,di
89 mov cx,64 ; 256 bytes (size of PSP)
90 xor eax,eax ; Clear PSP
91 rep stosd
93 mov word [es:0], 020CDh ; INT 20h instruction
94 ; First non-free paragraph
95 ; This is valid because comboot_seg == real_mode_seg
96 ; == the highest segment used by all derivatives
97 int 12h ; Get DOS memory size
98 shl ax,6 ; Kilobytes -> paragraphs
99 mov word [es:02h],ax
101 %ifndef DEPEND
102 %if real_mode_seg != comboot_seg
103 %error "This code assumes real_mode_seg == comboot_seg"
104 %endif
105 %endif
106 ; Copy the command line from high memory
107 mov si,cmd_line_here
108 mov cx,125 ; Max cmdline len (minus space and CR)
109 mov di,081h ; Offset in PSP for command line
110 mov al,' ' ; DOS command lines begin with a space
111 stosb
113 .loop: es lodsb
114 and al,al
115 jz .done
116 stosb
117 loop .loop
118 .done:
120 mov al,0Dh ; CR after last character
121 stosb
122 mov ax,di
123 sub al,82h ; Include space but not CR
124 mov [es:80h],al ; Store command line length
126 ; Now actually load the file...
127 pop si ; File handle
128 mov bx,100h ; Load at <seg>:0100h
129 mov cx,0FF00h >> SECTOR_SHIFT
130 ; Absolute maximum # of sectors
131 call getfssec
133 ; And invoke the program...
134 mov ax,es
135 mov ds,ax
136 mov ss,ax
137 xor sp,sp
138 push word 0 ; Return to address 0 -> exit
140 jmp comboot_seg:100h ; Run it
142 ; Proper return vector
143 comboot_return: cli ; Don't trust anyone
144 push enter_command ; Normal return to command prompt
145 jmp comboot_exit
147 ;
148 ; Set up the COMBOOT API interrupt vectors. This is also used
149 ; by the COM32 code.
150 ;
151 comboot_setup_api:
152 mov di,4*0x20 ; DOS interrupt vectors
153 mov eax,comboot_return ; INT 20h = exit
154 stosd
155 mov ax,comboot_int21 ; INT 21h = DOS-compatible syscalls
156 stosd
157 mov ax,comboot_int22 ; INT 22h = proprietary syscalls
158 stosd
159 mov ax,comboot_bogus
160 mov cx,29 ; All remaining DOS vectors
161 rep stosd
162 ret
164 ; INT 21h: generic DOS system call
165 comboot_int21: cli
166 push ds
167 push es
168 push fs
169 push gs
170 pushad
171 cld
172 mov bp,cs
173 mov ds,bp
174 mov es,bp
175 mov bp,sp ; Set up stack frame
177 call adjust_screen ; The COMBOOT program might have changed the screen
179 mov cx,int21_count
180 mov si,int21_table
181 .again: lodsb
182 cmp al,P_AH
183 lodsw
184 loopne .again
185 ; The last function in the list is the
186 ; "no such function" function
187 clc
188 call ax ; Call the invoked function
189 comboot_resume:
190 setc P_FLAGSL ; Propagate CF->error
191 popad
192 pop gs
193 pop fs
194 pop es
195 pop ds
196 iret
198 ; Attempted to execute non-21h DOS system call
199 comboot_bogus: cli ; Don't trust anyone
200 mov cx,err_notdos
201 push enter_command
202 jmp comboot_exit_msg
204 ;
205 ; Generic COMBOOT return to command line code
206 ; stack -> where to go next
207 ; CX -> message (for _msg version)
208 ;
209 comboot_exit:
210 xor cx,cx
211 comboot_exit_msg:
212 pop bx ; Return address
213 RESET_STACK_AND_SEGS AX
214 call adjust_screen ; The COMBOOT program might have changed the screen
215 jcxz .nomsg
216 mov si,KernelCName
217 call cwritestr
218 mov si,cx
219 call cwritestr
220 .nomsg:
221 jmp bx
223 ;
224 ; INT 21h system calls
225 ;
226 comboot_getkey: ; 01 = get key with echo
227 call vgashowcursor
228 call comboot_getchar
229 call vgahidecursor
230 call writechr
231 clc
232 ret
234 comboot_writechr: ; 02 = writechr
235 mov al,P_DL
236 call writechr
237 clc
238 ret
240 comboot_writeserial: ; 04 = write serial port
241 mov al,P_DL
242 call write_serial
243 clc
244 ret
246 comboot_getkeynoecho: ; 08 = get key w/o echo
247 call comboot_getchar
248 clc
249 ret
251 comboot_writestr: ; 09 = write DOS string
252 mov es,P_DS
253 mov si,P_DX
254 .loop: es lodsb
255 cmp al,'$' ; End string with $ - bizarre
256 je .done
257 call writechr
258 jmp short .loop
259 .done: clc
260 ret
262 comboot_checkkey: ; 0B = check keyboard status
263 cmp byte [APIKeyFlag],00h
264 jnz .waiting
265 call pollchar
266 .waiting: setz al
267 dec al ; AL = 0FFh if present, 0 if not
268 mov P_AL,al
269 clc
270 ret
272 comboot_checkver: ; 30 = check DOS version
273 ; We return 0 in all DOS-compatible version registers,
274 ; but the high part of eax-ebx-ecx-edx spell "SYSLINUX"
275 mov P_EAX,'SY' << 16
276 mov P_EBX,'SL' << 16
277 mov P_ECX,'IN' << 16
278 mov P_EDX,'UX' << 16
279 ret
281 comboot_getchar:
282 cmp byte [APIKeyFlag],00h
283 jne .queued
284 call getchar ; If not queued get input
285 and al,al ; Function key? (CF <- 0)
286 jnz .done
287 mov [APIKeyWait],ah ; High part of key
288 inc byte [APIKeyFlag] ; Set flag
289 .done: mov P_AL,al
290 ret
291 .queued: mov al,[APIKeyWait]
292 dec byte [APIKeyFlag]
293 jmp .done
295 ;
296 ; INT 22h - SYSLINUX-specific system calls
297 ; System call number in ax
298 ;
299 comboot_int22:
300 cli
301 push ds
302 push es
303 push fs
304 push gs
305 pushad
306 cld
307 mov bp,cs
308 mov ds,bp
309 mov es,bp
310 mov bp,sp ; Set up stack frame
312 call adjust_screen ; The COMBOOT program might have changed the screen
314 cmp ax,int22_count
315 jb .ok
316 xor ax,ax ; Function 0 -> unimplemented
317 .ok:
318 xchg ax,bx
319 add bx,bx ; CF <- 0
320 call [bx+int22_table]
321 jmp comboot_resume ; On return
323 ;
324 ; INT 22h AX=0000h Unimplemented call
325 ;
326 comapi_err:
327 stc
328 ret
330 ;
331 ; INT 22h AX=0001h Get SYSLINUX version
332 ;
333 comapi_get_version:
334 ; Number of API functions supported
335 mov P_AX,int22_count
336 ; SYSLINUX version
337 mov P_CX,(VER_MAJOR << 8)+VER_MINOR
338 ; SYSLINUX derivative ID byte
339 mov P_DX,my_id
340 ; For future use
341 mov P_BX,cs ; cs == 0
343 mov P_ES,ds
344 ; ES:SI -> version banner
345 mov P_SI,syslinux_banner
346 ; ES:DI -> copyright string
347 mov P_DI,copyright_str
349 comapi_nop:
350 clc
351 ret
353 ;
354 ; INT 22h AX=0002h Write string
355 ;
356 ; Write null-terminated string in ES:BX
357 ;
358 comapi_writestr:
359 mov ds,P_ES
360 mov si,P_BX
361 call writestr
362 clc
363 ret
365 ;
366 ; INT 22h AX=0003h Run command
367 ;
368 ; Terminates the COMBOOT program and executes the command line in
369 ; ES:BX as if it had been entered by the user.
370 ;
371 comapi_run:
372 mov ds,P_ES
373 mov si,P_BX
374 mov di,command_line
375 call strcpy
376 push load_kernel ; Run a new kernel
377 jmp comboot_exit ; Terminate task, clean up
379 ;
380 ; INT 22h AX=0004h Run default command
381 ;
382 ; Terminates the COMBOOT program and executes the default command line
383 ; as if a timeout had happened or the user pressed <Enter>.
384 ;
385 comapi_run_default:
386 push auto_boot
387 jmp comboot_exit
389 ;
390 ; INT 22h AX=0005h Force text mode
391 ;
392 ; Puts the video in standard text mode
393 ;
394 comapi_textmode:
395 call vgaclearmode
396 clc
397 ret
399 ;
400 ; INT 22h AX=0006h Open file
401 ;
402 comapi_open:
403 push ds
404 mov ds,P_ES
405 mov si,P_SI
406 mov di,InitRD
407 push di
408 call mangle_name
409 pop di
410 pop ds
411 call searchdir
412 jz comapi_err
413 mov P_AX,ax
414 mov P_HAX,dx
415 mov P_CX,SECTOR_SIZE
416 mov P_SI,si
417 clc
418 ret
420 ;
421 ; INT 22h AX=0007h Read file
422 ;
423 comapi_read:
424 mov es,P_ES
425 mov bx,P_BX
426 mov si,P_SI
427 mov cx,P_CX
428 call getfssec
429 jnc .noteof
430 xor si,si ; SI <- 0 on EOF, CF <- 0
431 .noteof: mov P_SI,si
432 ret
434 ;
435 ; INT 22h AX=0008h Close file
436 ;
437 comapi_close:
438 ; Do nothing for now. Eventually implement
439 ; an internal API for this.
440 clc
441 ret
443 ;
444 ; INT 22h AX=0009h Call PXE stack
445 ;
446 %if IS_PXELINUX
447 comapi_pxecall:
448 mov bx,P_BX
449 mov es,P_ES
450 mov di,P_DI
451 call pxenv
452 mov P_AX,ax
453 clc
454 ret
455 %else
456 comapi_pxecall equ comapi_err ; Not available
457 %endif
459 ;
460 ; INT 22h AX=000Ah Get Derivative-Specific Info
461 ;
462 comapi_derinfo:
463 mov P_AL,my_id
464 %if IS_SYSLINUX || IS_MDSLINUX || IS_EXTLINUX
465 mov al,[DriveNumber]
466 mov P_DL,al
467 mov P_ES,cs
468 mov P_BX,PartInfo
469 mov P_CL,SECTOR_SHIFT
470 %elif IS_PXELINUX
471 mov ax,[APIVer]
472 mov P_DX,ax
473 mov ax,[StrucPtr]
474 mov P_BX,ax
475 mov ax,[StrucPtr+2]
476 mov P_ES,ax
477 mov ax,[InitStack]
478 mov P_SI,ax
479 mov ax,[InitStack+2]
480 mov P_FS,ax
481 %elif IS_ISOLINUX
482 mov al,[DriveNo]
483 mov P_DL,al
484 mov P_ES,cs
485 mov P_BX,spec_packet
486 mov P_CL,SECTOR_SHIFT
487 %endif
488 clc
489 ret
491 ;
492 ; INT 22h AX=000Bh Get Serial Console Configuration
493 ;
494 comapi_serialcfg:
495 mov ax,[SerialPort]
496 mov P_DX,ax
497 mov ax,[BaudDivisor]
498 mov P_CX,ax
499 mov ax,[FlowControl]
500 or al,ah
501 mov ah,[FlowIgnore]
502 shr ah,4
503 test byte [DisplayCon],01h
504 jnz .normalconsole
505 or ah,80h
506 .normalconsole:
507 mov P_BX,ax
508 clc
509 ret
511 ;
512 ; INT 22h AX=000Ch Perform final cleanup
513 ;
514 comapi_cleanup:
515 %if IS_PXELINUX
516 ; Unload PXE if requested
517 test dl,3
518 setnz [KeepPXE]
519 sub bp,sp ; unload_pxe may move the stack around
520 call unload_pxe
521 add bp,sp ; restore frame pointer...
522 %elif IS_SYSLINUX || IS_MDSLINUX || IS_EXTLINUX
523 ; Restore original FDC table
524 mov eax,[OrigFDCTabPtr]
525 mov [fdctab],eax
526 %endif
527 ; Reset the floppy disk subsystem
528 xor ax,ax
529 xor dx,dx
530 int 13h
531 clc
532 ret
534 ;
535 ; INT 22h AX=000Dh Clean up then replace bootstrap
536 ;
537 comapi_chainboot:
538 call comapi_cleanup
539 mov eax,P_EDI
540 mov [trackbuf+4],eax ; Copy from
541 mov eax,P_ECX
542 mov [trackbuf+8],eax ; Total bytes
543 mov eax,7C00h
544 mov [trackbuf],eax ; Copy to
545 mov [EntryPoint],eax ; CS:IP entry point
546 mov esi,P_ESI
547 mov edx,P_EBX
548 mov bx,P_DS
549 jmp replace_bootstrap_one
552 ;
553 ; INT 22h AX=000Eh Get configuration file name
554 ;
555 comapi_configfile:
556 mov P_ES,cs
557 mov P_BX,ConfigName
558 clc
559 ret
561 ;
562 ; INT 22h AX=000Fh Get IPAPPEND strings
563 ;
564 %if IS_PXELINUX
565 comapi_ipappend:
566 mov P_ES,cs
567 mov P_CX,numIPAppends
568 mov P_BX,IPAppends
569 clc
570 ret
572 section .data
573 alignb 2, db 0
574 IPAppends dw IPOption
575 dw BOOTIFStr
576 numIPAppends equ ($-IPAppends)/2
578 %else
579 comapi_ipappend equ comapi_err
580 %endif
582 section .text
584 ;
585 ; INT 22h AX=0010h Resolve hostname
586 ;
587 %if IS_PXELINUX
588 comapi_dnsresolv:
589 mov ds,P_ES
590 mov si,P_BX
591 call dns_resolv
592 mov P_EAX,eax
593 ret
594 %else
595 comapi_dnsresolv equ comapi_err
596 %endif
598 section .text
600 ;
601 ; INT 22h AX=0011h Maximum number of shuffle descriptors
602 ;
603 comapi_maxshuffle:
604 mov P_CX,(2*trackbufsize)/12
605 ret
607 ;
608 ; INT 22h AX=0012h Cleanup, shuffle and boot
609 ;
610 comapi_shuffle:
611 call comapi_cleanup
612 mov cx,P_CX
613 cmp cx,(2*trackbufsize)/12
614 ja .error
616 push cx ; On stack: descriptor count
618 lea cx,[ecx+ecx*2] ; CX *= 3
620 mov fs,P_ES
621 mov si,P_DI
622 mov di,trackbuf
623 push di ; On stack: descriptor list address
624 fs rep movsd ; Copy the list
626 mov eax,P_EBP
627 mov [EntryPoint],eax ; CS:IP entry point
628 mov esi,P_ESI
629 mov edx,P_EBX
630 mov bx,P_DS
631 jmp replace_bootstrap
632 .error:
633 stc
634 ret
636 ;
637 ; INT 22h AX=0013h Idle call
638 ;
639 ;
640 ; *** FIX THIS ***
641 ; The idle call seems to have detrimental effects on some machines when
642 ; called from a COM32 context (WHY?) -- disable it for now.
643 ;
644 %if 0 ; def HAVE_IDLE
646 comapi_idle:
647 DO_IDLE
648 clc
649 ret
651 %else
653 comapi_idle equ comapi_err
655 %endif
657 ;
658 ; INT 22h AX=0014h Local boot
659 ;
660 %if IS_PXELINUX || IS_ISOLINUX
661 comapi_localboot:
662 mov ax,P_DX
663 jmp local_boot
664 %else
665 comapi_localboot equ comapi_err
666 %endif
668 ;
669 ; INT 22h AX=0015h Feature flags
670 ;
671 comapi_features:
672 mov P_ES,cs
673 mov P_BX,feature_flags
674 mov P_CX,feature_flags_len
675 clc
676 ret
678 ;
679 ; INT 22h AX=0016h Run kernel image
680 ;
681 comapi_runkernel:
682 push ds
683 mov ds,P_DS
684 mov si,P_SI
685 mov di,KernelName
686 push di
687 call mangle_name
688 pop di
689 pop ds
690 call searchdir
691 jz comapi_err
693 ; The kernel image was found, so we can load it...
694 mov [Kernel_SI],si
695 mov [Kernel_EAX],ax
696 mov [Kernel_EAX+2],dx
698 ; It's not just possible, but quite likely, that ES:BX
699 ; points into real_mode_seg, so we need to exercise some
700 ; special care here... use xfer_buf_seg as an intermediary
701 push ds
702 push es
703 mov ax,xfer_buf_seg
704 mov ds,P_ES
705 mov si,P_BX
706 mov es,ax
707 xor di,di
708 call strcpy
709 pop es
710 pop ds
712 %if IS_PXELINUX
713 mov al,P_CL
714 mov [IPAppend],al
715 %endif
717 call comboot_exit
719 .finish:
720 ; Copy the command line into its proper place
721 push ds
722 push es
723 mov ax,xfer_buf_seg
724 mov dx,real_mode_seg
725 mov ds,ax
726 mov es,dx
727 xor si,si
728 mov di,cmd_line_here
729 call strcpy
730 mov byte [es:di-1],' ' ; Simulate APPEND
731 pop es
732 pop ds
733 mov [CmdLinePtr],di
734 mov word [CmdOptPtr],zero_string
735 jmp kernel_good_saved
737 ;
738 ; INT 22h AX=0017h Report video mode change
739 ;
740 comapi_usingvga:
741 mov ax,P_BX
742 cmp ax,0Fh ; Unknown flags = failure
743 ja .error
744 mov [UsingVGA],al
745 mov cx,P_CX
746 mov dx,P_DX
747 mov [GXPixCols],cx
748 mov [GXPixRows],dx
749 test al,08h
750 jnz .notext
751 call adjust_screen
752 .notext:
753 clc
754 ret
755 .error:
756 stc
757 ret
759 ;
760 ; INT 22h AX=0018h Query custom font
761 ;
762 comapi_userfont:
763 mov al,[UserFont]
764 and al,al
765 jz .done
766 mov al,[VGAFontSize]
767 mov P_ES,ds
768 mov P_BX,vgafontbuf
770 .done: ; CF=0 here
771 mov P_AL,al
772 ret
774 ;
775 ; INT 22h AX=0019h Read disk
776 ;
777 %if IS_SYSLINUX || IS_MDSLINUX || IS_ISOLINUX || IS_EXTLINUX
778 comapi_readdisk:
779 mov esi,P_ESI ; Enforce ESI == EDI == 0, these
780 or esi,P_EDI ; are reserved for future expansion
781 jnz .err
782 mov eax,P_EDX
783 mov bp,P_CX
784 mov es,P_ES
785 mov bx,P_BX
786 call getlinsec
787 clc
788 ret
789 .err:
790 stc
791 ret
792 %else
793 comapi_readdisk equ comapi_err
794 %endif
796 section .data
798 %macro int21 2
799 db %1
800 dw %2
801 %endmacro
803 int21_table:
804 int21 00h, comboot_return
805 int21 01h, comboot_getkey
806 int21 02h, comboot_writechr
807 int21 04h, comboot_writeserial
808 int21 08h, comboot_getkeynoecho
809 int21 09h, comboot_writestr
810 int21 0Bh, comboot_checkkey
811 int21 30h, comboot_checkver
812 int21 4Ch, comboot_return
813 int21 -1, comboot_bogus
814 int21_count equ ($-int21_table)/3
816 align 2, db 0
817 int22_table:
818 dw comapi_err ; 0000 unimplemented syscall
819 dw comapi_get_version ; 0001 get SYSLINUX version
820 dw comapi_writestr ; 0002 write string
821 dw comapi_run ; 0003 run specified command
822 dw comapi_run_default ; 0004 run default command
823 dw comapi_textmode ; 0005 force text mode
824 dw comapi_open ; 0006 open file
825 dw comapi_read ; 0007 read file
826 dw comapi_close ; 0008 close file
827 dw comapi_pxecall ; 0009 call PXE stack
828 dw comapi_derinfo ; 000A derivative-specific info
829 dw comapi_serialcfg ; 000B get serial port config
830 dw comapi_cleanup ; 000C perform final cleanup
831 dw comapi_chainboot ; 000D clean up then bootstrap
832 dw comapi_configfile ; 000E get name of config file
833 dw comapi_ipappend ; 000F get ipappend strings
834 dw comapi_dnsresolv ; 0010 resolve hostname
835 dw comapi_maxshuffle ; 0011 maximum shuffle descriptors
836 dw comapi_shuffle ; 0012 cleanup, shuffle and boot
837 dw comapi_idle ; 0013 idle call
838 dw comapi_localboot ; 0014 local boot
839 dw comapi_features ; 0015 feature flags
840 dw comapi_runkernel ; 0016 run kernel image
841 dw comapi_usingvga ; 0017 report video mode change
842 dw comapi_userfont ; 0018 query custom font
843 dw comapi_readdisk ; 0019 read disk
844 int22_count equ ($-int22_table)/2
846 APIKeyWait db 0
847 APIKeyFlag db 0
849 zero_string db 0 ; Empty, null-terminated string
851 ;
852 ; This is the feature flag array for INT 22h AX=0015h
853 feature_flags:
854 %if IS_PXELINUX
855 db 1 ; Have local boot, idle not noop
856 %elif IS_ISOLINUX
857 db 3 ; Have local boot, idle is noop
858 %else
859 db 2 ; No local boot, idle is noop
860 %endif
861 feature_flags_len equ ($-feature_flags)