docs/lib/vg-html-chunk.xsl

   1 <?xml version="1.0"?> <!-- -*- sgml -*- -->
   2 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   3
   4 <!-- import the common styles -->
   5 <xsl:import href="vg-html-common.xsl"/>
   6
   7 <!-- use our custom html stylesheet -->
   8 <xsl:param name="html.stylesheet" select="'vg_basic.css'"/>
   9
  10 <!-- use UTF-8 encoding -->
  11 <xsl:param name="chunker.output.encoding" select="'UTF-8'"/>
  12
  13
  14 <!-- custom header for html documentation -->
  15 <xsl:template name="header.navigation">
  16   <xsl:param name="prev" select="/foo"/>
  17   <xsl:param name="next" select="/foo"/>
  18   <xsl:param name="nav.context"/>
  19
  20   <xsl:variable name="home" select="/*[1]"/>
  21   <xsl:variable name="up" select="parent::*"/>
  22
  23   <xsl:variable name="row1" select="$navig.showtitles != 0"/>
  24   <xsl:variable name="row2" select="count($prev) &gt; 0
  25                             or (count($up) &gt; 0
  26                             and generate-id($up) != generate-id($home) )
  27                             or count($next) &gt; 0"/>
  28
  29 <div>
  30 <!-- never show header nav stuff on title page -->
  31 <xsl:if test="count($prev)>0">
  32  <xsl:if test="$row1 or $row2">
  33   <table class="nav" width="100%" cellspacing="3" cellpadding="3" border="0" summary="Navigation header">
  34    <xsl:if test="$row2">
  35     <tr>
  36      <!-- prev -->
  37      <td width="22px" align="center" valign="middle">
  38       <xsl:if test="count($prev)>0">
  39        <a accesskey="p">
  40         <xsl:attribute name="href">
  41          <xsl:call-template name="href.target">
  42           <xsl:with-param name="object" select="$prev"/>
  43          </xsl:call-template>
  44         </xsl:attribute>
  45         <img src="images/prev.png" width="18" height="21" border="0">
  46          <xsl:attribute name="alt">
  47           <xsl:call-template name="gentext">
  48            <xsl:with-param name="key">nav-prev</xsl:with-param>
  49           </xsl:call-template>
  50          </xsl:attribute>
  51         </img>
  52        </a>
  53       </xsl:if>
  54      </td>
  55      <!-- up -->
  56      <xsl:if test="count($up)>0">
  57       <td width="25px" align="center" valign="middle">
  58        <a accesskey="u">
  59         <xsl:attribute name="href">
  60          <xsl:call-template name="href.target">
  61           <xsl:with-param name="object" select="$up"/>
  62          </xsl:call-template>
  63         </xsl:attribute>
  64         <img src="images/up.png" width="21" height="18" border="0">
  65          <xsl:attribute name="alt">
  66           <xsl:call-template name="gentext">
  67            <xsl:with-param name="key">nav-up</xsl:with-param>
  68           </xsl:call-template>
  69          </xsl:attribute>
  70         </img>
  71        </a>
  72       </td>
  73      </xsl:if>
  74      <!-- home -->
  75      <xsl:if test="$home != . or $nav.context = 'toc'">
  76       <td width="31px" align="center" valign="middle">
  77        <a accesskey="h">
  78         <xsl:attribute name="href">
  79          <xsl:call-template name="href.target">
  80           <xsl:with-param name="object" select="$home"/>
  81          </xsl:call-template>
  82         </xsl:attribute>
  83         <img src="images/home.png" width="27" height="20" border="0">
  84          <xsl:attribute name="alt">
  85           <xsl:call-template name="gentext">
  86            <xsl:with-param name="key">nav-up</xsl:with-param>
  87           </xsl:call-template>
  88          </xsl:attribute>
  89         </img>
  90        </a>
  91       </td>
  92      </xsl:if>
  93      <!-- chapter|section heading -->
  94      <th align="center" valign="middle">
  95        <xsl:apply-templates select="$up" mode="object.title.markup"/>
  96      </th>
  97      <!-- next -->
  98       <td width="22px" align="center" valign="middle">
  99         <xsl:if test="count($next)>0">
 100          <a accesskey="n">
 101           <xsl:attribute name="href">
 102            <xsl:call-template name="href.target">
 103             <xsl:with-param name="object" select="$next"/>
 104            </xsl:call-template>
 105           </xsl:attribute>
 106           <img src="images/next.png" width="18" height="21" border="0">
 107            <xsl:attribute name="alt">
 108             <xsl:call-template name="gentext">
 109              <xsl:with-param name="key">nav-next</xsl:with-param>
 110             </xsl:call-template>
 111            </xsl:attribute>
 112           </img>
 113          </a>
 114         </xsl:if>
 115        </td>
 116       </tr>
 117     </xsl:if>
 118    </table>
 119  </xsl:if>
 120 </xsl:if>
 121 </div>
 122 </xsl:template>
 123
 124
 125 </xsl:stylesheet>