vala/valaconstructor.vala

   1 /* valaconstructor.vala
   2  *
   3  * Copyright (C) 2006-2010  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents a class or instance constructor.
  27  */
  28 public class Vala.Constructor : Subroutine {
  29         /**
  30          * Specifies the generated `this` parameter for instance methods.
  31          */
  32         public Parameter this_parameter { get; set; }
  33
  34         /**
  35          * Specifies whether this is an instance or a class constructor.
  36          */
  37         public MemberBinding binding { get; set; default = MemberBinding.INSTANCE; }
  38
  39         public override bool has_result {
  40                 get { return false; }
  41         }
  42
  43         /**
  44          * Creates a new constructor.
  45          *
  46          * @param source reference to source code
  47          * @return       newly created constructor
  48          */
  49         public Constructor (SourceReference? source) {
  50                 base (null, source);
  51         }
  52
  53         public override void accept (CodeVisitor visitor) {
  54                 visitor.visit_constructor (this);
  55         }
  56
  57         public override void accept_children (CodeVisitor visitor) {
  58                 if (body != null) {
  59                         body.accept (visitor);
  60                 }
  61         }
  62
  63         public override bool check (CodeContext context) {
  64                 if (checked) {
  65                         return !error;
  66                 }
  67
  68                 checked = true;
  69
  70                 this_parameter = new Parameter ("this", new ObjectType (context.analyzer.current_class));
  71                 scope.add (this_parameter.name, this_parameter);
  72
  73                 owner = context.analyzer.current_symbol.scope;
  74                 context.analyzer.current_symbol = this;
  75
  76                 if (body != null) {
  77                         body.check (context);
  78                 }
  79
  80                 foreach (DataType body_error_type in body.get_error_types ()) {
  81                         if (!((ErrorType) body_error_type).dynamic_error) {
  82                                 Report.warning (body_error_type.source_reference, "unhandled error `%s'".printf (body_error_type.to_string()));
  83                         }
  84                 }
  85
  86                 context.analyzer.current_symbol = context.analyzer.current_symbol.parent_symbol;
  87
  88                 return !error;
  89         }
  90 }