configure.ac

   1 AC_INIT([vala], m4_esyscmd([build-aux/git-version-gen .tarball-version]), [j@bitron.ch], [vala])
   2 AC_CONFIG_SRCDIR([Makefile.am])
   3 AC_CONFIG_AUX_DIR([build-aux])
   4 AC_CONFIG_HEADERS(config.h)
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AM_INIT_AUTOMAKE([dist-bzip2])
   7 AM_MAINTAINER_MODE
   8
   9 PACKAGE_SUFFIX=-0.14
  10 AC_SUBST(PACKAGE_SUFFIX)
  11 AC_DEFINE_UNQUOTED(PACKAGE_SUFFIX, "$PACKAGE_SUFFIX", [Define to the suffix of this package])
  12
  13 program_transform_name="s,\$\$,${PACKAGE_SUFFIX},"
  14
  15 AC_SUBST(pkgdatadir, [${datadir}/vala${PACKAGE_SUFFIX}])
  16
  17 # Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_DISABLE_STATIC
  21 AC_PROG_LIBTOOL
  22 AC_PROG_LN_S
  23
  24 AC_PROG_LEX
  25 if test "$LEX" = :; then
  26         AC_MSG_ERROR([flex not found but required])
  27 fi
  28
  29 AC_CHECK_PROGS(YACC, 'bison -y' byacc yacc, :)
  30 if test "$YACC" = :; then
  31         AC_MSG_ERROR([bison not found but required])
  32 fi
  33
  34 AC_PATH_PROG(VALAC, valac, valac)
  35 AC_SUBST(VALAC)
  36
  37 VALAFLAGS="$VALAFLAGS --disable-version-header"
  38
  39 AC_SUBST(VALAFLAGS)
  40 AC_SUBST(CFLAGS)
  41 AC_SUBST(CPPFLAGS)
  42 AC_SUBST(LDFLAGS)
  43
  44 AC_ARG_ENABLE(unversioned, AS_HELP_STRING([--disable-unversioned], [Disable unversioned binaries]), enable_unversioned=$enableval, enable_unversioned=yes)
  45 AM_CONDITIONAL(ENABLE_UNVERSIONED, test x$enable_unversioned = xyes)
  46
  47 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [Enable coverage analysis]), enable_coverage=$enableval, enable_coverage=no)
  48 AM_CONDITIONAL(ENABLE_COVERAGE, test x$enable_coverage = xyes)
  49
  50 if test "$enable_coverage" = "yes"; then
  51         COVERAGE_VALAFLAGS="-g"
  52         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
  53         COVERAGE_LIBS="-lgcov"
  54 else
  55         COVERAGE_VALAFLAGS=
  56         COVERAGE_CFLAGS=
  57         COVERAGE_LIBS=
  58 fi
  59 AC_SUBST(COVERAGE_VALAFLAGS)
  60 AC_SUBST(COVERAGE_CFLAGS)
  61 AC_SUBST(COVERAGE_LIBS)
  62
  63 AC_ARG_ENABLE(vapigen, AS_HELP_STRING([--enable-vapigen], [Enable VAPI generator]), enable_vapigen=$enableval, enable_vapigen=no)
  64 AM_CONDITIONAL(ENABLE_VAPIGEN, test x$enable_vapigen = xyes)
  65
  66 if test "$enable_vapigen" = "yes"; then
  67   vapigen_decl="vapigen=\${bindir}/vapigen${PACKAGE_SUFFIX}"
  68   gen_introspect_decl="gen_introspect=\${libdir}/vala${PACKAGE_SUFFIX}/gen-introspect${PACKAGE_SUFFIX}"
  69   vala_gen_introspect_decl="vala_gen_introspect=\${bindir}/vala-gen-introspect${PACKAGE_SUFFIX}"
  70 else
  71   vapigen_decl=''
  72   gen_introspect_decl=''
  73   vala_gen_introspect_decl=''
  74 fi
  75 AC_SUBST(vapigen_decl)
  76 AC_SUBST(gen_introspect_decl)
  77 AC_SUBST(vala_gen_introspect_decl)
  78
  79 GLIB_REQUIRED=2.16.0
  80
  81 PKG_CHECK_MODULES(GLIB, glib-2.0 >= $GLIB_REQUIRED gobject-2.0 >= $GLIB_REQUIRED)
  82
  83 AC_SUBST(GLIB_CFLAGS)
  84 AC_SUBST(GLIB_LIBS)
  85
  86 PKG_CHECK_MODULES(GMODULE, gmodule-2.0 >= $GLIB_REQUIRED)
  87
  88 AC_SUBST(GMODULE_CFLAGS)
  89 AC_SUBST(GMODULE_LIBS)
  90
  91 PKG_CHECK_MODULES(GTHREAD, gthread-2.0 >= $GLIB_REQUIRED)
  92
  93 AC_SUBST(GTHREAD_CFLAGS)
  94 AC_SUBST(GTHREAD_LIBS)
  95
  96 AC_PATH_PROG([XSLTPROC], [xsltproc], :)
  97 AM_CONDITIONAL(HAVE_XSLTPROC, test "$XSLTPROC" != :)
  98
  99 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
 100
 101 AC_CONFIG_FILES([Makefile
 102            libvala.pc
 103            gee/Makefile
 104            ccode/Makefile
 105            vala/Makefile
 106            codegen/Makefile
 107            compiler/Makefile
 108            vapi/Makefile
 109            tests/Makefile
 110            doc/Makefile
 111            doc/vala/Makefile
 112            gobject-introspection/Makefile
 113            vapigen/Makefile
 114            vapigen/vala-gen-introspect/Makefile
 115            vapigen/vala-gen-introspect/vala-gen-introspect])
 116
 117 AC_OUTPUT