com32/lib/sys/entry.S

   1 # -----------------------------------------------------------------------
   2 #
   3 #   Copyright 2003-2004 H. Peter Anvin - All Rights Reserved
   4 #
   5 #   Permission is hereby granted, free of charge, to any person
   6 #   obtaining a copy of this software and associated documentation
   7 #   files (the "Software"), to deal in the Software without
   8 #   restriction, including without limitation the rights to use,
   9 #   copy, modify, merge, publish, distribute, sublicense, and/or
  10 #   sell copies of the Software, and to permit persons to whom
  11 #   the Software is furnished to do so, subject to the following
  12 #   conditions:
  13 #
  14 #   The above copyright notice and this permission notice shall
  15 #   be included in all copies or substantial portions of the Software.
  16 #
  17 #   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  18 #   EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  19 #   OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  20 #   NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  21 #   HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  22 #   WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  23 #   FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  24 #   OTHER DEALINGS IN THE SOFTWARE.
  25 #
  26 # -----------------------------------------------------------------------
  27
  28 # COM32 start up code - must be linked first in the binary
  29
  30
  31                 .section ".init","ax"
  32                 .globl _start
  33                 .type _start, @function
  34 _start:
  35                 # This first instruction acts as COM32 magic number
  36                 movl $0x21cd4cff,%eax
  37
  38                 # Upwards string operations
  39                 cld
  40
  41                 # Zero the .bss segment
  42                 xorl %eax,%eax
  43                 movl $__bss_start,%edi          # Symbol provided by linker
  44                 movl $_end+3,%ecx               # Symbol provided by linker
  45                 subl %edi,%ecx
  46                 shrl $2,%ecx
  47                 rep ; stosl
  48
  49                 # Copy COM32 invocation parameters
  50                 leal 4(%esp),%esi               # Argument list
  51                 movl $__com32,%edi
  52                 movl $6,%ecx
  53                 movl %esp,-4(%edi)              # Save the initial stack ptr
  54                 cmpl (%esi),%ecx
  55                 jbe 1f
  56                 movl (%esi),%ecx
  57 1:              rep ; movsl
  58
  59                 # Parse the command line (assumes REGPARM)
  60                 movl __com32+4,%edx             # Command line
  61                 pushl %edx                      # Make space for argv
  62                 movl %esp,%eax
  63                 call __parse_argv
  64                 pushl %eax                      # Save argc
  65
  66                 # Look for library initialization functions
  67                 movl $__ctors_start, %esi
  68 2:
  69                 cmpl $__ctors_end, %esi
  70                 jae 3f
  71                 call *(%esi)
  72                 addl $4,%esi
  73                 jmp 2b
  74 #
  75 # Actually run main.  This assumes REGPARM is used!!!!
  76 #
  77 3:
  78                 popl %eax                       # argc
  79                 popl %edx                       # argv
  80                 call main
  81                 call *(__exit_handler)
  82                 hlt
  83                 .size _start, .-_start
  84
  85                 .bss
  86                 .globl __entry_esp
  87 __entry_esp:    .space 4
  88                 .globl __com32
  89 __com32:        .space 4*6