vala/valaintegerliteral.vala

   1 /* valaintegerliteral.vala
   2  *
   3  * Copyright (C) 2006-2008  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents an integer literal in the source code.
  27  */
  28 public class Vala.IntegerLiteral : Literal {
  29         /**
  30          * The literal value.
  31          */
  32         public string value { get; set; }
  33
  34         /**
  35          * Creates a new integer literal.
  36          *
  37          * @param i      literal value
  38          * @param source reference to source code
  39          * @return       newly created integer literal
  40          */
  41         public IntegerLiteral (string i, SourceReference? source = null) {
  42                 value = i;
  43                 source_reference = source;
  44         }
  45
  46         public override void accept (CodeVisitor visitor) {
  47                 visitor.visit_integer_literal (this);
  48
  49                 visitor.visit_expression (this);
  50         }
  51
  52         public override string to_string () {
  53                 return value;
  54         }
  55
  56         /**
  57          * Returns the type name of the value this literal represents.
  58          *
  59          * @return the name of literal type
  60          */
  61         public string get_type_name () {
  62                 string number = value;
  63
  64                 int l = 0;
  65                 while (number.has_suffix ("l") || number.has_suffix ("L")) {
  66                         l++;
  67                         number = number.ndup (number.size () - 1);
  68                 }
  69
  70                 bool u = false;
  71                 if (number.has_suffix ("u") || number.has_suffix ("U")) {
  72                         u = true;
  73                         number = number.ndup (number.size () - 1);
  74                 }
  75
  76                 int64 n = number.to_int64 ();
  77                 if (!u && n > 0x7fffffff) {
  78                         // value doesn't fit into signed 32-bit
  79                         l = 2;
  80                 } else if (u && n > 0xffffffff) {
  81                         // value doesn't fit into unsigned 32-bit
  82                         l = 2;
  83                 }
  84
  85                 if (l == 0) {
  86                         if (u) {
  87                                 return "uint";
  88                         } else {
  89                                 return "int";
  90                         }
  91                 } else if (l == 1) {
  92                         if (u) {
  93                                 return "ulong";
  94                         } else {
  95                                 return "long";
  96                         }
  97                 } else {
  98                         if (u) {
  99                                 return "uint64";
 100                         } else {
 101                                 return "int64";
 102                         }
 103                 }
 104         }
 105
 106         public override bool is_pure () {
 107                 return true;
 108         }
 109
 110         public override bool check (SemanticAnalyzer analyzer) {
 111                 if (checked) {
 112                         return !error;
 113                 }
 114
 115                 checked = true;
 116
 117                 value_type = new IntegerType ((Struct) analyzer.root_symbol.scope.lookup (get_type_name ()), value, get_type_name ());
 118
 119                 return !error;
 120         }
 121 }