arch/.unmaintained/m68k-emul/dispatch.s

   1 /*
   2     Copyright © 1995-2001, The AROS Development Team. All rights reserved.
   3     $Id$
   4
   5     Desc: Exec function Dispatch()
   6     Lang: english
   7 */
   8
   9 /******************************************************************************
  10
  11     NAME
  12         AROS_LH0(void, Dispatch,
  13
  14     LOCATION
  15         struct ExecBase *, SysBase, 10, Exec)
  16
  17     FUNCTION
  18
  19     INPUTS
  20
  21     RESULT
  22
  23     NOTES
  24
  25     EXAMPLE
  26
  27     BUGS
  28
  29     SEE ALSO
  30
  31     INTERNALS
  32
  33     HISTORY
  34
  35 ******************************************************************************/
  36
  37         #include "machine.i"
  38
  39         .text
  40         .balign 16
  41         .globl  AROS_SLIB_ENTRY(Dispatch,Exec)
  42         .type   AROS_SLIB_ENTRY(Dispatch,Exec),@function
  43
  44 AROS_SLIB_ENTRY(Dispatch,Exec):
  45         /* move whole user context to user stack */
  46         movem.l %d0-%d7/%a0-%a6,-(%sp)
  47 #if !UseRegisterArgs
  48         move.l  64(%sp),%a6
  49 #endif
  50
  51         jbsr    AROS_CSYMNAME(os_disable)
  52
  53         /* get current task and store sp there */
  54         move.l  ThisTask(%a6),%a2
  55         move.l  %sp,tc_SPReg(%a2)
  56
  57         /* call the switch routine if necessary */
  58         btst    #TB_SWITCH,tc_Flags(%a2)
  59         jbeq    .noswch
  60         move.l  tc_Switch(%a2),%a5
  61         jsr     (%a5)
  62
  63         /* store IDNestCnt */
  64 .noswch:
  65         move.b  IDNestCnt(%a6),tc_IDNestCnt(%a2)
  66         move.b  #-1,IDNestCnt(%a6)
  67
  68         /* get task from ready list */
  69         move.l  TaskReady(%a6),%a2
  70         move.l  (%a2),%a0
  71         move.l  %a0,TaskReady(%a6)
  72         lea.l   TaskReady(%a6),%a1
  73         move.l  %a1,4.w(%a0)
  74
  75         /* and use it as new current task */
  76         move.l  %a2,ThisTask(%a6)
  77         move.b  #TS_RUN,tc_State(%a2)
  78         move.b  tc_IDNestCnt(%a2),IDNestCnt(%a6)
  79
  80         /* call the launch routine if necessary */
  81         btst    #TB_LAUNCH,tc_Flags(%a2)
  82         jbeq    .nolnch
  83         move.l  tc_Launch(%a2),%a5
  84         jsr     (%a5)
  85
  86         /* get stack pointer */
  87 .nolnch:
  88         move.l  tc_SPReg(%a2),%d0
  89
  90         /* Compare against SPLower */
  91         cmp.l   tc_SPLower(%a2),%d0
  92         jbls    .alert
  93
  94         /* Compare against SPUpper */
  95         cmp.l   tc_SPUpper(%a2),%d0
  96         jbcc    .alert
  97
  98         /* Put the SP into the correct register after checking */
  99         move.l  %d0,%sp
 100         /* Unblock signals if necessary */
 101         tst.b   tc_IDNestCnt(%a2)
 102         jbpl    .noen
 103         /* If called from the signal handler don't do it. */
 104         tst.b   AROS_CSYMNAME(supervisor)
 105         jbne    .noen
 106         jbsr    AROS_CSYMNAME(os_enable)
 107
 108 .noen:
 109         /* Except bit set? */
 110         btst    #TB_EXCEPT,tc_Flags(%a2)
 111         jbeq    .noexpt
 112
 113         /* Raise a task exception in Disable()d state. */
 114 #if !UseRegisterArgs
 115         move.l  %a6,-(%sp)
 116 #endif
 117 /*      jsr     Disable(%a6) */
 118         jsr     Exception(%a6)
 119 /*      jsr     Enable(%a6) */
 120 #if !UseRegisterArgs
 121         addq.w  #4,%sp
 122 #endif
 123
 124         /* restore context. */
 125 .noexpt:
 126         movem.l (%sp)+,%d0-%d7/%a0-%a6
 127         rts
 128
 129 .alert:
 130         /* Call Alert() */
 131 #if !UseRegisterArgs
 132         move.l  %a6,-(%sp)
 133 #endif
 134         move.l  #AT_DeadEnd,%d7
 135         or.l    #AN_StackProbe,%d7
 136 #if !UseRegisterArgs
 137         move.l  %d0,-(%sp)
 138 #endif
 139         jsr     Alert(%a6)
 140         /* Function does not return */