vala/valaenumvalue.vala

   1 /* valaenumvalue.vala
   2  *
   3  * Copyright (C) 2006-2010  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents an enum member in the source code.
  27  */
  28 public class Vala.EnumValue : Constant {
  29         /**
  30          * Creates a new enum value with the specified numerical representation.
  31          *
  32          * @param name  enum value name
  33          * @param value numerical representation
  34          * @return      newly created enum value
  35          */
  36         public EnumValue (string name, Expression? value, SourceReference? source_reference = null, Comment? comment = null) {
  37                 base (name, null, value, source_reference, comment);
  38         }
  39
  40         /**
  41          * Returns the string literal of this signal to be used in C code.
  42          * (FIXME: from vlaasignal.vala)
  43          *
  44          * @return string literal to be used in C code
  45          */
  46         public CCodeConstant get_canonical_cconstant () {
  47                 var str = new StringBuilder ("\"");
  48
  49                 string i = name;
  50
  51                 while (i.length > 0) {
  52                         unichar c = i.get_char ();
  53                         if (c == '_') {
  54                                 str.append_c ('-');
  55                         } else {
  56                                 str.append_unichar (c.tolower ());
  57                         }
  58
  59                         i = i.next_char ();
  60                 }
  61
  62                 str.append_c ('"');
  63
  64                 return new CCodeConstant (str.str);
  65         }
  66
  67         public override void accept (CodeVisitor visitor) {
  68                 visitor.visit_enum_value (this);
  69         }
  70
  71         public override void accept_children (CodeVisitor visitor) {
  72                 if (value != null) {
  73                         value.accept (visitor);
  74                 }
  75         }
  76
  77         public override string get_default_cname () {
  78                 var en = (Enum) parent_symbol;
  79                 return "%s%s".printf (en.get_cprefix (), name);
  80         }
  81
  82         public override bool check (CodeContext context) {
  83                 if (checked) {
  84                         return !error;
  85                 }
  86
  87                 checked = true;
  88
  89                 process_attributes ();
  90
  91                 if (value != null) {
  92                         value.check (context);
  93                 }
  94
  95                 return !error;
  96         }
  97 }