release/src/router/libiconv/gnulib-local/m4/alloca.m4

   1 # alloca.m4 serial 4 (gettext-0.18.2)
   2 dnl Copyright (C) 2002-2003, 2006, 2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ALLOCA],
   8 [
   9   dnl Work around a bug of AC_EGREP_CPP in autoconf-2.57.
  10   AC_REQUIRE([AC_PROG_CPP])
  11   AC_REQUIRE([AC_PROG_EGREP])
  12
  13   AC_REQUIRE([AC_FUNC_ALLOCA])
  14   if test $ac_cv_func_alloca_works = no; then
  15     gl_PREREQ_ALLOCA
  16   fi
  17
  18   # Define an additional variable used in the Makefile substitution.
  19
  20   AC_EGREP_CPP([Need own alloca], [
  21 #if defined __GNUC__ || defined _MSC_VER || !HAVE_ALLOCA_H
  22   Need own alloca
  23 #endif
  24     ],
  25     ALLOCA_H=alloca.h,
  26     ALLOCA_H=)
  27   AC_SUBST([ALLOCA_H])
  28   AM_CONDITIONAL([GL_GENERATE_ALLOCA_H], [test -n "$ALLOCA_H"])
  29 ])
  30
  31 # Prerequisites of lib/alloca.c.
  32 # STACK_DIRECTION is already handled by AC_FUNC_ALLOCA.
  33 AC_DEFUN([gl_PREREQ_ALLOCA], [
  34   AC_CHECK_HEADERS_ONCE(stdlib.h string.h)
  35   :
  36 ])