test.lisp

   1 ;;; -*- show-trailing-whitespace: t; indent-tabs-mode: nil -*-
   2
   3 ;;; Copyright (c) 2007,2008 David Lichteblau, Ivan Shvedunov.
   4 ;;; All rights reserved.
   5
   6 ;;; Redistribution and use in source and binary forms, with or without
   7 ;;; modification, are permitted provided that the following conditions
   8 ;;; are met:
   9 ;;;
  10 ;;;   * Redistributions of source code must retain the above copyright
  11 ;;;     notice, this list of conditions and the following disclaimer.
  12 ;;;
  13 ;;;   * Redistributions in binary form must reproduce the above
  14 ;;;     copyright notice, this list of conditions and the following
  15 ;;;     disclaimer in the documentation and/or other materials
  16 ;;;     provided with the distribution.
  17 ;;;
  18 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR 'AS IS' AND ANY EXPRESSED
  19 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  20 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
  22 ;;; DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23 ;;; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
  24 ;;; GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25 ;;; INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  26 ;;; WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  27 ;;; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  28 ;;; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29
  30 (in-package :xuriella)
  31
  32 (defparameter *tests-directory*
  33   "/home/david/src/XSLT-testsuite-04/testsuite/TESTS/")
  34
  35 (defclass test-case ()
  36   ((id :initarg :id :accessor test-id)
  37    (category :initarg :category :accessor test-category)
  38    (operation :initarg :operation :accessor test-operation)
  39    (data-pathname :initarg :data-pathname :accessor test-data-pathname)
  40    (stylesheet-pathname :initarg :stylesheet-pathname
  41                         :accessor test-stylesheet-pathname)
  42    (data-pathname-2 :initarg :data-pathname-2 :accessor test-data-pathname-2)
  43    (stylesheet-pathname-2 :initarg :stylesheet-pathname-2
  44                           :accessor test-stylesheet-pathname-2)
  45    (output-pathname :initarg :output-pathname
  46                     :accessor test-official-output-pathname)
  47    (output-compare :initarg :output-compare
  48                    :accessor test-output-compare)))
  49
  50 (defmethod print-object ((object test-case) stream)
  51   (print-unreadable-object (object stream :identity nil :type t)
  52     (format stream "~A ~A/~A"
  53             (test-operation object)
  54             (test-category object)
  55             (test-id object))))
  56
  57
  58 ;;;; SIMPLIFY-TESTS
  59
  60 ;;; Translate catalog.xml into an actually usable katalog.xml
  61 ;;; by running the test cases through xsltproc to see what it thinks
  62 ;;; about them.
  63
  64 (defun simplify-tests (&optional (d *tests-directory*))
  65   (with-open-file (stream (merge-pathnames "katalog.xml" d)
  66                           :direction :output
  67                           :if-exists :supersede
  68                           :element-type '(unsigned-byte 8))
  69     (cxml:with-xml-output (cxml:make-octet-stream-sink stream)
  70       (cxml:with-element "simplified-test-suite"
  71         (klacks:with-open-source
  72             (source (klacks:make-tapping-source
  73                      (cxml:make-source (merge-pathnames "catalog.xml" d))))
  74           (let ((*default-pathname-defaults* (merge-pathnames d)))
  75             (map-original-tests #'simplify-test source)))))))
  76
  77 (defun map-original-tests (run-test source &key (test (constantly t)))
  78   (let ((total 0)
  79         (pass 0)
  80         major-path)
  81     (loop
  82        while (klacks:find-event source :start-element)
  83        for lname = (klacks:current-lname source)
  84        do
  85        (cond
  86          ((equal lname "major-path")
  87           (klacks:skip source :start-element)
  88           (setf major-path
  89                 (namestring
  90                  (merge-pathnames (klacks:consume-characters source)))))
  91          ((equal lname "test-case")
  92           (let* ((<test-case>
  93                   (stp:document-element
  94                    (klacks:serialize-element source (stp:make-builder))))
  95                  (test-case (parse-original-test major-path <test-case>)))
  96             (when (funcall test test-case)
  97               (incf total)
  98               (when (funcall run-test test-case)
  99                 (incf pass)))))
 100          (t
 101           (klacks:skip source :start-element))))
 102     (format t "~&Passed ~D/~D tests.~%" pass total)))
 103
 104 (defun parse-original-test (major-path <test-case>)
 105   (let* ((file-path
 106           (stp:string-value
 107            (stp:find-recursively-if (stp:of-name "file-path") <test-case>)))
 108          (base (concatenate 'string major-path "/" file-path))
 109          (out-base (concatenate 'string major-path "/REF_OUT/" file-path))
 110          (scenario
 111           (stp:find-recursively-if (stp:of-name "scenario") <test-case>))
 112          data
 113          stylesheet
 114          supplemental-stylesheet
 115          supplemental-data
 116          output
 117          compare)
 118     (dolist (<input> (stp:filter-recursively (stp:of-name "input-file")
 119                                              <test-case>))
 120       (let ((role (stp:attribute-value <input> "role"))
 121             (path (concatenate 'string base "/" (stp:string-value <input>))))
 122         (cond
 123           ((equal role "principal-data")
 124            (setf data path))
 125           ((equal role "principal-stylesheet")
 126            (setf stylesheet path))
 127           ((equal role "supplemental-stylesheet")
 128            (setf supplemental-stylesheet path))
 129           ((equal role "supplemental-data")
 130            (setf supplemental-data path))
 131           (t
 132            (error "unrecognized role: ~A" role)))))
 133     (dolist (<output> (stp:filter-recursively (stp:of-name "output-file")
 134                                             <test-case>))
 135       (let ((role (stp:attribute-value <output> "role"))
 136             (path (concatenate 'string out-base
 137                                "/"
 138                                (stp:string-value <output>))))
 139         (cond
 140           ((equal role "principal")
 141            (setf output path)
 142            (setf compare (stp:attribute-value <output> "compare")))
 143           (t
 144            (error "unrecognized role: ~A" role)))))
 145     (make-instance 'test-case
 146                    :id (stp:attribute-value <test-case> "id")
 147                    :category (stp:attribute-value <test-case> "category")
 148                    :operation (stp:attribute-value scenario "operation")
 149                    :data-pathname data
 150                    :stylesheet-pathname stylesheet
 151                    :stylesheet-pathname-2 supplemental-stylesheet
 152                    :data-pathname-2 supplemental-data
 153                    :output-pathname output
 154                    :output-compare compare)))
 155
 156 (defun write-simplified-test (test-case operation)
 157   (cxml:with-element "test-case"
 158     (cxml:attribute "id" (test-id test-case))
 159     (cxml:attribute "category" (test-category test-case))
 160     (flet ((p (l p)
 161              (cxml:attribute l (and p (namestring p)))))
 162       (p "data" (test-data-pathname test-case))
 163       (p "stylesheet" (noindent-stylesheet-pathname test-case))
 164       (p "data-2" (test-data-pathname-2 test-case))
 165       (p "stylesheet-2" (test-stylesheet-pathname-2 test-case))
 166       (p "output" (test-official-output-pathname test-case))
 167       (p "compare" (test-output-compare test-case)))
 168     (cxml:attribute "operation" operation)))
 169
 170 (defun test-output-pathname (test type)
 171   (make-pathname :name (test-id test)
 172                  :type type
 173                  :defaults (test-data-pathname test)))
 174
 175 (defun sanitize-stylesheet (in out)
 176   (if (probe-file in)
 177       (handler-case
 178           (let ((d (cxml:parse (pathname in) (stp:make-builder))))
 179             (xpath:with-namespaces ((nil #.*xsl*))
 180               (xpath:do-node-set (output (xpath:evaluate "//output" d))
 181                 (let ((a (stp:find-attribute-named output "indent")))
 182                   (when a
 183                     (stp:detach a)))))
 184             (with-open-file (s out
 185                                :direction :output
 186                                :if-exists :rename-and-delete
 187                                :element-type '(unsigned-byte 8))
 188               (stp:serialize d (cxml:make-octet-stream-sink s))))
 189         (error (c)
 190           (warn "ignoring bogus stylesheet ~A: ~A" in c)
 191           (copy-file in out)))
 192       (warn "oops, ignoring missing stylesheet: ~A" in)))
 193
 194 (defun noindent-stylesheet-pathname (test-case)
 195   (make-pathname :type "noindent-xsl"
 196                  :defaults (test-stylesheet-pathname test-case)))
 197
 198 (defun simplify-test (test-case)
 199   (flet ((report (status &optional (fmt "") &rest args)
 200            (format t "~&~A ~A [~A]~?~%"
 201                    status
 202                    (test-id test-case)
 203                    (test-category test-case)
 204                    fmt
 205                    args)))
 206     (let* ((data (test-data-pathname test-case))
 207            (stylesheet (test-stylesheet-pathname test-case))
 208            (noindent-stylesheet (noindent-stylesheet-pathname test-case))
 209            #+xuriella::xsltproc
 210            (out (test-output-pathname test-case "xsltproc"))
 211            (saxon-out (test-output-pathname test-case "saxon")))
 212       (sanitize-stylesheet stylesheet noindent-stylesheet)
 213       (if (equal (test-operation test-case) "standard")
 214           (handler-case
 215               (progn
 216                 #+xuriella::xsltproc (xsltproc noindent-stylesheet data out)
 217                 (saxon noindent-stylesheet data saxon-out)
 218                 (report "PASS")
 219                 (write-simplified-test test-case "standard")
 220                 t)
 221             (error (c)
 222               (report "FAIL" ": ~A" c)
 223               (write-simplified-test test-case "execution-error")
 224               nil))
 225           (handler-case
 226               (progn
 227                 #+xuriella::xsltproc
 228                 (xsltproc noindent-stylesheet data "/dev/null")
 229                 (saxon noindent-stylesheet data "/dev/null")
 230                 (report "FAIL" ": expected error not signalled")
 231                 ;; let's ignore unexpected successes for now
 232                 nil)
 233             (error (c)
 234               (report "PASS" ": expected error ~A" c)
 235               (write-simplified-test test-case "execution-error")
 236               t))))))
 237
 238 (defun xsltproc (stylesheet input output)
 239   (flet ((full-namestring (x)
 240            (namestring (merge-pathnames x))))
 241     (let* ((asdf::*verbose-out* (make-string-output-stream))
 242            (code (asdf:run-shell-command
 243                   "cd ~S && xsltproc ~S ~S >~S"
 244                   (full-namestring "")
 245                   (full-namestring stylesheet)
 246                   (full-namestring input)
 247                   (full-namestring output))))
 248       (unless (zerop code)
 249         (error "running xsltproc failed with code ~A [~%~A~%]"
 250                code
 251                (get-output-stream-string asdf::*verbose-out*))))))
 252
 253 (defun saxon (stylesheet input output)
 254   (flet ((full-namestring (x)
 255            (namestring (merge-pathnames x))))
 256     (let* ((asdf::*verbose-out* (make-string-output-stream))
 257            (code (asdf:run-shell-command
 258                   "cd ~S && java -jar /usr/share/java/saxon.jar ~S ~S >~S"
 259                   (full-namestring "")
 260                   (full-namestring input)
 261                   (full-namestring stylesheet)
 262                   (full-namestring output))))
 263       (unless (zerop code)
 264         (error "running saxon failed with code ~A [~%~A~%]"
 265                code
 266                (get-output-stream-string asdf::*verbose-out*))))))
 267
 268
 269 ;;;; RUN-TESTS and DRIBBLE-TESTS
 270
 271 ;;; Process katalog.xml
 272
 273 (defun dribble-tests
 274     (&key filter (directory *tests-directory*) (file "TEST"))
 275   (let ((*package* (find-package 'cl-user))
 276         (*print-circle* nil))
 277     (with-open-file (dribble
 278                      (merge-pathnames file
 279                                       (slot-value (asdf:find-system :xuriella)
 280                                                   'asdf::relative-pathname))
 281                      :direction :output
 282                      :if-exists :supersede
 283                      :external-format :utf-8)
 284       (let* ((dribble (make-broadcast-stream dribble *standard-output*))
 285              (*standard-output* dribble)
 286              (*trace-output* dribble)
 287              (*error-output* dribble)
 288              (*terminal-io* (make-two-way-stream *standard-input* dribble)))
 289         (handler-bind ((warning
 290                         (lambda (c)
 291                           (warn "~A" (replace-junk (princ-to-string c)))
 292                           (muffle-warning c))))
 293           (run-tests :filter filter
 294                      :directory directory))))))
 295
 296 (defparameter *bad-tests*
 297   '(;; Inconsistent tests:
 298     ;;
 299     ;; Some tests wants us to recover from this error, yet this one doesn't:
 300     "copy_copy61"
 301     "copy_copy62"
 302
 303     ;; Should we fix this?
 304     ;;
 305     ;; We signal a run-time error when and if it's actually used.  The test
 306     ;; wants a compilation-time error...
 307     "AttributeSets_RefToUndefinedAttributeSet"
 308
 309     ;; We would pass this:
 310     ;;
 311     ;; We perform recovery, but saxon doesn't.  Recovery results in non-XML
 312     ;; output, which we can't parse for comparison against the official
 313     ;; test case.
 314     "output_output75"
 315     ;;
 316     ;; we'd pass these tests, but the test authors forgot to declare the
 317     ;; entity they're writing, so we can't parse it for comparison.
 318     "output_output06"
 319     "output_output10"
 320     "output_output61"
 321     ;;
 322     ;; another similar test where the output is unparsable, except that
 323     ;; here an entity declaration wouldn't have helped either:
 324     "Copying_ResultTreeFragmentWithEscapedText"
 325
 326     ;; Broken test:
 327     ;;
 328     ;; Input document isn't ns-wf.
 329     "Attributes__78387"
 330     ;;
 331     ;; Someone commented out most of this test...
 332     "BVTs_bvt045"
 333
 334     ;; FIXME: should re-enable these at some point:
 335     ;;
 336     ;; the following tests take a lot of time due to the problems of current matching algorithm:
 337     "impincl_impincl16"
 338     ;; probably the same problem (but I haven't checked):
 339     "Import__91164"
 340
 341     ;; stack exhaustion -- matching problem i think
 342     "Keys_PerfRepro3"))
 343
 344 ;; Tests where the output isn't a match because of extraneous whitespace.
 345 ;; For these tests, we force space normalization before comparing.
 346 ;;
 347 ;; Possible reasons for this problem are:
 348 ;;   a. The output method is declared in an imported stylesheet.
 349 ;;      SANITIZE-STYLESHEET is supposed to get rid of indent="yes", but it
 350 ;;      misses imported stylesheets.
 351 ;;   b. Saxon output isn't a match, but the official output is.
 352 ;;      But the official output is unaffected by SANITIZE-STYLESHEET.
 353 ;;
 354 (defparameter *whitespace-issues*
 355   '("BVTs_bvt044"
 356     "Namespace-alias__91782"
 357     "AttributeSets__91038"
 358     "BVTs_bvt041"
 359     "BVTs_bvt042"
 360     "BVTs_bvt054"
 361     "BVTs_bvt058"))
 362
 363 (defparameter *known-failures*
 364   '(
 365     ;; uses EBCDIC-CP-IT (whatever that is), but Babel's only got EBCDIC-US.
 366     ;; Doesn't actually test any differences between the two, so it's
 367     ;; probably just there to annoy us.
 368     "output_output22"
 369
 370     ;; uses KOI, which Babel doesn't support
 371     "BVTs_bvt019"
 372
 373     ;; FIXME?
 374     ;;
 375     ;; This is an HTML output method issue.  The spec says the HTML
 376     ;; output method should output elements with a null namespace URI as
 377     ;; HTML, and if their name isn't recognized, as an inline element.
 378     ;; <xml> here is such an element.  It has an attributes with a
 379     ;; namespace though, and the spec doesn't say what we should do with that
 380     ;; attribute.  We currently output it using Closure HTML, and
 381     ;; lose its namespace.  This test wants the attribute and its
 382     ;; namespace to survive.
 383     "BVTs_bvt054"))
 384
 385 (defun run-tests (&key filter (directory *tests-directory*))
 386   (when (typep filter '(or string cons))
 387     (setf filter (cl-ppcre:create-scanner filter)))
 388   (klacks:with-open-source
 389       (source (klacks:make-tapping-source
 390                (cxml:make-source (merge-pathnames "katalog.xml" directory))))
 391     (let ((*default-pathname-defaults* (merge-pathnames directory)))
 392       (map-tests #'run-test
 393                  source
 394                  :test (lambda (test)
 395                          (and (or (null filter)
 396                                   (cl-ppcre:all-matches
 397                                    filter
 398                                    (format nil "~A/~A"
 399                                            (test-category test)
 400                                            (test-id test))))
 401                               (not (find (test-id test)
 402                                          *bad-tests*
 403                                          :test #'equal))))))))
 404
 405 (defun run-named-test (name &optional (d *tests-directory*))
 406   (let ((*break-on-signals*
 407          '(and error (not babel-encodings:character-encoding-error))))
 408     (run-tests :filter (format nil "/~A$" name) :directory d)))
 409
 410 (defun copy-file (p q)
 411   (with-open-file (in p :element-type '(unsigned-byte 8))
 412     (with-open-file (out q
 413                          :element-type '(unsigned-byte 8)
 414                          :direction :output
 415                          :if-exists :rename-and-delete)
 416       (let ((buf (make-array 8192 :element-type '(unsigned-byte 8))))
 417         (loop for pos = (read-sequence buf in)
 418            until (zerop pos)
 419            do (write-sequence buf out :end pos))))))
 420
 421 (defun find-named-test (name &optional (d *tests-directory*))
 422   (klacks:with-open-source
 423       (source (klacks:make-tapping-source
 424                (cxml:make-source (merge-pathnames "katalog.xml" d))))
 425     (block nil
 426       (map-tests (lambda (test)
 427                    (return test))
 428                  source
 429                  :test (lambda (test) (equal (test-id test) name))))))
 430
 431 (defun copy-test-files (name &optional (d *tests-directory*))
 432   (let* ((test (find-named-test name d))
 433          (*default-pathname-defaults* (merge-pathnames d))
 434          (*break-on-signals*
 435           '(and error (not babel-encodings:character-encoding-error)))
 436          (target-dir (merge-pathnames "copied-test/"
 437                                       (asdf:component-pathname
 438                                        (asdf:find-system :xuriella))))
 439          (xsl (merge-pathnames "test.xsl" target-dir))
 440          (xml (merge-pathnames "test.xml" target-dir))
 441          (txt (merge-pathnames "official-output.txt" target-dir))
 442          (expected (merge-pathnames "expected.xml" target-dir))
 443          (actual (merge-pathnames "actual.xml" target-dir)))
 444     (ensure-directories-exist target-dir)
 445     (copy-file (test-stylesheet-pathname test) xsl)
 446     (copy-file (test-data-pathname test) xml)
 447     (when (test-official-output-pathname test)
 448       (copy-file (test-official-output-pathname test) txt))
 449     (format t "Test stylesheet copied to:~%  ~A~%~%" xsl)
 450     (format t "Test data copied to:~%  ~A~%~%" xml)
 451     (when (test-official-output-pathname test)
 452       (format t "Official output file:~%  ~A~%~%" txt))
 453     (format t "Run xsltproc like this:~%  cd ~A~%  xsltproc ~A ~A >~A~%~%"
 454             (namestring target-dir)
 455             (enough-namestring xsl target-dir)
 456             (enough-namestring xml target-dir)
 457             (enough-namestring expected target-dir))
 458     (format t "Run saxon like this:~%  cd ~A~%  java -jar /usr/share/java/saxon.jar ~A ~A >~A~%~%"
 459             (namestring target-dir)
 460             (enough-namestring xml target-dir)
 461             (enough-namestring xsl target-dir)
 462             (enough-namestring expected target-dir))
 463     (format t "Run MSXSL like this:~%  cd ~A~%  wine msxsl.exe ~A ~A >~A~%~%"
 464             (namestring target-dir)
 465             (enough-namestring xml target-dir)
 466             (enough-namestring xsl target-dir)
 467             (enough-namestring expected target-dir))
 468     (format t "Run xuriella like this:~%")
 469     `(apply-stylesheet ,xsl ,xml :output ,actual)))
 470
 471 (defun map-tests (run-test source &key (test (constantly t)))
 472   (let ((total 0)
 473         (pass 0)
 474         (known 0))
 475     (loop
 476        while (klacks:find-event source :start-element)
 477        for lname = (klacks:current-lname source)
 478        do
 479        (cond
 480          ((equal lname "test-case")
 481           (let* ((<test-case>
 482                   (stp:document-element
 483                    (klacks:serialize-element source (stp:make-builder))))
 484                  (test-case (parse-test <test-case>)))
 485             (when (funcall test test-case)
 486               (incf total)
 487               (ecase (funcall run-test test-case)
 488                 ((nil))
 489                 ((t)
 490                  (incf pass))
 491                 (:known-failure
 492                  (incf known))))))
 493          (t
 494           (klacks:skip source :start-element))))
 495     (format t "~&Passed ~D/~D tests (~D expected failures, ~D unexpected failures).~%"
 496             pass total known (- total pass known))))
 497
 498 (defun parse-test (<test-case>)
 499   (stp:with-attributes (id category operation
 500                            data stylesheet data-2 stylesheet-2
 501                            output compare)
 502       <test-case>
 503     (make-instance 'test-case
 504                    :id id
 505                    :category category
 506                    :operation operation
 507                    :data-pathname data
 508                    :stylesheet-pathname stylesheet
 509                    :data-pathname-2 data-2
 510                    :stylesheet-pathname-2 stylesheet-2
 511                    :output-pathname output
 512                    :output-compare compare)))
 513
 514 ;; read from file P, skipping the XMLDecl or TextDecl and Doctype at the
 515 ;; beginning, if any.
 516 (defun slurp-for-comparison (p)
 517   (with-open-file (s p :element-type '(unsigned-byte 8))
 518     (unless (and (eql (read-byte s nil) #xef)
 519                  (eql (read-byte s nil) #xbb)
 520                  (eql (read-byte s nil) #xbf))
 521       (file-position s 0))
 522     (if (plusp (file-length s))
 523         (slurp-for-comparison-1 p s t)
 524         "<wrapper/>")))
 525
 526 (defun slurp-for-comparison-1 (p s junk-info)
 527   (let ((pos (file-position s))         ;for UTF-8 "BOM"
 528         (xstream (runes:make-xstream s :speed 1))
 529         (prev-pos 0))
 530     (setf (runes:xstream-name xstream)
 531           (cxml::make-stream-name
 532            :entity-name "main document"
 533            :entity-kind :main
 534            :uri (cxml::pathname-to-uri (merge-pathnames p))))
 535     (let ((source
 536            (flet ((er (pub sys)
 537                     pub sys
 538                     (flexi-streams:make-in-memory-input-stream
 539                      #())))
 540              (cxml:make-source xstream
 541                                :pathname p
 542                                :entity-resolver #'er))))
 543       (unless (eq junk-info :nada)
 544         (loop
 545            for key = (progn
 546                        (setf prev-pos (runes:xstream-position xstream))
 547                        (klacks:peek-next source))
 548            until (eq key :start-document))
 549         (cxml::with-source (source cxml::context)
 550           (when (eq (cxml::zstream-token-category
 551                      (cxml::main-zstream cxml::context))
 552                     :NMTOKEN)
 553             ;; oops, doesn't look like XML at all
 554             (file-position s pos)
 555             (return-from slurp-for-comparison-1
 556               (slurp-for-comparison-1 p s :nada)))))
 557       (etypecase junk-info
 558         (integer
 559          (dotimes (x junk-info)
 560            (setf prev-pos (runes:xstream-position xstream))
 561            (klacks:peek-next source)))
 562         ((eql t)
 563          (let ((nskip 0))
 564            (handler-case
 565                (loop
 566                   (case (klacks:peek-next source)
 567                     (:start-element (return))
 568                     (:characters
 569                      (if (whitespacep (klacks:current-characters source))
 570                          (incf nskip)
 571                          (return)))
 572                     (t
 573                      (incf nskip))))
 574              ((or file-error cxml:xml-parse-error) ()
 575                (when (zerop nskip)
 576                  (setf nskip nil))))
 577            ;; retry
 578            (with-open-file (u p :element-type '(unsigned-byte 8))
 579              (file-position u pos)
 580              (return-from slurp-for-comparison-1
 581                (slurp-for-comparison-1 p u nskip)))))
 582         ((member nil :nada)))
 583       (with-output-to-string (r)
 584         (let* ((seen-char
 585                 (cxml::with-source (source cxml::context)
 586                   (ecase (cxml::zstream-token-category
 587                           (cxml::main-zstream cxml::context))
 588                     (:seen-< #\<)
 589                     (:? #\?)
 590                     ((nil :s)
 591                      (setf prev-pos (runes:xstream-position xstream))
 592                      nil))))
 593                (off-by-one-p (or seen-char (eq junk-info :nada)))
 594                (new-pos (- prev-pos (if off-by-one-p 1 0))))
 595           ;; copy doctype over
 596           (with-open-file (u p :element-type '(unsigned-byte 8))
 597             (file-position u pos)
 598             (let ((y (runes:make-xstream u :speed 1)))
 599               (loop
 600                  while (< (runes:xstream-position y) new-pos)
 601                  do (write-char (runes:read-rune y) r))))
 602           (write-line "<wrapper>" r)
 603           (when seen-char
 604             (write-char seen-char r)))
 605         (loop
 606            for char = (runes:read-rune xstream)
 607            until (eq char :eof)
 608            do (write-char char r))
 609         (write-line "</wrapper>" r)))))
 610
 611 (defun parse-for-comparison (p)
 612   (let* ((d (flet ((er (pub sys)
 613                     pub sys
 614                     (flexi-streams:make-in-memory-input-stream
 615                      #())))
 616               (cxml:parse (slurp-for-comparison p)
 617                           (make-text-normalizer (stp:make-builder))
 618                           :entity-resolver #'er)))
 619          (de (stp:document-element d)))
 620     (let ((first (stp:first-child de)))
 621       (when (typep first 'stp:text)
 622         (cond
 623           ((whitespacep (stp:data first))
 624            (stp:delete-child first de))
 625           (t
 626            (setf (stp:data first)
 627                  (cl-ppcre:regex-replace #.(format nil "^[~A]+" *whitespace*)
 628                                          (stp:data first)
 629                                          ""))))))
 630     (let ((last (stp:last-child de)))
 631       (when (typep last 'stp:text)
 632         (cond
 633           ((whitespacep (stp:data last))
 634            (stp:delete-child last de))
 635           (t
 636            (setf (stp:data last)
 637                  (cl-ppcre:regex-replace #.(format nil "[~A]+$" *whitespace*)
 638                                          (stp:data last)
 639                                          ""))))))
 640     d))
 641
 642 (defun output-equal-p (compare p q &key normalize)
 643   (handler-case
 644       (ecase compare
 645         (:xml (xml-output-equal-p p q normalize))
 646         (:html (html-output-equal-p p q))
 647         (:text (text-output-equal-p p q)))
 648     ((or error parse-number::invalid-number) (c)
 649       (warn "comparison failed: ~A" c)
 650       nil)))
 651
 652 ;; Workaround for namespace_namespace23 and other tests:
 653 ;;  - For these tests, saxon and msxsl output a declaration for the XSL
 654 ;;    namespace without using that declaration.
 655 ;;  - I think saxon and msxsl are both wrong.
 656 ;;  - The official test output agrees with my assessment.
 657 ;;    (So does libxslt, but that's not to be trusted. :-))
 658 ;;  - Here's the catch: The official test output is broken in its whitespace
 659 ;;    handling.
 660 ;; So let's normalize spaces in test output that looks like an XSLT
 661 ;; stylesheet, allowing us to pass these tests using the official test output.
 662 (defun maybe-normalize-test-spaces (wrapper force)
 663   (let ((i 0))
 664     (loop while (< i (length (cxml-stp-impl::%children wrapper))) do
 665          (let ((wrapper-child (stp:nth-child i wrapper)))
 666            (cond
 667              ((not (typep wrapper-child 'stp:element))
 668               (if force
 669                   (stp:delete-nth-child i wrapper)
 670                   (incf i)))
 671              ((or (equal (stp:namespace-uri wrapper-child) *xsl*)
 672                   force)
 673               (strip-stylesheet wrapper-child)
 674               (labels ((recurse (e &optional preserve)
 675                          (stp:do-children (child e)
 676                            (typecase child
 677                              (stp:text
 678                               (setf (stp:data child)
 679                                     (normalize-whitespace (stp:data child))))
 680                              (stp:element
 681                                  (stp:with-attributes ((space "space" *xml*))
 682                                      child
 683                                    (let ((new-preserve
 684                                           (cond
 685                                             ((namep child "text") t)
 686                                             ((not space) preserve)
 687                                             ((equal space "preserve") t)
 688                                             (t nil))))
 689                                      (recurse child new-preserve))))))))
 690                 (recurse wrapper-child))
 691               (incf i))
 692              (t
 693               (incf i)))))))
 694
 695 (defun xml-output-equal-p (p q normalize)
 696   (let ((r (parse-for-comparison p))
 697         (s (parse-for-comparison q)))
 698     (maybe-normalize-test-spaces (stp:document-element r) normalize)
 699     (maybe-normalize-test-spaces (stp:document-element s) normalize)
 700     (and (let ((u (stp:document-type r))
 701                (v (stp:document-type s)))
 702            (if u
 703                (and v (node= u v))
 704                (null v)))
 705          (node= (stp:document-element r) (stp:document-element s)))))
 706
 707 ;; FIXME: don't do this in <pre> etc.
 708 (defun normalize-html-whitespace (node)
 709   (when (typep node 'stp:parent-node)
 710     ;; ignore newlines after start tags completely
 711     (let ((first (stp:first-child node)))
 712       (when (and (typep first 'stp:text)
 713                  (alexandria:starts-with #\newline (stp:data first)))
 714         (setf (stp:data first) (subseq (stp:data first) 1))))
 715     ;; ignore newlines before end tags completely
 716     (let ((last (stp:last-child node)))
 717       (when (and (typep last 'stp:text)
 718                  (alexandria:ends-with #\newline (stp:data last)))
 719         (setf (stp:data last)
 720               (subseq (stp:data last) 0 (length (stp:data last))))))
 721     ;; normalize sequences of whitespace
 722     (stp:do-children (child node)
 723       (if (typep child 'stp:text)
 724           (setf (stp:data child)
 725                 (let ((str (normalize-whitespace (stp:data child))))
 726                   (when
 727                       ;; FIXME!  Here we remove whitespace entirely.
 728                       ;; Totally incorrect, but I don't see how we could
 729                       ;; watch Saxon's output otherwise.
 730                       (equal str " ")
 731                     (setf str ""))
 732                   str))
 733           (normalize-html-whitespace child)))
 734     ;; just to be sure, join adjacent nodes
 735     (cxml-stp-impl::normalize-text-nodes! node)))
 736
 737 ;; FIXME: this check is too lenient, because chtml is an error-correcting
 738 ;; parser.
 739 (defun html-output-equal-p (p q)
 740   (let ((r (chtml:parse (pathname p) (stp:make-builder)))
 741         (s (chtml:parse (pathname q) (stp:make-builder))))
 742     (normalize-html-whitespace r)
 743     (normalize-html-whitespace s)
 744     (flet ((fix-case (node)
 745              (xpath:with-namespaces (("xhtml" "http://www.w3.org/1999/xhtml"))
 746                (xpath:do-node-set
 747                    (content (xpath:evaluate "//xhtml:meta/@content" node))
 748                  (setf (stp:value content)
 749                        (string-downcase (stp:value content)))))))
 750       (fix-case r)
 751       (fix-case s))
 752     (node= (stp:document-element r) (stp:document-element s))))
 753
 754 (defun text-output-equal-p (p q)
 755   (with-open-file (a p :element-type '(unsigned-byte 8))
 756     (with-open-file (b q :element-type '(unsigned-byte 8))
 757       (let ((len (file-length a)))
 758         (and (eql len (file-length b))
 759              (let ((d (make-array len :element-type '(unsigned-byte 8)))
 760                    (e (make-array len :element-type '(unsigned-byte 8))))
 761                (read-sequence d a)
 762                (read-sequence e b)
 763                (equalp d e)))))))
 764
 765 (defun strip-addresses (str)
 766   (cl-ppcre:regex-replace-all "{[0-9a-fA-F]+}\\>" str "{xxxxxxxx}>"))
 767
 768 (defun slurp-output-method (p)
 769   (xpath:with-namespaces ((nil #.*xsl*))
 770     (let* ((d (handler-bind
 771                   ((warning #'muffle-warning))
 772                 (cxml:parse (pathname p) (stp:make-builder))))
 773            (output (xpath:first-node (xpath:evaluate "//output" d))))
 774       (if output
 775           (let ((method (stp:attribute-value output "method")))
 776             (if method
 777                 (intern (string-upcase method) :keyword)
 778                 :xml))
 779           :xml))))
 780
 781 (defun replace-junk (str)
 782   (cl-ppcre:regex-replace-all
 783    `(:group ,(namestring *tests-directory*))
 784    (map 'string
 785         (lambda (c)
 786           (if (or (eql c #\newline) (<= 32 (char-code c) 126))
 787               c
 788               #\?))
 789         str)
 790    "..."))
 791
 792 (defun run-test (test)
 793   (let ((expected-saxon (test-output-pathname test "saxon"))
 794         #+xuriella::xsltproc
 795         (expected-xsltproc (test-output-pathname test "xsltproc"))
 796         (actual (test-output-pathname test "xuriella"))
 797         (official (test-official-output-pathname test))
 798         (force-normalization
 799          (find (test-id test) *whitespace-issues* :test #'equal))
 800         (output-method nil))
 801     (handler-bind ((|hey test suite, this is an HTML document|
 802                     (lambda (c)
 803                       (declare (ignore c))
 804                       (setf output-method :html))))
 805       (labels ((uri-resolver (uri)
 806                  (if (search "%5c%5c%5c%5cwebxtest%5c%5cmanagedshadow%5c%5cmanaged_b2%5c%5ctestdata%5c%5cxslt%5c%5celement%5c%5cxslt_element_NSShared.xml"
 807                              uri)
 808                      (cxml::pathname-to-uri
 809                       (merge-pathnames
 810                        "MSFT_Conformance_Tests/Elements/xslt_element_NSShared.xml"
 811                        *tests-directory*))
 812                      uri))
 813                (doit ()
 814                  (with-open-file (s actual
 815                                     :if-exists :rename-and-delete
 816                                     :direction :output
 817                                     :element-type '(unsigned-byte 8))
 818                    (handler-bind ((xslt-error
 819                                    (lambda (c)
 820                                      (declare (ignore c))
 821                                      (when (find-restart 'recover)
 822                                        (invoke-restart 'recover)))))
 823                      (apply-stylesheet (pathname (test-stylesheet-pathname test))
 824                                        (pathname (test-data-pathname test))
 825                                        :output s
 826                                        :uri-resolver #'uri-resolver))))
 827                (pp (label pathname)
 828                  (when pathname
 829                    (format t "  ~A: ~A~%"
 830                            label
 831                            (enough-namestring pathname *tests-directory*))))
 832                (report (ok &optional (fmt "") &rest args)
 833                  (write-string
 834                   (replace-junk
 835                    (strip-addresses
 836                     (format nil "~&~A ~A [~A]~?~%"
 837                             (cond
 838                               (ok "PASS")
 839                               ((find (test-id test)
 840                                      *known-failures*
 841                                      :test #'equal)
 842                                (setf ok :known-failure)
 843                                "KNOWNFAIL")
 844                               (t
 845                                "FAIL"))
 846                             (test-id test)
 847                             (test-category test)
 848                             fmt
 849                             args))))
 850                  (pp "Stylesheet" (test-stylesheet-pathname test))
 851                  (pp "Data" (test-data-pathname test))
 852                  (pp "Supplemental stylesheet"
 853                      (test-stylesheet-pathname-2 test))
 854                  (pp "Supplemental data" (test-data-pathname-2 test))
 855                  (pp "Expected output (1)" expected-saxon)
 856                  #+xuriella::xsltproc
 857                  (pp "Expected output (2)" expected-xsltproc)
 858                  (pp "Actual output" actual)
 859                  (terpri)
 860                  ok))
 861         (cond
 862           ((equal (test-operation test) "standard")
 863            (handler-case
 864                (progn
 865                  (when (find (test-id test)
 866                              nil ;;'("axes_axes47" "attribset_attribset20")
 867                              :test #'equal)
 868                    (error "skipping problematic test"))
 869                  (doit)
 870                  (let* ((output-method
 871                          (or output-method
 872                              (slurp-output-method
 873                               (test-stylesheet-pathname test))))
 874                         (saxon-matches-p
 875                          (output-equal-p output-method
 876                                          expected-saxon
 877                                          actual
 878                                          :normalize force-normalization))
 879                         #+xuriella::xsltproc
 880                         (xsltproc-matches-p
 881                          (output-equal-p output-method
 882                                          expected-xsltproc
 883                                          actual))
 884                         (official-matches-p
 885                          (output-equal-p output-method
 886                                          official
 887                                          actual
 888                                          :normalize force-normalization)))
 889                    (cond
 890                      ((or saxon-matches-p
 891                           #+xuriella::xsltproc xsltproc-matches-p
 892                           official-matches-p)
 893                       (report t)
 894                       #+xuriella::xsltproc
 895                       (report t ": saxon ~A, xsltproc ~A~:[~; (MISMATCH)~]"
 896                               saxon-matches-p
 897                               xsltproc-matches-p
 898                               (if saxon-matches-p
 899                                   (not xsltproc-matches-p)
 900                                   xsltproc-matches-p)))
 901                      (t
 902                       (report nil ": output doesn't match")))))
 903              ((or error parse-number::invalid-number) (c)
 904                (report nil ": ~A" c))))
 905           (t
 906            (handler-case
 907                (doit)
 908              (xslt-error (c)
 909                (report t ": raised an xslt-error as expected" c))
 910              ((or error parse-number::invalid-number) (c)
 911                (report nil ": condition of incorrect type: ~%~A" c))
 912              (:no-error (result)
 913                (cond
 914                  ((not (and official (probe-file official)))
 915                   (report nil ": expected error not signalled: " result))
 916                  ((output-equal-p
 917                    (or output-method
 918                        (slurp-output-method (test-stylesheet-pathname test)))
 919                    official
 920                    actual
 921                    :normalize force-normalization)
 922                   (report t))
 923                  (t
 924                   (report nil ": saxon error not signalled and official output not a match")))))))))))
 925
 926 (defun run-xpath-tests ()
 927   (run-tests :filter "XPath-Expression/|XSLT-Data-Model/"))
 928
 929
 930 ;;;; from cxml-stp-test
 931
 932 (defun assert-node= (a b)
 933   (unless (node= a b)
 934     (error "assertion failed: ~S and ~S are not NODE=" a b)))
 935
 936 (defun child-count (node)
 937   (stp:count-children-if (constantly t) node))
 938
 939 (defun named-node-= (a b)
 940   (and (equal (stp:namespace-uri a) (stp:namespace-uri b))
 941        ;; (equal (stp:namespace-prefix a) (stp:namespace-prefix b))
 942        (equal (stp:local-name a) (stp:local-name b))))
 943
 944 (defun parent-node-= (e f)
 945   (and (eql (child-count e)
 946             (child-count f))
 947        (every #'node= (stp:list-children e) (stp:list-children f))))
 948
 949 (defmethod node= ((e stp:element) (f stp:element))
 950   (and (named-node-= e f)
 951        (parent-node-= e f)
 952        (null
 953         (set-exclusive-or (stp:list-attributes e) (stp:list-attributes f)
 954                           :test #'node=))
 955        (block nil
 956          (flet ((check-namespaces (a b)
 957                   (let ((result ()))
 958                     (stp:map-extra-namespaces
 959                      (lambda (k v)
 960                        (unless (equal v (stp:find-namespace k b))
 961                          (return nil)))
 962                      a)
 963                     result)))
 964            (check-namespaces e f)
 965            (check-namespaces f e))
 966          t)))
 967
 968 (defmethod node= ((a stp:node) (b stp:node))
 969   nil)
 970
 971 (defmethod node= ((e stp:document) (f stp:document))
 972   (parent-node-= e f))
 973
 974 (defmethod node= ((a stp:attribute) (b stp:attribute))
 975   (and (named-node-= a b)
 976        (equal (stp:value a) (stp:value b))))
 977
 978 (defmethod node= ((a stp:comment) (b stp:comment))
 979   (equal (stp:data a) (stp:data b)))
 980
 981 (defmethod node= ((a stp:text) (b stp:text))
 982   (equal (stp:data a) (stp:data b)))
 983
 984 (defmethod node= ((a stp:processing-instruction)
 985                   (b stp:processing-instruction))
 986   (and (equal (stp:data a) (stp:data b))
 987        (equal (stp:target a) (stp:target b))))
 988
 989 (defmethod node= ((a stp:document-type) (b stp:document-type))
 990   (and (equal (stp:root-element-name a) (stp:root-element-name b))
 991        (equal (stp:public-id a) (stp:public-id b))
 992        (equal (stp:system-id a) (stp:system-id b))
 993        (equal (stp:internal-subset a) (stp:internal-subset b))))
 994
 995 (xpath-sys:define-xpath-function/eager
 996     xslt :print
 997     (thing)
 998   (if (xpath:node-set-p thing)
 999       (loop
1000          initially (format t ";;; node set:~%")
1001          for i from 0
1002          for node in (xpath:all-nodes thing)
1003          do
1004            (format t ";;;   ~D: ~A~%" i (type-of node)))
1005       (format t ";;; ~A~%" thing))
1006   thing)