| blob | de64a18f58a274b890f47e2597e932b6de87d9e1 |
1 ;; -----------------------------------------------------------------------
2 ;;
3 ;; Copyright 1994-2004 H. Peter Anvin - All Rights Reserved
4 ;;
5 ;; This program is free software; you can redistribute it and/or modify
6 ;; it under the terms of the GNU General Public License as published by
7 ;; the Free Software Foundation, Inc., 53 Temple Place Ste 330,
8 ;; Boston MA 02111-1307, USA; either version 2 of the License, or
9 ;; (at your option) any later version; incorporated herein by reference.
10 ;;
11 ;; -----------------------------------------------------------------------
13 ;;
14 ;; parseconfig.inc
15 ;;
16 ;; Configuration file operations
17 ;;
19 section .text
20 ;
21 ; "default" command
22 ;
23 pc_default: mov di,default_cmd
24 call getline
25 mov byte [di-1],0 ; null-terminate
26 ret
28 ;
29 ; "ontimeout" command
30 ;
31 pc_ontimeout: mov di,Ontimeout
32 call getline
33 sub di,Ontimeout+1 ; Don't need final space
34 mov [OntimeoutLen],di
35 ret
37 ;
38 ; "onerror" command
39 ;
40 pc_onerror: mov di,Onerror
41 call getline
42 sub di,Onerror
43 mov [OnerrorLen],di
44 ret
46 ;
47 ; "append" command
48 ;
49 pc_append: cmp byte [VKernel],0
50 ja .vk
51 mov di,AppendBuf
52 call getline
53 sub di,AppendBuf
54 .app1: mov [AppendLen],di
55 ret
56 .vk: mov di,VKernelBuf+vk_append ; "append" command (vkernel)
57 call getline
58 sub di,VKernelBuf+vk_append
59 cmp di,byte 2
60 jne .app2
61 cmp byte [VKernelBuf+vk_append],'-'
62 jne .app2
63 xor di,di ; If "append -" -> null string
64 .app2: mov [VKernelBuf+vk_appendlen],di
65 ret
67 ;
68 ; "ipappend" command (PXELINUX only)
69 ;
70 %if IS_PXELINUX
71 pc_ipappend: call getint
72 jc .err
73 cmp byte [VKernel],0
74 jne .vk
75 mov [IPAppend],bl
76 .err: ret
77 .vk: mov [VKernelBuf+vk_ipappend],bl
78 ret
79 %endif
81 ;
82 ; "localboot" command (PXELINUX, ISOLINUX)
83 ;
84 %if IS_PXELINUX || IS_ISOLINUX
85 pc_localboot: call getint
86 cmp byte [VKernel],0 ; ("label" section only)
87 je .err
88 mov di,VKernelBuf+vk_rname
89 xor ax,ax
90 mov cx,FILENAME_MAX
91 rep stosb ; Null kernel name
92 %if IS_PXELINUX
93 ; PXELINUX uses the first 4 bytes of vk_rname for the
94 ; mangled IP address
95 mov [VKernelBuf+vk_rname+5], bx ; Return type
96 %else
97 mov [VKernelBuf+vk_rname+1], bx ; Return type
98 %endif
99 .err: ret
100 %endif
102 ;
103 ; "kernel" command
104 pc_kernel: cmp byte [VKernel],0
105 je .err ; ("label" section only)
106 call pc_getline
107 mov di,VKernelBuf+vk_rname
108 call mangle_name
109 .err: ret
111 ;
112 ; "timeout", "totaltimeout" command
113 ;
114 ; N.B. 1/10 s ~ 1.D2162AABh clock ticks
115 ;
116 pc_timeout: push ax
117 call getint
118 pop si
119 jc .err
120 mov eax,0D2162AABh
121 mul ebx ; clock ticks per 1/10 s
122 add ebx,edx
123 mov [si],ebx
124 .err: ret
127 ;
128 ; "totaltimeout" command
129 ;
130 pc_totaltimeout:
132 ;
133 ; Generic integer variable setting commands:
134 ; "prompt", "implicit"
135 ;
136 pc_setint16:
137 push ax
138 call getint
139 pop si
140 jc .err
141 mov [si],bx
142 .err: ret
144 ;
145 ; Generic file-processing commands:
146 ; "display", "font", "kbdmap"
147 ;
148 pc_filecmd: push ax ; Function to tailcall
149 call pc_getline
150 mov di,MNameBuf
151 push di
152 call mangle_name
153 pop di
154 call searchdir ; tailcall
155 jnz .ok
156 pop ax ; Drop the successor function
157 .ok: ret ; Tailcall if OK, error return
159 ;
160 ; "serial" command
161 ;
162 pc_serial: call getint
163 jc .err
164 push bx ; Serial port #
165 call skipspace
166 jnc .ok
167 pop bx
168 .err: ret
169 .ok:
170 call ungetc
171 call getint
172 mov [FlowControl], word 0 ; Default to no flow control
173 jc .nobaud
174 .valid_baud:
175 push ebx
176 call skipspace
177 jc .no_flow
178 call ungetc
179 call getint ; Hardware flow control?
180 jnc .valid_flow
181 .no_flow:
182 xor bx,bx ; Default -> no flow control
183 .valid_flow:
184 and bh,0Fh ; FlowIgnore
185 shl bh,4
186 mov [FlowIgnore],bh
187 mov bh,bl
188 and bx,0F003h ; Valid bits
189 mov [FlowControl],bx
190 pop ebx ; Baud rate
191 jmp short .parse_baud
192 .nobaud:
193 mov ebx,DEFAULT_BAUD ; No baud rate given
194 .parse_baud:
195 pop di ; Serial port #
196 cmp ebx,byte 75
197 jb .err ; < 75 baud == bogus
198 mov eax,BAUD_DIVISOR
199 cdq
200 div ebx
201 mov [BaudDivisor],ax
202 push ax ; Baud rate divisor
203 cmp di,3
204 ja .port_is_io ; If port > 3 then port is I/O addr
205 shl di,1
206 mov di,[di+serial_base] ; Get the I/O port from the BIOS
207 .port_is_io:
208 mov [SerialPort],di
210 ;
211 ; Begin code to actually set up the serial port
212 ;
213 lea dx,[di+3] ; DX -> LCR
214 mov al,83h ; Enable DLAB
215 call slow_out
217 pop ax ; Divisor
218 mov dx,di ; DX -> LS
219 call slow_out
221 inc dx ; DX -> MS
222 mov al,ah
223 call slow_out
225 mov al,03h ; Disable DLAB
226 inc dx ; DX -> LCR
227 inc dx
228 call slow_out
230 in al,dx ; Read back LCR (detect missing hw)
231 cmp al,03h ; If nothing here we'll read 00 or FF
232 jne .serial_port_bad ; Assume serial port busted
233 dec dx
234 dec dx ; DX -> IER
235 xor al,al ; IRQ disable
236 call slow_out
238 inc dx ; DX -> FCR/IIR
239 mov al,01h
240 call slow_out ; Enable FIFOs if present
241 in al,dx
242 cmp al,0C0h ; FIFOs enabled and usable?
243 jae .fifo_ok
244 xor ax,ax ; Disable FIFO if unusable
245 call slow_out
246 .fifo_ok:
248 inc dx
249 inc dx ; DX -> MCR
250 in al,dx
251 or al,[FlowOutput] ; Assert bits
252 call slow_out
254 ; Show some life
255 mov si,syslinux_banner
256 call write_serial_str
257 mov si,copyright_str
258 call write_serial_str
259 ret
261 .serial_port_bad:
262 mov [SerialPort], word 0
263 ret
265 ;
266 ; "F"-key command
267 ;
268 pc_fkey: push ax
269 call pc_getline
270 pop di
271 call mangle_name ; Mangle file name
272 ret
274 ;
275 ; "label" command
276 ;
277 pc_label: call commit_vk ; Commit any current vkernel
278 mov di,VKernelBuf ; Erase the vkernelbuf for better compression
279 mov cx,(vk_size >> 1)
280 xor ax,ax
281 rep stosw
282 call pc_getline
283 mov di,VKernelBuf+vk_vname
284 call mangle_name ; Mangle virtual name
285 mov byte [VKernel],1 ; We've seen a "label" statement
286 mov si,VKernelBuf+vk_vname ; By default, rname == vname
287 mov di,VKernelBuf+vk_rname
288 mov cx,FILENAME_MAX
289 rep movsb
290 mov si,AppendBuf ; Default append==global append
291 mov di,VKernelBuf+vk_append
292 mov cx,[AppendLen]
293 mov [VKernelBuf+vk_appendlen],cx
294 rep movsb
295 %if IS_PXELINUX ; PXELINUX only
296 mov al,[IPAppend] ; Default ipappend==global ipappend
297 mov [VKernelBuf+vk_ipappend],al
298 %endif
299 ret
301 ;
302 ; "say" command
303 ;
304 pc_say: call pc_getline ; "say" command
305 call writestr
306 jmp crlf ; tailcall
308 ;
309 ; "text" command; ignore everything until we get an "endtext" line
310 ;
311 pc_text: call pc_getline ; Ignore rest of line
312 .loop:
313 call pc_getline
314 .skipspace:
315 lodsb
316 and al,al
317 jz .loop
318 cmp al,' '
319 jbe .skipspace
321 dec si
322 lodsd
323 and eax,0xfdfdfdfd
324 cmp eax,'ENDT'
325 jne .loop
326 lodsd
327 and eax,0x00fdfdfd
328 cmp eax,'EXT'
329 jne .loop
330 ; If we get here we hit ENDTEXT
331 ret
333 ;
334 ; Comment line
335 ;
336 pc_comment: ; Fall into pc_getline
338 ;
339 ; Common subroutine: load line into trackbuf; returns with SI -> trackbuf
340 ;
341 pc_getline: mov di,trackbuf
342 push di
343 call getline
344 xor al,al
345 stosb ; Null-terminate
346 pop si
347 ret
349 ;
350 ; Main loop for configuration file parsing
351 ;
352 parse_config:
353 mov di,VKernelBuf ; Clear VKernelBuf at start
354 xor ax,ax
355 mov cx,vk_size
356 rep stosb
357 .again:
358 call getcommand
359 jnc .again ; If not EOF do it again
360 ;
361 ; The fall through to commit_vk to commit any final
362 ; VKernel being read
363 ;
364 ;
365 ; commit_vk: Store the current VKernelBuf into buffer segment
366 ;
367 commit_vk:
368 ; For better compression, clean up the append field
369 mov ax,[VKernelBuf+vk_appendlen]
370 mov di,VKernelBuf+vk_append
371 add di,ax
372 mov cx,max_cmd_len+1
373 sub cx,ax
374 xor ax,ax
375 rep stosb
377 ; Pack temporarily into trackbuf
378 mov si,VKernelBuf
379 mov di,trackbuf
380 mov cx,vk_size
381 call rllpack
382 ; Now DX = number of bytes
383 mov di,[VKernelBytes]
384 mov cx,dx
385 add dx,di
386 jc .overflow ; If > 1 segment
387 mov [VKernelBytes],dx
388 mov si,trackbuf
389 push es
390 push word vk_seg
391 pop es
392 rep movsb
393 pop es
394 ret
395 .overflow:
396 mov si,vk_overflow_msg
397 call writestr
398 ret
400 section .data
401 vk_overflow_msg db 'Out of memory parsing config file', CR, LF, 0
403 align 4, db 0
404 KbdTimeout dd 0 ; Keyboard timeout (if any)
405 TotalTimeout dd 0 ; Total timeout (if any)
406 AppendLen dw 0 ; Bytes in append= command
407 OntimeoutLen dw 0 ; Bytes in ontimeout command
408 OnerrorLen dw 0 ; Bytes in onerror command
409 CmdLinePtr dw cmd_line_here ; Command line advancing pointer
410 ForcePrompt dw 0 ; Force prompt
411 NoEscape dw 0 ; No escape
412 AllowImplicit dw 1 ; Allow implicit kernels
413 AllowOptions dw 1 ; User-specified options allowed
414 SerialPort dw 0 ; Serial port base (or 0 for no serial port)
415 VKernelBytes dw 0 ; Number of bytes used by vkernels
416 VKernel db 0 ; Have we seen any "label" statements?
418 section .latebss
419 alignb 4 ; For the good of REP MOVSD
420 command_line resb max_cmd_len+2 ; Command line buffer
421 alignb 4
422 default_cmd resb max_cmd_len+1 ; "default" command line
424 %include "rllpack.inc"