coregrind/m_syswrap/syscall-mips64-linux.S

   1
   2 /*--------------------------------------------------------------------*/
   3 /*--- Support for doing system calls.      syscall-mips64-linux.S  ---*/
   4 /*--------------------------------------------------------------------*/
   5
   6 /*
   7   This file is part of Valgrind, a dynamic binary instrumentation
   8   framework.
   9
  10    Copyright (C) 2010-2017 RT-RK
  11
  12    This program is free software; you can redistribute it and/or
  13    modify it under the terms of the GNU General Public License as
  14    published by the Free Software Foundation; either version 2 of the
  15    License, or (at your option) any later version.
  16
  17    This program is distributed in the hope that it will be useful, but
  18    WITHOUT ANY WARRANTY; without even the implied warranty of
  19    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20    General Public License for more details.
  21
  22    You should have received a copy of the GNU General Public License
  23    along with this program; if not, see <http://www.gnu.org/licenses/>.
  24
  25    The GNU General Public License is contained in the file COPYING.
  26 */
  27
  28 #include "pub_core_basics_asm.h"
  29
  30 #if defined(VGP_mips64_linux)
  31
  32 #include "pub_core_vkiscnums_asm.h"
  33 #include "libvex_guest_offsets.h"
  34
  35 /*----------------------------------------------------------------*/
  36 /*
  37    Perform a syscall for the client. This will run a syscall
  38    with the client's specific per-thread signal mask.
  39
  40    The structure of this function is such that, if the syscall is
  41    interrupted by a signal, we can determine exactly what
  42    execution state we were in with respect to the execution of
  43    the syscall by examining the value of PC in the signal
  44    handler. This means that we can always do the appropriate
  45    thing to precisely emulate the kernel's signal/syscall
  46    interactions.
  47
  48    The syscall number is taken from the argument, even though it
  49    should also be in regs->v0. The syscall result is written
  50    back to regs->v0 on completion.
  51
  52    VG_(fixup_guest_state_after_syscall_interrupted) does the
  53    thread state fixup in the case where we were interrupted by a
  54    signal.
  55
  56    Prototype:
  57
  58    UWord ML_(do_syscall_for_client_WRK)(
  59              Int syscallno,                 // $4 - a0
  60              void* guest_state,             // $5 - a1
  61              const vki_sigset_t *sysmask,   // $6 - a2
  62              const vki_sigset_t *postmask,  // $7 - a3
  63              Int nsigwords)                 // $8 - a4
  64 */
  65
  66 /* from vki_arch.h */
  67 #define VKI_SIG_SETMASK 3
  68
  69 .globl ML_(do_syscall_for_client_WRK)
  70 ML_(do_syscall_for_client_WRK):
  71
  72    /* save regs $a0 - $a4 on stack */
  73    daddiu  $29, $29, -48
  74    sd      $4, 0($29)                /* syscallno */
  75    sd      $5, 8($29)                /* guest_state */
  76    sd      $6, 16($29)               /* sysmask */
  77    sd      $7, 24($29)               /* postmask */
  78    sd      $8, 32($29)               /* nsigwords */
  79
  80 1: li      $2, __NR_rt_sigprocmask
  81    li      $4, VKI_SIG_SETMASK
  82    move    $5, $6                    /* sysmask */
  83    move    $6, $7                    /* postmask */
  84    move    $7, $8                    /* nsigwords */
  85    syscall
  86
  87    bnez    $7, 7f
  88    nop
  89
  90    /* Actually do the client syscall */
  91    ld      $5, 8($29)                /* guest_state */
  92    ld      $4, OFFSET_mips64_r4($5)  /* a0 */
  93
  94    ld      $6, OFFSET_mips64_r6($5)  /* a2 */
  95    ld      $7, OFFSET_mips64_r7($5)  /* a3 */
  96    ld      $8, OFFSET_mips64_r8($5)  /* a4 */
  97    ld      $9, OFFSET_mips64_r9($5)  /* a5 */
  98    ld      $10, OFFSET_mips64_r10($5)  /* a6 */
  99    ld      $11, OFFSET_mips64_r11($5)  /* a7 */
 100
 101    ld      $5, OFFSET_mips64_r5($5)  /* a1 */
 102    ld      $2, 0($29)                /* syscallno */
 103
 104 2: syscall
 105
 106    /* Saving return values into Guest state  */
 107 3: ld      $5, 8($29)                /* guest_state */
 108    sd      $2, OFFSET_mips64_r2($5)  /* v0 */
 109    sd      $7, OFFSET_mips64_r7($5)  /* a3 */
 110
 111 4: li      $2, __NR_rt_sigprocmask
 112    li      $4, VKI_SIG_SETMASK
 113    ld      $5, 24($29)               /* postmask */
 114    move    $6, $0                    /* 0 (zero) */
 115    ld      $7, 32($29)               /* nsigwords */
 116    syscall
 117
 118    bnez    $7, 7f
 119    nop
 120
 121 5: /* restore 29 and return */
 122    daddiu  $29, $29, 48
 123    jr      $31
 124    nop
 125
 126 7: /* error */
 127    daddiu  $29, $29, 48
 128    li      $2, 0x8000
 129    jr      $31
 130    nop
 131
 132 .section .rodata
 133 /* export the ranges so that
 134    VG_(fixup_guest_state_after_syscall_interrupted) can do the
 135    right thing */
 136
 137 .globl ML_(blksys_setup)
 138 .globl ML_(blksys_restart)
 139 .globl ML_(blksys_complete)
 140 .globl ML_(blksys_committed)
 141 .globl ML_(blksys_finished)
 142 #if defined(VGABI_N32)
 143 ML_(blksys_setup):      .int 1b
 144 ML_(blksys_restart):    .int 2b
 145 ML_(blksys_complete):   .int 3b
 146 ML_(blksys_committed):  .int 4b
 147 ML_(blksys_finished):   .int 5b
 148 #else
 149 ML_(blksys_setup):      .quad 1b
 150 ML_(blksys_restart):    .quad 2b
 151 ML_(blksys_complete):   .quad 3b
 152 ML_(blksys_committed):  .quad 4b
 153 ML_(blksys_finished):   .quad 5b
 154 #endif
 155
 156 #endif // defined(VGP_mips64_linux)
 157
 158 /* Let the linker know we don't need an executable stack */
 159 MARK_STACK_NO_EXEC
 160
 161 /*--------------------------------------------------------------------*/
 162 /*--- end                                                          ---*/
 163 /*--------------------------------------------------------------------*/