vala/valaswitchlabel.vala

   1 /* valaswitchlabel.vala
   2  *
   3  * Copyright (C) 2006-2010  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents a switch label in the source code.
  27  */
  28 public class Vala.SwitchLabel : CodeNode {
  29         /**
  30          * Specifies the label expression.
  31          */
  32         public Expression expression { get; set; }
  33
  34         public weak SwitchSection section { get; set; }
  35
  36         /**
  37          * Creates a new switch case label.
  38          *
  39          * @param expr   label expression
  40          * @param source reference to source code
  41          * @return       newly created switch case label
  42          */
  43         public SwitchLabel (Expression expr, SourceReference? source = null) {
  44                 expression = expr;
  45                 source_reference = source;
  46         }
  47
  48         /**
  49          * Creates a new switch default label.
  50          *
  51          * @param source reference to source code
  52          * @return       newly created switch default label
  53          */
  54         public SwitchLabel.with_default (SourceReference? source = null) {
  55                 source_reference = source;
  56         }
  57
  58         public override void accept (CodeVisitor visitor) {
  59                 visitor.visit_switch_label (this);
  60         }
  61
  62         public override void accept_children (CodeVisitor visitor) {
  63                 if (expression != null) {
  64                         expression.accept (visitor);
  65
  66                         visitor.visit_end_full_expression (expression);
  67                 }
  68         }
  69
  70         public override bool check (CodeContext context) {
  71                 if (expression != null) {
  72                         var switch_statement = (SwitchStatement) section.parent_node;
  73
  74                         // enum-type inference
  75                         var condition_target_type = switch_statement.expression.target_type;
  76                         if (expression.symbol_reference == null && condition_target_type != null && condition_target_type.data_type is Enum) {
  77                                 var enum_type = (Enum) condition_target_type.data_type;
  78                                 foreach (var val in enum_type.get_values ()) {
  79                                         if (expression.to_string () == val.name) {
  80                                                 expression.target_type = condition_target_type.copy ();
  81                                                 expression.symbol_reference = val;
  82                                                 break;
  83                                         }
  84                                 }
  85                         }
  86
  87                         expression.check (context);
  88
  89                         if (!expression.is_constant ()) {
  90                                 error = true;
  91                                 Report.error (expression.source_reference, "Expression must be constant");
  92                                 return false;
  93                         }
  94                         if (!expression.value_type.compatible (switch_statement.expression.value_type)) {
  95                                 error = true;
  96                                 Report.error (expression.source_reference, "Cannot convert from `%s' to `%s'".printf (expression.value_type.to_string (), switch_statement.expression.value_type.to_string ()));
  97                                 return false;
  98                         }
  99                 }
 100
 101                 return true;
 102         }
 103
 104         public override void emit (CodeGenerator codegen) {
 105                 codegen.visit_switch_label (this);
 106         }
 107 }