amtk/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3
   4 pkgname=amtk
   5 pkgver=5.6.1
   6 pkgrel=1
   7 pkgdesc="Actions, Menus and Toolbars Kit for GTK applications"
   8 url="https://gitlab.gnome.org/World/amtk"
   9 arch=(x86_64)
  10 license=(LGPL3)
  11 depends=(gtk3)
  12 makedepends=(meson git gobject-introspection gtk-doc)
  13 _commit=f0029cf75ec416159079a27b578b9253a04b1c5a  # tags/5.6.1^0
  14 source=("git+https://gitlab.gnome.org/World/amtk.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd amtk
  19   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd amtk
  24 }
  25
  26 build() {
  27   arch-meson amtk build
  28   meson compile -C build
  29 }
  30
  31 check() {
  32   meson test -C build --print-errorlogs
  33 }
  34
  35 package() {
  36   depends+=(libg{lib,object,io}-2.0.so libgtk-3.so)
  37   provides+=("libamtk-${pkgver%%.*}.so")
  38
  39   meson install -C build --destdir "$pkgdir"
  40 }