coregrind/m_syswrap/syscall-ppc32-linux.S

   1
   2 /*--------------------------------------------------------------------*/
   3 /*--- Support for doing system calls.        syscall-ppc32-linux.S ---*/
   4 /*--------------------------------------------------------------------*/
   5
   6 /*
   7   This file is part of Valgrind, a dynamic binary instrumentation
   8   framework.
   9
  10   Copyright (C) 2005-2017 Paul Mackerras (paulus@samba.org)
  11
  12   This program is free software; you can redistribute it and/or
  13   modify it under the terms of the GNU General Public License as
  14   published by the Free Software Foundation; either version 2 of the
  15   License, or (at your option) any later version.
  16
  17   This program is distributed in the hope that it will be useful, but
  18   WITHOUT ANY WARRANTY; without even the implied warranty of
  19   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20   General Public License for more details.
  21
  22   You should have received a copy of the GNU General Public License
  23   along with this program; if not, see <http://www.gnu.org/licenses/>.
  24
  25   The GNU General Public License is contained in the file COPYING.
  26 */
  27
  28 #include "pub_core_basics_asm.h"
  29
  30 #if defined(VGP_ppc32_linux)
  31
  32 #include "pub_core_vkiscnums_asm.h"
  33 #include "libvex_guest_offsets.h"
  34
  35
  36 /*----------------------------------------------------------------*/
  37 /*
  38         Perform a syscall for the client.  This will run a syscall
  39         with the client's specific per-thread signal mask.
  40
  41         The structure of this function is such that, if the syscall is
  42         interrupted by a signal, we can determine exactly what
  43         execution state we were in with respect to the execution of
  44         the syscall by examining the value of NIP in the signal
  45         handler.  This means that we can always do the appropriate
  46         thing to precisely emulate the kernel's signal/syscall
  47         interactions.
  48
  49         The syscall number is taken from the argument, even though it
  50         should also be in regs->m_gpr[0].  The syscall result is written
  51         back to regs->m_gpr[3]/m_xer/m_result on completion.
  52
  53         Returns 0 if the syscall was successfully called (even if the
  54         syscall itself failed), or a nonzero error code in the lowest
  55         8 bits if one of the sigprocmasks failed (there's no way to
  56         determine which one failed).  And there's no obvious way to
  57         recover from that either, but nevertheless we want to know.
  58
  59         VG_(fixup_guest_state_after_syscall_interrupted) does the
  60         thread state fixup in the case where we were interrupted by a
  61         signal.
  62
  63         Prototype:
  64
  65         UWord ML_(do_syscall_for_client_WRK)(
  66                                   Int syscallno,                // r3
  67                                   void* guest_state,            // r4
  68                                   const vki_sigset_t *sysmask,  // r5
  69                                   const vki_sigset_t *postmask, // r6
  70                                   Int sigsetSzB)                // r7
  71 */
  72 /* from vki_arch.h */
  73 #define VKI_SIG_SETMASK 2
  74
  75 .globl ML_(do_syscall_for_client_WRK)
  76 ML_(do_syscall_for_client_WRK):
  77         /* make a stack frame */
  78         stwu    1,-32(1)
  79         stw     31,28(1)
  80         stw     30,24(1)
  81         stw     29,20(1)
  82         stw     28,16(1)
  83         mr      31,3            /* syscall number */
  84         mr      30,4            /* guest_state */
  85         mr      29,6            /* postmask */
  86         mr      28,7            /* sigsetSzB */
  87
  88         /* set the signal mask for doing the system call */
  89         /* set up for sigprocmask(SIG_SETMASK, sysmask, postmask) */
  90 1:      li      0,__NR_rt_sigprocmask
  91         li      3,VKI_SIG_SETMASK
  92         mr      4,5
  93         mr      5,6
  94         mr      6,7
  95         sc                      /* set the mask */
  96         bso     7f              /* if the sigprocmask fails */
  97
  98         /* load up syscall args from the threadstate */
  99         lwz     3,OFFSET_ppc32_GPR3(30)
 100         lwz     4,OFFSET_ppc32_GPR4(30)
 101         lwz     5,OFFSET_ppc32_GPR5(30)
 102         lwz     6,OFFSET_ppc32_GPR6(30)
 103         lwz     7,OFFSET_ppc32_GPR7(30)
 104         lwz     8,OFFSET_ppc32_GPR8(30)
 105         mr      0,31            /* syscall number */
 106 2:      sc                      /* do the syscall */
 107
 108         /* put the result back in the threadstate  */
 109 3:      stw     3,OFFSET_ppc32_GPR3(30)     /* gst->GPR3 = sc result */
 110         /* copy cr0.so back to simulated state */
 111         mfcr    5                           /* r5 = CR               */
 112         rlwinm  5,5,4,31,31                 /* r5 = (CR >> 28) & 1   */
 113         stb     5,OFFSET_ppc32_CR0_0(30)    /* gst->CR0.SO = cr0.so  */
 114
 115         /* block signals again */
 116         /* set up for sigprocmask(SIG_SETMASK, postmask, NULL) */
 117 4:      li      0,__NR_rt_sigprocmask
 118         li      3,VKI_SIG_SETMASK
 119         mr      4,29
 120         li      5,0
 121         mr      6,28
 122         sc                      /* set the mask */
 123         bso     7f              /* if the sigprocmask fails */
 124         /* now safe from signals */
 125         li      3,0             /* SUCCESS */
 126
 127         /* pop off stack frame */
 128 5:      lwz     28,16(1)
 129         lwz     29,20(1)
 130         lwz     30,24(1)
 131         lwz     31,28(1)
 132         addi    1,1,32
 133         blr
 134
 135         /* failure: return 0x8000 | error code */
 136 7:      ori     3,3,0x8000      /* FAILURE -- ensure return value is nonzero */
 137         b       5b
 138
 139 .section .rodata
 140 /* export the ranges so that
 141    VG_(fixup_guest_state_after_syscall_interrupted) can do the
 142    right thing */
 143
 144 .globl ML_(blksys_setup)
 145 .globl ML_(blksys_restart)
 146 .globl ML_(blksys_complete)
 147 .globl ML_(blksys_committed)
 148 .globl ML_(blksys_finished)
 149 ML_(blksys_setup):     .long 1b
 150 ML_(blksys_restart):   .long 2b
 151 ML_(blksys_complete):  .long 3b
 152 ML_(blksys_committed): .long 4b
 153 ML_(blksys_finished):  .long 5b
 154
 155 #endif // defined(VGP_ppc32_linux)
 156
 157 /* Let the linker know we don't need an executable stack */
 158 MARK_STACK_NO_EXEC
 159
 160 /*--------------------------------------------------------------------*/
 161 /*--- end                                                          ---*/
 162 /*--------------------------------------------------------------------*/