arch/.unmaintained/m68k-emul/exception.s

   1 /*
   2     Copyright © 1995-2001, The AROS Development Team. All rights reserved.
   3     $Id$
   4
   5     Desc: Exec function Exception
   6     Lang: english
   7 */
   8
   9 /******************************************************************************
  10
  11     NAME
  12         AROS_LH0(void, Exception,
  13
  14     LOCATION
  15         struct ExecBase *, SysBase, 11, Exec)
  16
  17     FUNCTION
  18
  19     INPUTS
  20
  21     RESULT
  22
  23     NOTES
  24
  25     EXAMPLE
  26
  27     BUGS
  28
  29     SEE ALSO
  30
  31     INTERNALS
  32
  33     HISTORY
  34
  35 ******************************************************************************/
  36
  37         #include "machine.i"
  38
  39         .text
  40         .balign 16
  41         .globl  AROS_SLIB_ENTRY(Exception,Exec)
  42         .type   AROS_SLIB_ENTRY(Exception,Exec),@function
  43 AROS_SLIB_ENTRY(Exception,Exec):
  44         movem.l %a2/%a6/%d2,-(%sp)
  45         /* First clear task exception bit. */
  46 #if !UseRegisterArgs
  47         move.l  16(%sp),%a6
  48 #endif
  49         move.l  ThisTask(%a6),%a2
  50         bclr    #TB_EXCEPT,tc_Flags(%a2)
  51
  52         /* If the exception is raised out of Wait IDNestCnt may be >0 */
  53         move.b  IDNestCnt(%a6),%d2
  54         /* Set it to a defined value */
  55         clr.b   IDNestCnt(%a6)
  56
  57 .exloop:        /* Get mask of signals causing the exception */
  58         move.l  tc_SigExcept(%a2),%d0
  59         and.l   tc_SigRecvd(%a2),%d0
  60         jbeq    .excend
  61
  62         /* Clear bits */
  63         eor.l   %d0,tc_SigExcept(%a2)
  64         eor.l   %d0,tc_SigRecvd(%a2)
  65
  66         /* Raise exception. Enable Interrupts */
  67         move.l  tc_ExceptData(%a2),%a1
  68 #if !UseRegisterArgs
  69         move.l  %a6,-(%sp)
  70 #endif
  71         jsr     Enable(%a6)
  72 #if !UseRegisterArgs
  73         move.l  %a6,-(%sp)
  74         move.l  %a1,-(%sp)
  75         move.l  %d0,-(%sp)
  76 #endif
  77         move.l  tc_ExceptCode(%a2),%a0
  78         jsr     (%a0)
  79 #if !UseRegisterArgs
  80         move.l  %a6,-(%sp)
  81 #endif
  82         jsr     Disable(%a6)
  83 #if !UseRegisterArgs
  84         add.w   #20,%sp
  85 #endif
  86
  87         /* Re-use returned bits */
  88         or.l    %d0,tc_SigExcept(%a2)
  89         jbra    .exloop
  90
  91 .excend:        /* Restore IDNestCnt and return */
  92         move.b  %d2,IDNestCnt(%a6)
  93         movem.l (%sp)+,%a2/%a6/%d2
  94         rts
  95