apitrace/trunk/PKGBUILD

   1 # Maintainer: Laurent Carlier <lordheavym@gmail.com>
   2 # Contributor: Luca Bennati <lucak3 AT gmail DOT com>
   3 # Contributor: Glaucous <glakke1 at gmail dot com>
   4
   5 pkgname=apitrace
   6 pkgver=11.1
   7 pkgrel=1
   8 pkgdesc="Graphics API Tracing"
   9 arch=('x86_64')
  10 url="https://github.com/apitrace/apitrace"
  11 license=('custom')
  12 makedepends=('cmake' 'git' 'mesa' 'qt5-base')
  13 depends=('python' 'libgl' 'procps-ng')
  14 optdepends=('qt5-base: GUI support')
  15 source=("$pkgname-$pkgver::git+https://github.com/apitrace/apitrace.git#tag=${pkgver}")
  16 sha256sums=(SKIP)
  17
  18 prepare() {
  19   cd apitrace-${pkgver}
  20
  21   git submodule update --init --depth 1 --recursive
  22 }
  23
  24 build() {
  25   cd apitrace-${pkgver}
  26
  27   cmake . -Bbuild -DCMAKE_INSTALL_PREFIX=/usr \
  28     -DENABLE_GUI=TRUE
  29   make -C build
  30 }
  31
  32 package() {
  33   cd apitrace-${pkgver}
  34
  35   make -C build DESTDIR="${pkgdir}/" install
  36
  37   install -m755 -d "${pkgdir}/usr/share/licenses/apitrace"
  38   install -m644 LICENSE "${pkgdir}/usr/share/licenses/apitrace/"
  39 }