coregrind/m_syswrap/syscall-amd64-darwin.S

   1
   2 /*--------------------------------------------------------------------*/
   3 /*--- Support for doing system calls.       syscall-amd64-darwin.S ---*/
   4 /*--------------------------------------------------------------------*/
   5
   6 /*
   7   This file is part of Valgrind, a dynamic binary instrumentation
   8   framework.
   9
  10   Copyright (C) 2000-2017 Julian Seward
  11      jseward@acm.org
  12
  13   This program is free software; you can redistribute it and/or
  14   modify it under the terms of the GNU General Public License as
  15   published by the Free Software Foundation; either version 2 of the
  16   License, or (at your option) any later version.
  17
  18   This program is distributed in the hope that it will be useful, but
  19   WITHOUT ANY WARRANTY; without even the implied warranty of
  20   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21   General Public License for more details.
  22
  23   You should have received a copy of the GNU General Public License
  24   along with this program; if not, see <http://www.gnu.org/licenses/>.
  25
  26   The GNU General Public License is contained in the file COPYING.
  27 */
  28
  29 #include "pub_core_basics_asm.h"
  30
  31 #if defined(VGP_amd64_darwin)
  32
  33 #include "pub_core_vkiscnums_asm.h"
  34 #include "libvex_guest_offsets.h"
  35
  36
  37 /*----------------------------------------------------------------*/
  38 /*
  39         Perform a syscall for the client.  This will run a syscall
  40         with the client's specific per-thread signal mask.
  41
  42         The structure of this function is such that, if the syscall is
  43         interrupted by a signal, we can determine exactly what
  44         execution state we were in with respect to the execution of
  45         the syscall by examining the value of %eip in the signal
  46         handler.  This means that we can always do the appropriate
  47         thing to precisely emulate the kernel's signal/syscall
  48         interactions.
  49
  50         The syscall number is taken from the argument, even though it
  51         should also be in guest_state->guest_RAX.  The syscall result
  52         is written back to guest_state->guest_RAX on completion.
  53
  54         Returns 0 if the syscall was successfully called (even if the
  55         syscall itself failed), or a -ve error code if one of the
  56         sigprocmasks failed (there's no way to determine which one
  57         failed).
  58
  59         VG_(fixup_guest_state_after_syscall_interrupted) does the
  60         thread state fixup in the case where we were interrupted by a
  61         signal.
  62
  63         Prototype:
  64
  65         Int ML_(do_syscall_for_client_WRK(
  66                                   Int syscallno,                // rdi
  67                                   void* guest_state,            // rsi
  68                                   const vki_sigset_t *sysmask,  // rdx
  69                                   const vki_sigset_t *postmask, // rcx
  70                                   Int sigsetSzB)                // r8
  71
  72         Note that sigsetSzB is totally ignored (and irrelevant).
  73 */
  74
  75 /* from vki_arch.h */
  76 #define VKI_SIG_SETMASK 3
  77
  78 /* DO_SYSCALL MACH|MDEP|UNIX */
  79 #define MACH 1
  80 #define MDEP 2
  81 #define UNIX 3
  82
  83 .macro DO_SYSCALL
  84         /* save callee-saved regs */
  85         pushq   %rbp
  86         movq    %rsp, %rbp
  87         // stack is now aligned
  88         pushq   %rdi  // -8(%rbp)   syscallno
  89         pushq   %rsi  // -16(%rbp)  guest_state
  90         pushq   %rdx  // -24(%rbp)  sysmask
  91         pushq   %rcx  // -32(%rbp)  postmask
  92         pushq   %r8   // -40(%rbp)  sigsetSzB
  93         // stack is now aligned
  94
  95 L_$0_1: /* Even though we can't take a signal until the sigprocmask completes,
  96            start the range early.
  97            If rip is in the range [1,2), the syscall hasn't been started yet */
  98
  99         /* Set the signal mask which should be current during the syscall. */
 100         /* GrP fixme signals
 101            DDD: JRS fixme: use __NR___pthread_sigmask, not __NR_rt_sigprocmask
 102         movq    $__NR_rt_sigprocmask, %rax      // syscall #
 103         movq    $VKI_SIG_SETMASK, %rdi          // how
 104         movq    -24(%rbp), %rsi                 // sysmask
 105         movq    -32(%rbp), %rdx                 // postmask
 106         movq    -40(%rbp), %r10                 // sigsetSzB in r10 not rcx
 107         DDD: fixme return address
 108         syscall
 109
 110         jnc     7f      // sigprocmask failed
 111         */
 112
 113         /* OK, that worked.  Now do the syscall proper. */
 114
 115         /* 6 register parameters */
 116         movq    -16(%rbp), %r11 /* r11 = VexGuestAMD64State * */
 117         movq    OFFSET_amd64_RDI(%r11), %rdi
 118         movq    OFFSET_amd64_RSI(%r11), %rsi
 119         movq    OFFSET_amd64_RDX(%r11), %rdx
 120         movq    OFFSET_amd64_RCX(%r11), %r10 /* rcx is passed in r10 instead */
 121         movq    OFFSET_amd64_R8(%r11), %r8
 122         movq    OFFSET_amd64_R9(%r11), %r9
 123         /* 2 stack parameters plus return address (ignored by syscall) */
 124         movq    OFFSET_amd64_RSP(%r11), %r11 /* r11 = simulated RSP */
 125         movq    16(%r11), %rax
 126         pushq   %rax
 127         movq    8(%r11), %rax
 128         pushq   %rax
 129         /* stack is currently aligned - return address misaligns */
 130         movq    0(%r11), %rax
 131         pushq   %rax
 132         /* syscallno */
 133         movq    -8(%rbp), %rax
 134
 135         /* If rip==2, then the syscall was either just about
 136            to start, or was interrupted and the kernel was
 137            restarting it. */
 138 L_$0_2: syscall
 139 L_$0_3: /* In the range [3, 4), the syscall result is in %rax,
 140            but hasn't been committed to RAX. */
 141
 142         /* stack contents: 3 words for syscall above, plus our prologue */
 143         setc    0(%rsp)         /* stash returned carry flag */
 144
 145         movq    -16(%rbp), %r11 /* r11 = VexGuestAMD64State * */
 146         movq    %rax, OFFSET_amd64_RAX(%r11)    /* save back to RAX */
 147         movq    %rdx, OFFSET_amd64_RDX(%r11)    /* save back to RDX */
 148
 149 .if $0 == UNIX
 150         /* save carry flag to VEX */
 151         xor     %rax, %rax
 152         movb    0(%rsp), %al
 153         movq    %rax, %rdi      /* arg1 = new flag */
 154         movq    %r11, %rsi      /* arg2 = vex state */
 155         addq    $$24, %rsp      /* remove syscall parameters */
 156         movl    $$1, OFFSET_amd64_SETC(%r11)
 157         call    _LibVEX_GuestAMD64_put_rflag_c
 158         movq    -16(%rbp), %r11
 159         movl    $$0, OFFSET_amd64_SETC(%r11)
 160 .else
 161         addq    $$24, %rsp      /* remove syscall parameters*/
 162 .endif
 163
 164 L_$0_4: /* Re-block signals.  If eip is in [4,5), then the syscall
 165            is complete and we needn't worry about it. */
 166         /* GrP fixme signals
 167            DDD: JRS fixme: use __NR___pthread_sigmask, not __NR_rt_sigprocmask
 168         PUSH_di_si_dx_cx_8
 169
 170         movq    $__NR_rt_sigprocmask, %rax      // syscall #
 171         movq    $VKI_SIG_SETMASK, %rdi          // how
 172         movq    %rcx, %rsi                      // postmask
 173         xorq    %rdx, %rdx                      // NULL
 174         movq    %r8, %r10                       // sigsetSzB
 175         DDD: fixme return address
 176         syscall
 177
 178         POP_di_si_dx_cx_8
 179
 180         jnc     7f      // sigprocmask failed
 181         */
 182 L_$0_5: /* now safe from signals */
 183         movq    $$0, %rax       /* SUCCESS */
 184         movq    %rbp, %rsp
 185         popq    %rbp
 186         ret
 187
 188 /* GrP fixme signals
 189 L_$0_7: // failure:      return 0x8000 | error code
 190         DDD: fixme return value
 191         movq    %rbp, %rsp
 192         popq    %rbp
 193         ret
 194 */
 195
 196 .endmacro
 197
 198
 199 .globl ML_(do_syscall_for_client_unix_WRK)
 200 ML_(do_syscall_for_client_unix_WRK):
 201         DO_SYSCALL UNIX
 202
 203 .globl ML_(do_syscall_for_client_mach_WRK)
 204 ML_(do_syscall_for_client_mach_WRK):
 205         DO_SYSCALL MACH
 206
 207 .globl ML_(do_syscall_for_client_mdep_WRK)
 208 ML_(do_syscall_for_client_mdep_WRK):
 209         DO_SYSCALL MDEP
 210
 211 .data
 212 /* export the ranges so that
 213    VG_(fixup_guest_state_after_syscall_interrupted) can do the
 214    right thing */
 215
 216 /* eg MK_L_SCLASS_N(UNIX,99) produces L_3_99
 217    since UNIX is #defined to 3 at the top of this file */
 218 #define FOO(scclass,labelno) L_##scclass##_##labelno
 219 #define MK_L_SCCLASS_N(scclass,labelno) FOO(scclass,labelno)
 220
 221 .globl ML_(blksys_setup_MACH)
 222 .globl ML_(blksys_restart_MACH)
 223 .globl ML_(blksys_complete_MACH)
 224 .globl ML_(blksys_committed_MACH)
 225 .globl ML_(blksys_finished_MACH)
 226 ML_(blksys_setup_MACH): .quad MK_L_SCCLASS_N(MACH,1)
 227 ML_(blksys_restart_MACH):       .quad MK_L_SCCLASS_N(MACH,2)
 228 ML_(blksys_complete_MACH):      .quad MK_L_SCCLASS_N(MACH,3)
 229 ML_(blksys_committed_MACH):     .quad MK_L_SCCLASS_N(MACH,4)
 230 ML_(blksys_finished_MACH):      .quad MK_L_SCCLASS_N(MACH,5)
 231
 232 .globl ML_(blksys_setup_MDEP)
 233 .globl ML_(blksys_restart_MDEP)
 234 .globl ML_(blksys_complete_MDEP)
 235 .globl ML_(blksys_committed_MDEP)
 236 .globl ML_(blksys_finished_MDEP)
 237 ML_(blksys_setup_MDEP): .quad MK_L_SCCLASS_N(MDEP,1)
 238 ML_(blksys_restart_MDEP):       .quad MK_L_SCCLASS_N(MDEP,2)
 239 ML_(blksys_complete_MDEP):      .quad MK_L_SCCLASS_N(MDEP,3)
 240 ML_(blksys_committed_MDEP):     .quad MK_L_SCCLASS_N(MDEP,4)
 241 ML_(blksys_finished_MDEP):      .quad MK_L_SCCLASS_N(MDEP,5)
 242
 243 .globl ML_(blksys_setup_UNIX)
 244 .globl ML_(blksys_restart_UNIX)
 245 .globl ML_(blksys_complete_UNIX)
 246 .globl ML_(blksys_committed_UNIX)
 247 .globl ML_(blksys_finished_UNIX)
 248 ML_(blksys_setup_UNIX): .quad MK_L_SCCLASS_N(UNIX,1)
 249 ML_(blksys_restart_UNIX):       .quad MK_L_SCCLASS_N(UNIX,2)
 250 ML_(blksys_complete_UNIX):      .quad MK_L_SCCLASS_N(UNIX,3)
 251 ML_(blksys_committed_UNIX):     .quad MK_L_SCCLASS_N(UNIX,4)
 252 ML_(blksys_finished_UNIX):      .quad MK_L_SCCLASS_N(UNIX,5)
 253
 254 #endif // defined(VGP_amd64_darwin)
 255
 256 /* Let the linker know we don't need an executable stack */
 257 MARK_STACK_NO_EXEC
 258
 259 /*--------------------------------------------------------------------*/
 260 /*--- end                                                          ---*/
 261 /*--------------------------------------------------------------------*/