vala/valaforstatement.vala

   1 /* valaforstatement.vala
   2  *
   3  * Copyright (C) 2006-2009  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24 using Gee;
  25
  26 /**
  27  * Represents a for iteration statement in the source code.
  28  */
  29 public class Vala.ForStatement : CodeNode, Statement {
  30         /**
  31          * Specifies the loop condition.
  32          */
  33         public Expression? condition {
  34                 get {
  35                         return _condition;
  36                 }
  37                 set {
  38                         _condition = value;
  39                         if (_condition != null) {
  40                                 _condition.parent_node = this;
  41                         }
  42                 }
  43         }
  44
  45         /**
  46          * Specifies the loop body.
  47          */
  48         public Block body {
  49                 get {
  50                         return _body;
  51                 }
  52                 set {
  53                         _body = value;
  54                         _body.parent_node = this;
  55                 }
  56         }
  57
  58         private Gee.List<Expression> initializer = new ArrayList<Expression> ();
  59         private Gee.List<Expression> iterator = new ArrayList<Expression> ();
  60
  61         private Expression _condition;
  62         private Block _body;
  63
  64         /**
  65          * Creates a new for statement.
  66          *
  67          * @param cond             loop condition
  68          * @param body             loop body
  69          * @param source_reference reference to source code
  70          * @return                 newly created for statement
  71          */
  72         public ForStatement (Expression? condition, Block body, SourceReference? source_reference = null) {
  73                 this.condition = condition;
  74                 this.body = body;
  75                 this.source_reference = source_reference;
  76         }
  77
  78         /**
  79          * Appends the specified expression to the list of initializers.
  80          *
  81          * @param init an initializer expression
  82          */
  83         public void add_initializer (Expression init) {
  84                 init.parent_node = this;
  85                 initializer.add (init);
  86         }
  87
  88         /**
  89          * Returns a copy of the list of initializers.
  90          *
  91          * @return initializer list
  92          */
  93         public Gee.List<Expression> get_initializer () {
  94                 return new ReadOnlyList<Expression> (initializer);
  95         }
  96
  97         /**
  98          * Appends the specified expression to the iterator.
  99          *
 100          * @param iter an iterator expression
 101          */
 102         public void add_iterator (Expression iter) {
 103                 iter.parent_node = this;
 104                 iterator.add (iter);
 105         }
 106
 107         /**
 108          * Returns a copy of the iterator.
 109          *
 110          * @return iterator
 111          */
 112         public Gee.List<Expression> get_iterator () {
 113                 return new ReadOnlyList<Expression> (iterator);
 114         }
 115
 116         public override void accept (CodeVisitor visitor) {
 117                 visitor.visit_for_statement (this);
 118         }
 119
 120         public override void accept_children (CodeVisitor visitor) {
 121                 foreach (Expression init_expr in initializer) {
 122                         init_expr.accept (visitor);
 123                         visitor.visit_end_full_expression (init_expr);
 124                 }
 125
 126                 if (condition != null) {
 127                         condition.accept (visitor);
 128
 129                         visitor.visit_end_full_expression (condition);
 130                 }
 131
 132                 foreach (Expression it_expr in iterator) {
 133                         it_expr.accept (visitor);
 134                         visitor.visit_end_full_expression (it_expr);
 135                 }
 136
 137                 body.accept (visitor);
 138         }
 139
 140         bool always_true (Expression condition) {
 141                 var literal = condition as BooleanLiteral;
 142                 return (literal != null && literal.value);
 143         }
 144
 145         public override bool check (SemanticAnalyzer analyzer) {
 146                 // convert to simple loop
 147
 148                 var block = new Block (source_reference);
 149
 150                 // initializer
 151                 foreach (var init_expr in initializer) {
 152                         block.add_statement (new ExpressionStatement (init_expr, init_expr.source_reference));
 153                 }
 154
 155                 // do not generate if block if condition is always true
 156                 if (condition != null && !always_true (condition)) {
 157                         // condition
 158                         var if_condition = new UnaryExpression (UnaryOperator.LOGICAL_NEGATION, condition, condition.source_reference);
 159                         var true_block = new Block (condition.source_reference);
 160                         true_block.add_statement (new BreakStatement (condition.source_reference));
 161                         var if_stmt = new IfStatement (if_condition, true_block, null, condition.source_reference);
 162                         body.insert_statement (0, if_stmt);
 163                 }
 164
 165                 // iterator
 166                 var first_local = new LocalVariable (analyzer.bool_type.copy (), get_temp_name (), new BooleanLiteral (true, source_reference), source_reference);
 167                 block.add_statement (new DeclarationStatement (first_local, source_reference));
 168
 169                 var iterator_block = new Block (source_reference);
 170                 foreach (var it_expr in iterator) {
 171                         iterator_block.add_statement (new ExpressionStatement (it_expr, it_expr.source_reference));
 172                 }
 173
 174                 var first_if = new IfStatement (new UnaryExpression (UnaryOperator.LOGICAL_NEGATION, new MemberAccess.simple (first_local.name, source_reference), source_reference), iterator_block, null, source_reference);
 175                 body.insert_statement (0, first_if);
 176                 body.insert_statement (1, new ExpressionStatement (new Assignment (new MemberAccess.simple (first_local.name, source_reference), new BooleanLiteral (false, source_reference), AssignmentOperator.SIMPLE, source_reference), source_reference));
 177
 178                 block.add_statement (new Loop (body, source_reference));
 179
 180                 var parent_block = (Block) parent_node;
 181                 parent_block.replace_statement (this, block);
 182
 183                 return block.check (analyzer);
 184         }
 185 }