arch/i386-all/stdc/math/s_remquo.s

   1 /*-
   2  * Copyright (c) 2005 David Schultz <das@FreeBSD.ORG>
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  */
  26
  27 /*
  28  * Based on public-domain remainder routine by J.T. Conklin <jtc@NetBSD.org>.
  29  */
  30
  31         #include "aros/i386/asm.h"
  32
  33         .text
  34         _ALIGNMENT
  35         .globl  AROS_CDEFNAME(remquo)
  36         _FUNCTION(AROS_CDEFNAME(remquo))
  37
  38         .set    FirstArg, 4 /* Skip Return-Adress */
  39         .set    arg_x, FirstArg
  40
  41         .set    SecondArg, 16 /* Skip FirstArg */
  42         .set    arg_y, SecondArg
  43
  44         .set    ThirdArg, 16 /* Skip SecondArg */
  45         .set    arg_quo, ThirdArg
  46
  47 AROS_CDEFNAME(remquo):
  48         fldl    12(%esp)
  49         fldl    4(%esp)
  50 1:      fprem1
  51         fstsw   %ax
  52         sahf
  53         jp      1b
  54         fstp    %st(1)
  55 /* Extract the three low-order bits of the quotient from C0,C3,C1. */
  56         shrl    $6,%eax
  57         movl    %eax,%ecx
  58         andl    $0x108,%eax
  59         rorl    $7,%eax
  60         orl     %eax,%ecx
  61         roll    $4,%eax
  62         orl     %ecx,%eax
  63         andl    $7,%eax
  64 /* Negate the quotient bits if x*y<0.  Avoid using an unpredictable branch. */
  65         movl    16(%esp),%ecx
  66         xorl    8(%esp),%ecx
  67         sarl    $16,%ecx
  68         sarl    $16,%ecx
  69         xorl    %ecx,%eax
  70         andl    $1,%ecx
  71         addl    %ecx,%eax
  72 /* Store the quotient and return. */
  73         movl    20(%esp),%ecx
  74         movl    %eax,(%ecx)
  75         ret