alacritty/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Christian Rebischke <chris.rebischke@archlinux.org>
   2 # Maintainer: Jiachen YANG <farseerfc@archlinux.org>
   3 # Maintainer: Daniel M. Capella <polyzen@archlinux.org>
   4 # Maintainer: T.J. Townsend <blakkheim@archlinux.org>
   5 # Contributor: kpcyrd <git@rxv.cc>
   6 # Contributor: quininer <quininer@live.com>
   7
   8 pkgname='alacritty'
   9 pkgdesc="A cross-platform, GPU-accelerated terminal emulator"
  10 pkgver=0.12.0
  11 pkgrel=1
  12 arch=('x86_64')
  13 url="https://github.com/alacritty/alacritty"
  14 license=('Apache')
  15 makedepends=('git' 'rust' 'cargo' 'cmake' 'ncurses' 'desktop-file-utils' 'gdb' 'libxcb')
  16 depends=('freetype2' 'fontconfig' 'libxi' 'libxcursor' 'libxkbcommon' 'libxrandr')
  17 checkdepends=('ttf-dejavu') # for monospace fontconfig test
  18 optdepends=('ncurses: for alacritty terminfo database')
  19 source=("git+$url.git#tag=v$pkgver?signed")
  20 validpgpkeys=('4DAA67A9EA8B91FCC15B699C85CDAE3C164BA7B4'  # Christian Dürr <contact@christianduerr.com>
  21               'A56EF308A9F1256C25ACA3807EA8F8B94622A6A9') # Kirill Chibisov <contact@kchibisov.com>
  22 sha256sums=('SKIP')
  23
  24 prepare() {
  25   cd "$pkgname"
  26   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  27 }
  28
  29 build(){
  30   cd "$pkgname"
  31   CARGO_INCREMENTAL=0 cargo build --release --locked --offline
  32 }
  33
  34 check(){
  35   cd "$pkgname"
  36   CARGO_INCREMENTAL=0 cargo test --locked --offline
  37 }
  38
  39 package() {
  40   cd "$pkgname"
  41   desktop-file-install -m 644 --dir "$pkgdir/usr/share/applications/" "extra/linux/Alacritty.desktop"
  42   install -D -m755 "target/release/alacritty" "$pkgdir/usr/bin/alacritty"
  43   install -D -m644 "extra/alacritty.man" "$pkgdir/usr/share/man/man1/alacritty.1"
  44   install -D -m644 "extra/alacritty-msg.man" "$pkgdir/usr/share/man/man1/alacritty-msg.1"
  45   install -D -m644 "extra/linux/org.alacritty.Alacritty.appdata.xml" "$pkgdir/usr/share/appdata/org.alacritty.Alacritty.appdata.xml"
  46   install -D -m644 "alacritty.yml" "$pkgdir/usr/share/doc/alacritty/example/alacritty.yml"
  47   install -D -m644 "extra/completions/alacritty.bash" "$pkgdir/usr/share/bash-completion/completions/alacritty"
  48   install -D -m644 "extra/completions/_alacritty" "$pkgdir/usr/share/zsh/site-functions/_alacritty"
  49   install -D -m644 "extra/completions/alacritty.fish" "$pkgdir/usr/share/fish/vendor_completions.d/alacritty.fish"
  50   install -D -m644 "extra/logo/alacritty-term.svg" "$pkgdir/usr/share/pixmaps/Alacritty.svg"
  51 }