vala/valaunaryexpression.vala

   1 /* valaunaryexpression.vala
   2  *
   3  * Copyright (C) 2006-2009  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using Gee;
  24
  25 /**
  26  * Represents an expression with one operand in the source code.
  27  *
  28  * Supports +, -, !, ~, ref, out.
  29  */
  30 public class Vala.UnaryExpression : Expression {
  31         /**
  32          * The unary operator.
  33          */
  34         public UnaryOperator operator { get; set; }
  35
  36         /**
  37          * The operand.
  38          */
  39         public Expression inner {
  40                 get {
  41                         return _inner;
  42                 }
  43                 set {
  44                         _inner = value;
  45                         _inner.parent_node = this;
  46                 }
  47         }
  48
  49         private Expression _inner;
  50
  51         /**
  52          * Creates a new unary expression.
  53          *
  54          * @param op     unary operator
  55          * @param inner  operand
  56          * @param source reference to source code
  57          * @return       newly created binary expression
  58          */
  59         public UnaryExpression (UnaryOperator op, Expression _inner, SourceReference source) {
  60                 operator = op;
  61                 inner = _inner;
  62                 source_reference = source;
  63         }
  64
  65         public override void accept (CodeVisitor visitor) {
  66                 visitor.visit_unary_expression (this);
  67
  68                 visitor.visit_expression (this);
  69         }
  70
  71         public override void accept_children (CodeVisitor visitor) {
  72                 inner.accept (visitor);
  73         }
  74
  75         public override void replace_expression (Expression old_node, Expression new_node) {
  76                 if (inner == old_node) {
  77                         inner = new_node;
  78                 }
  79         }
  80
  81         private string get_operator_string () {
  82                 switch (_operator) {
  83                 case UnaryOperator.PLUS: return "+";
  84                 case UnaryOperator.MINUS: return "-";
  85                 case UnaryOperator.LOGICAL_NEGATION: return "!";
  86                 case UnaryOperator.BITWISE_COMPLEMENT: return "~";
  87                 case UnaryOperator.INCREMENT: return "++";
  88                 case UnaryOperator.DECREMENT: return "--";
  89                 case UnaryOperator.REF: return "ref ";
  90                 case UnaryOperator.OUT: return "out ";
  91                 }
  92
  93                 assert_not_reached ();
  94         }
  95
  96         public override string to_string () {
  97                 return get_operator_string () + _inner.to_string ();
  98         }
  99
 100         public override bool is_pure () {
 101                 if (operator == UnaryOperator.INCREMENT || operator == UnaryOperator.DECREMENT) {
 102                         return false;
 103                 }
 104
 105                 return inner.is_pure ();
 106         }
 107
 108         bool is_numeric_type (DataType type) {
 109                 if (!(type.data_type is Struct)) {
 110                         return false;
 111                 }
 112
 113                 var st = (Struct) type.data_type;
 114                 return st.is_integer_type () || st.is_floating_type ();
 115         }
 116
 117         bool is_integer_type (DataType type) {
 118                 if (!(type.data_type is Struct)) {
 119                         return false;
 120                 }
 121
 122                 var st = (Struct) type.data_type;
 123                 return st.is_integer_type ();
 124         }
 125
 126         MemberAccess? find_member_access (Expression expr) {
 127                 if (expr is MemberAccess) {
 128                         return (MemberAccess) expr;
 129                 }
 130
 131                 return null;
 132         }
 133
 134         public override bool check (SemanticAnalyzer analyzer) {
 135                 if (checked) {
 136                         return !error;
 137                 }
 138
 139                 checked = true;
 140
 141                 if (operator == UnaryOperator.REF || operator == UnaryOperator.OUT) {
 142                         inner.lvalue = true;
 143                         inner.target_type = target_type;
 144                 }
 145
 146                 if (!inner.check (analyzer)) {
 147                         /* if there was an error in the inner expression, skip type check */
 148                         error = true;
 149                         return false;
 150                 }
 151
 152                 if (inner.value_type is FieldPrototype) {
 153                         error = true;
 154                         Report.error (inner.source_reference, "Access to instance member `%s' denied".printf (inner.symbol_reference.get_full_name ()));
 155                         return false;
 156                 }
 157
 158                 if (operator == UnaryOperator.PLUS || operator == UnaryOperator.MINUS) {
 159                         // integer or floating point type
 160                         if (!is_numeric_type (inner.value_type)) {
 161                                 error = true;
 162                                 Report.error (source_reference, "Operator not supported for `%s'".printf (inner.value_type.to_string ()));
 163                                 return false;
 164                         }
 165
 166                         value_type = inner.value_type;
 167                 } else if (operator == UnaryOperator.LOGICAL_NEGATION) {
 168                         // boolean type
 169                         if (!inner.value_type.compatible (analyzer.bool_type)) {
 170                                 error = true;
 171                                 Report.error (source_reference, "Operator not supported for `%s'".printf (inner.value_type.to_string ()));
 172                                 return false;
 173                         }
 174
 175                         value_type = inner.value_type;
 176                 } else if (operator == UnaryOperator.BITWISE_COMPLEMENT) {
 177                         // integer type
 178                         if (!is_integer_type (inner.value_type)) {
 179                                 error = true;
 180                                 Report.error (source_reference, "Operator not supported for `%s'".printf (inner.value_type.to_string ()));
 181                                 return false;
 182                         }
 183
 184                         value_type = inner.value_type;
 185                 } else if (operator == UnaryOperator.INCREMENT ||
 186                            operator == UnaryOperator.DECREMENT) {
 187                         // integer type
 188                         if (!is_integer_type (inner.value_type)) {
 189                                 error = true;
 190                                 Report.error (source_reference, "Operator not supported for `%s'".printf (inner.value_type.to_string ()));
 191                                 return false;
 192                         }
 193
 194                         var ma = find_member_access (inner);
 195                         if (ma == null) {
 196                                 error = true;
 197                                 Report.error (source_reference, "Prefix operators not supported for this expression");
 198                                 return false;
 199                         }
 200
 201                         var old_value = new MemberAccess (ma.inner, ma.member_name, inner.source_reference);
 202                         var bin = new BinaryExpression (operator == UnaryOperator.INCREMENT ? BinaryOperator.PLUS : BinaryOperator.MINUS, old_value, new IntegerLiteral ("1"), source_reference);
 203
 204                         var assignment = new Assignment (ma, bin, AssignmentOperator.SIMPLE, source_reference);
 205                         assignment.target_type = target_type;
 206                         analyzer.replaced_nodes.add (this);
 207                         parent_node.replace_expression (this, assignment);
 208                         assignment.check (analyzer);
 209                         return true;
 210                 } else if (operator == UnaryOperator.REF || operator == UnaryOperator.OUT) {
 211                         if (inner.symbol_reference is Field || inner.symbol_reference is FormalParameter || inner.symbol_reference is LocalVariable) {
 212                                 // ref and out can only be used with fields, parameters, and local variables
 213                                 lvalue = true;
 214                                 value_type = inner.value_type;
 215                         } else {
 216                                 error = true;
 217                                 Report.error (source_reference, "ref and out method arguments can only be used with fields, parameters, and local variables");
 218                                 return false;
 219                         }
 220                 } else {
 221                         error = true;
 222                         Report.error (source_reference, "internal error: unsupported unary operator");
 223                         return false;
 224                 }
 225
 226                 return !error;
 227         }
 228
 229         public override void get_defined_variables (Collection<LocalVariable> collection) {
 230                 inner.get_defined_variables (collection);
 231                 if (operator == UnaryOperator.OUT || operator == UnaryOperator.REF) {
 232                         var local = inner.symbol_reference as LocalVariable;
 233                         if (local != null) {
 234                                 collection.add (local);
 235                         }
 236                 }
 237         }
 238
 239         public override void get_used_variables (Collection<LocalVariable> collection) {
 240                 if (operator != UnaryOperator.OUT) {
 241                         inner.get_used_variables (collection);
 242                 }
 243         }
 244 }
 245
 246 public enum Vala.UnaryOperator {
 247         NONE,
 248         PLUS,
 249         MINUS,
 250         LOGICAL_NEGATION,
 251         BITWISE_COMPLEMENT,
 252         INCREMENT,
 253         DECREMENT,
 254         REF,
 255         OUT
 256 }