workbench/network/WirelessManager/wpa_supplicant/wpa_gui-qt4/wpa_gui.pro

   1 TEMPLATE        = app
   2 LANGUAGE        = C++
   3 TRANSLATIONS    = lang/wpa_gui_de.ts
   4
   5 CONFIG  += qt warn_on release
   6
   7 DEFINES += CONFIG_CTRL_IFACE
   8
   9 win32 {
  10   LIBS += -lws2_32 -static
  11   DEFINES += CONFIG_NATIVE_WINDOWS CONFIG_CTRL_IFACE_NAMED_PIPE
  12   SOURCES += ../../src/utils/os_win32.c
  13 } else:win32-g++ {
  14   # cross compilation to win32
  15   LIBS += -lws2_32 -static -mwindows
  16   DEFINES += CONFIG_NATIVE_WINDOWS CONFIG_CTRL_IFACE_NAMED_PIPE
  17   SOURCES += ../../src/utils/os_win32.c
  18   RESOURCES += icons_png.qrc
  19 } else:win32-x-g++ {
  20   # cross compilation to win32
  21   LIBS += -lws2_32 -static -mwindows
  22   DEFINES += CONFIG_NATIVE_WINDOWS CONFIG_CTRL_IFACE_NAMED_PIPE
  23   DEFINES += _X86_
  24   SOURCES += ../../src/utils/os_win32.c
  25   RESOURCES += icons_png.qrc
  26 } else {
  27   DEFINES += CONFIG_CTRL_IFACE_UNIX
  28   SOURCES += ../../src/utils/os_unix.c
  29 }
  30
  31 INCLUDEPATH     += . .. ../../src ../../src/utils
  32
  33 HEADERS += wpamsg.h \
  34         wpagui.h \
  35         eventhistory.h \
  36         scanresults.h \
  37         userdatarequest.h \
  38         networkconfig.h \
  39         addinterface.h \
  40         peers.h \
  41         stringquery.h
  42
  43 SOURCES += main.cpp \
  44         wpagui.cpp \
  45         eventhistory.cpp \
  46         scanresults.cpp \
  47         userdatarequest.cpp \
  48         networkconfig.cpp \
  49         addinterface.cpp \
  50         peers.cpp \
  51         stringquery.cpp \
  52         ../../src/common/wpa_ctrl.c
  53
  54 RESOURCES += icons.qrc
  55
  56 FORMS   = wpagui.ui \
  57         eventhistory.ui \
  58         scanresults.ui \
  59         userdatarequest.ui \
  60         networkconfig.ui \
  61         peers.ui
  62
  63
  64 unix {
  65   UI_DIR = .ui
  66   MOC_DIR = .moc
  67   OBJECTS_DIR = .obj
  68 }