apko/trunk/PKGBUILD

   1 # Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
   2
   3 pkgname=apko
   4 pkgver=0.8.0
   5 pkgrel=1
   6 pkgdesc="Declarative APK-based container building tool with support for sigstore signatures"
   7 url="https://github.com/chainguard-dev/apko"
   8 arch=('x86_64')
   9 license=('Apache-2.0')
  10 depends=('apk-tools' 'alpine-keyring')
  11 makedepends=('go')
  12 source=("https://github.com/chainguard-dev/apko/archive/v${pkgver}/apko-${pkgver}.tar.gz")
  13 b2sums=('095551b193fc97f9759b914831eda1b7bb0316ae6aff3f0c77fb025a65c651409e34f19987e3030ad19e74f8c9e7522363ae5d6e76346a1319136dbd4dead423')
  14
  15 build() {
  16   cd "${pkgname}-${pkgver}"
  17   mkdir build
  18   CGO_LDFLAGS="${LDFLAGS}" \
  19     GOFLAGS="-trimpath -buildmode=pie -mod=readonly" \
  20     go build -o build/ -tags -tags=pivkey,pkcs11key ./...
  21
  22   for i in bash fish zsh; do
  23     build/apko completion ${i} > ./apko.${i}
  24   done
  25 }
  26
  27 check() {
  28   cd "${pkgname}-${pkgver}"
  29   go test ./...
  30 }
  31
  32 package() {
  33   cd "${pkgname}-${pkgver}"
  34   install -Dm755 build/apko "${pkgdir}"/usr/bin/apko
  35   install -Dm644 apko.bash "${pkgdir}"/usr/share/bash-completion/completions/apko
  36   install -Dm644 apko.fish "${pkgdir}"/usr/share/fish/completions/apko.fish
  37   install -Dm644 apko.zsh "${pkgdir}"/usr/share/zsh/site-functions/_apko
  38 }
  39
  40 # vim: ts=2 sw=2 et: