format-number.lisp

   1 ;;; -*- show-trailing-whitespace: t; indent-tabs-mode: nil -*-
   2
   3 ;;; Copyright (c) 2008 David Lichteblau, Ivan Shvedunov.
   4 ;;; All rights reserved.
   5
   6 ;;; Redistribution and use in source and binary forms, with or without
   7 ;;; modification, are permitted provided that the following conditions
   8 ;;; are met:
   9 ;;;
  10 ;;;   * Redistributions of source code must retain the above copyright
  11 ;;;     notice, this list of conditions and the following disclaimer.
  12 ;;;
  13 ;;;   * Redistributions in binary form must reproduce the above
  14 ;;;     copyright notice, this list of conditions and the following
  15 ;;;     disclaimer in the documentation and/or other materials
  16 ;;;     provided with the distribution.
  17 ;;;
  18 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR 'AS IS' AND ANY EXPRESSED
  19 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  20 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
  22 ;;; DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23 ;;; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
  24 ;;; GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25 ;;; INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  26 ;;; WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  27 ;;; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  28 ;;; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29
  30 (in-package :xuriella)
  31
  32 (defstruct (decimal-format (:conc-name "DF/"))
  33   ;; picture string and output syntax:
  34   (decimal-separator #\.)               ;active
  35   (grouping-separator #\,)              ;active
  36   (zero-digit #\0)                      ;active
  37   (percent #\%)
  38   (per-mille (code-char #x2030))
  39
  40   ;; picture string syntax only
  41   (digit #\#)                           ;active
  42   (pattern-separator #\;)               ;active
  43
  44   ;; output syntax only:
  45   (infinity "Infinity")
  46   (nan "NaN")
  47   (minus-sign #\-))
  48
  49 (defstruct (picture (:conc-name "PIC/"))
  50   percentp
  51   per-mille-p
  52   prefix
  53   suffix
  54   integer-part-grouping-positions
  55   minimum-integer-part-size
  56   fractional-part-grouping-positions
  57   minimum-fractional-part-size
  58   maximum-fractional-part-size)
  59
  60 (defun df/active-characters (df)
  61   (format nil "~C~C~C~C~C"
  62           (df/decimal-separator df)
  63           (df/grouping-separator df)
  64           (df/zero-digit df)
  65           (df/digit df)
  66           (df/pattern-separator df)))
  67
  68 (defun df/digits (df)
  69   (let ((result (make-array 10))
  70         (start (char-code (df/zero-digit df))))
  71     (loop
  72        for i from 0 below 10
  73        do
  74          (setf (elt result i) (code-char (+ start i))))
  75     result))
  76
  77 (defun find-decimal-format (lname uri stylesheet &optional (errorp t))
  78   (or (gethash (cons lname uri)
  79                (stylesheet-decimal-formats stylesheet))
  80       (when errorp
  81         (xslt-error "decimal format not found: ~A/~A" lname uri))))
  82
  83 (defun (setf find-decimal-format) (newval lname uri stylesheet)
  84   (setf (gethash (cons lname uri)
  85                  (stylesheet-decimal-formats stylesheet))
  86         newval))
  87
  88 (defun decimal-format= (a b)
  89   (every (lambda (accessor)
  90            (equal (funcall accessor a)
  91                   (funcall accessor b)))
  92          (list #'df/decimal-separator
  93                #'df/grouping-separator
  94                #'df/zero-digit
  95                #'df/percent
  96                #'df/per-mille
  97                #'df/digit
  98                #'df/pattern-separator
  99                #'df/infinity
 100                #'df/nan
 101                #'df/minus-sign)))
 102
 103 (xpath-sys:define-xpath-function/lazy
 104     xslt :format-number
 105     (value picture &optional format-name)
 106   (let ((namespaces *namespaces*))
 107     (lambda (ctx)
 108       (let ((df
 109              (if format-name
 110                  (let ((qname (funcall format-name ctx)))
 111                    (multiple-value-bind (local-name uri)
 112                        (decode-qname/runtime qname namespaces nil)
 113                      (find-decimal-format local-name
 114                                           (or uri "")
 115                                           *stylesheet*)))
 116                  (find-decimal-format "" "" *stylesheet*))))
 117         (multiple-value-bind (pos neg)
 118             (parse-picture (xpath:string-value (funcall picture ctx)) df)
 119           (format-number (float (xpath:number-value (funcall value ctx))
 120                                 1.0d0)
 121                          pos
 122                          neg
 123                          df))))))
 124
 125 (defun test-format-number (value picture)
 126   (let ((df (make-decimal-format)))
 127     (multiple-value-bind (pos neg)
 128         (parse-picture picture df)
 129       (format-number value pos neg df))))
 130
 131 (defun parse-picture (picture df)
 132   (destructuring-bind (&optional positive negative &rest erroneous)
 133       (split-sequence:split-sequence
 134        (df/pattern-separator df)
 135        picture)
 136     (unless (and positive (not erroneous))
 137       (xpath:xpath-error "invalid pattern separators"))
 138     (unless negative
 139       (setf negative (concatenate 'string
 140                                   (string (df/minus-sign df))
 141                                   positive)))
 142     (values (parse-sub-picture positive df)
 143             (parse-sub-picture negative df))))
 144
 145 (defmacro df/case (df form &rest clauses)
 146   `(let ((.form ,form)
 147          (.df ,df))
 148      (cond
 149        ,@(loop
 150             for (accessor . body) in clauses
 151             collect `((eql (,accessor .df) .form) ,@body)))))
 152
 153 (defun parse-integer-picture (picture df start end)
 154   (let ((integer-part-grouping-positions '())
 155         (minimum-integer-part-size 0))
 156     (loop
 157        for i from start below end
 158        for c = (elt picture i)
 159        until (eql c (df/decimal-separator df))
 160        do
 161          (df/case df c
 162            (df/grouping-separator
 163             (push 0 integer-part-grouping-positions))
 164            (df/digit
 165             (when integer-part-grouping-positions
 166               (incf (car integer-part-grouping-positions))))
 167            (df/zero-digit
 168             (when integer-part-grouping-positions
 169               (incf (car integer-part-grouping-positions)))
 170             (incf minimum-integer-part-size)))
 171        finally
 172          (when integer-part-grouping-positions
 173            ;; zzz I wrote the above algorithm based on the XSLT 2.0 spec,
 174            ;; only to find out that the test suite doesn't want
 175            ;; multiple INTEGER-PART-GROUPING-POSITIONS.  Sun says
 176            ;; that only the last one is used:
 177            ;; http://java.sun.com/j2se/1.3/docs/api/java/text/DecimalFormat.html
 178            (setf integer-part-grouping-positions
 179                  (list (car integer-part-grouping-positions))))
 180          (return (values i
 181                          (loop
 182                             for pos in integer-part-grouping-positions
 183                             for accum = pos then (+ accum pos)
 184                             collect accum)
 185                          minimum-integer-part-size)))))
 186
 187 (defun parse-fractional-picture (picture df start end)
 188   (let ((fractional-part-grouping-positions '())
 189         (minimum-fractional-part-size 0)
 190         (maximum-fractional-part-size 0)
 191         (current-grouping 0))
 192     (loop
 193        for i from start below end
 194        for c = (elt picture i)
 195        do
 196          (df/case df c
 197            (df/grouping-separator
 198             (push current-grouping fractional-part-grouping-positions))
 199            (df/digit
 200             (incf current-grouping)
 201             (incf maximum-fractional-part-size))
 202            (df/zero-digit
 203             (incf current-grouping)
 204             (incf minimum-fractional-part-size)
 205             (incf maximum-fractional-part-size))
 206            (df/decimal-separator))
 207        finally
 208          (return (values (nreverse fractional-part-grouping-positions)
 209                          minimum-fractional-part-size
 210                          maximum-fractional-part-size)))))
 211
 212 (defun parse-sub-picture (picture df)
 213   (let ((active (df/active-characters df)))
 214     (flet ((activep (x) (find x active)))
 215       (let ((start (position-if #'activep picture))
 216             (last (position-if #'activep picture :from-end t)))
 217         (unless start
 218           (xpath:xpath-error "no digit-sign or zero-digit sign found"))
 219         (let* ((end (1+ last))
 220                (result (make-picture
 221                          :percentp (find (df/percent df) picture)
 222                          :per-mille-p (find (df/per-mille df) picture)
 223                          :prefix (subseq picture 0 start)
 224                          :suffix (subseq picture end))))
 225           (setf (values start
 226                         (pic/integer-part-grouping-positions result)
 227                         (pic/minimum-integer-part-size result))
 228                 (parse-integer-picture picture df start end))
 229           (setf (values (pic/fractional-part-grouping-positions result)
 230                         (pic/minimum-fractional-part-size result)
 231                         (pic/maximum-fractional-part-size result))
 232                 (parse-fractional-picture picture df start end))
 233           result)))))
 234
 235 (defun format-number (value positive-picture negative-picture df)
 236   (if (xpath::nan-p value)
 237       (df/nan df)
 238       (let ((picture (if (minusp value) negative-picture positive-picture)))
 239         (if (xpath::inf-p value)
 240             (concatenate 'string
 241                          (pic/prefix picture)
 242                          (df/infinity df)
 243                          (pic/suffix picture))
 244             (format-ordinary-number value picture df)))))
 245
 246 (defun format-number-~f (number picture df)
 247   (let* ((str (format nil "~,vF"
 248                       (pic/maximum-fractional-part-size picture)
 249                       number))
 250          (str (string-trim (string (df/zero-digit df)) str)) ;for 0.0
 251          (digits (df/digits df)))
 252     (map 'string
 253          (lambda (x)
 254            (if (eql x #\.)
 255                (df/decimal-separator df)
 256                (elt digits (- (char-code x) #.(char-code #\0)))))
 257          str)))
 258
 259 (defun make-grouping-test (positions)
 260   (if (and positions
 261            (let ((first (car positions)))
 262              (loop
 263                 for expected = first then (+ expected first)
 264                 for pos in positions
 265                 always (eql pos expected))))
 266       (let ((first (car positions)))
 267         (lambda (x)
 268           (and (plusp x) (zerop (mod x first)))))
 269       (lambda (x)
 270         (and (plusp x) (find x positions)))))
 271
 272 (defun format-ordinary-number (value picture df)
 273   (let* ((adjusted-number
 274           (cond
 275             ((pic/percentp picture)
 276              (* value 100))
 277             ((pic/per-mille-p picture)
 278              (* value 1000))
 279             (t
 280              value)))
 281          (str (format-number-~f (abs adjusted-number) picture df))
 282          (left (position (df/decimal-separator df) str))
 283          (right (1- (- (length str) left)))
 284          (wanted-left (max left (pic/minimum-integer-part-size picture)))
 285          (wanted-right (max right (pic/minimum-fractional-part-size picture)))
 286          (zero (df/zero-digit df))
 287          (left-test (make-grouping-test
 288                      (pic/integer-part-grouping-positions picture)))
 289          (right-test (make-grouping-test
 290                       (pic/fractional-part-grouping-positions picture))))
 291     (with-output-to-string (s)
 292       (write-string (pic/prefix picture) s)
 293       (loop
 294          for i from (1- wanted-left) downto 0
 295          for index from (- left wanted-left)
 296          do
 297            (if (< i left)
 298                (write-char (elt str index) s)
 299                (write-char zero s))
 300            (when (funcall left-test i)
 301              (write-char (df/grouping-separator df) s)))
 302       (when (plusp wanted-right)
 303         (write-char (df/decimal-separator df) s)
 304         (loop
 305            for i from 0 below wanted-right
 306            for index from (+ left 1)
 307            do
 308              (when (funcall right-test i)
 309                (write-char (df/grouping-separator df) s))
 310              (if (< i right)
 311                  (write-char (elt str index) s)
 312                  (write-char zero s))))
 313       (write-string (pic/suffix picture) s))))