ccode/valaccodevariabledeclarator.vala

   1 /* valaccodevariabledeclarator.vala
   2  *
   3  * Copyright (C) 2006-2009  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents a variable declarator in the C code.
  27  */
  28 public class Vala.CCodeVariableDeclarator : CCodeDeclarator {
  29         /**
  30          * The variable name.
  31          */
  32         public string name { get; set; }
  33
  34         /**
  35          * The optional initializer expression.
  36          */
  37         public CCodeExpression? initializer { get; set; }
  38
  39         /**
  40          * The optional declarator suffix.
  41          */
  42         public CCodeDeclaratorSuffix? declarator_suffix { get; set; }
  43
  44         /**
  45          * Initializer only used to zero memory, safe to initialize as part
  46          * of declaration at beginning of block instead of separate assignment.
  47          */
  48         public bool init0 { get; set; }
  49
  50         public CCodeVariableDeclarator (string name, CCodeExpression? initializer = null, CCodeDeclaratorSuffix? declarator_suffix = null) {
  51                 this.name = name;
  52                 this.initializer = initializer;
  53                 this.declarator_suffix = declarator_suffix;
  54         }
  55
  56         public CCodeVariableDeclarator.zero (string name, CCodeExpression? initializer, CCodeDeclaratorSuffix? declarator_suffix = null) {
  57                 this.name = name;
  58                 this.initializer = initializer;
  59                 this.declarator_suffix = declarator_suffix;
  60                 this.init0 = true;
  61         }
  62
  63         public override void write (CCodeWriter writer) {
  64                 writer.write_string (name);
  65
  66                 if (declarator_suffix != null) {
  67                         declarator_suffix.write (writer);
  68                 }
  69
  70                 if (initializer != null) {
  71                         writer.write_string (" = ");
  72                         initializer.write (writer);
  73                 }
  74         }
  75
  76         public override void write_declaration (CCodeWriter writer) {
  77                 writer.write_string (name);
  78
  79                 if (declarator_suffix != null) {
  80                         declarator_suffix.write (writer);
  81                 }
  82
  83                 if (initializer != null && init0) {
  84                         writer.write_string (" = ");
  85                         initializer.write (writer);
  86                 }
  87         }
  88
  89         public override void write_initialization (CCodeWriter writer) {
  90                 if (initializer != null && !init0) {
  91                         writer.write_indent (line);
  92
  93                         writer.write_string (name);
  94                         writer.write_string (" = ");
  95                         initializer.write (writer);
  96
  97                         writer.write_string (";");
  98                         writer.write_newline ();
  99                 }
 100         }
 101 }
 102
 103 public class Vala.CCodeDeclaratorSuffix {
 104         bool array;
 105         CCodeExpression? array_length;
 106
 107         public CCodeDeclaratorSuffix.with_array (CCodeExpression? array_length = null) {
 108                 this.array_length = array_length;
 109                 array = true;
 110         }
 111
 112         public void write (CCodeWriter writer) {
 113                 if (array) {
 114                         writer.write_string ("[");
 115                         if (array_length != null) {
 116                                 array_length.write (writer);
 117                         }
 118                         writer.write_string ("]");
 119                 }
 120         }
 121 }