arch-wiki-docs/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
   3
   4 pkgname=arch-wiki-docs
   5 pkgver=20230228
   6 pkgrel=1
   7 pkgdesc='Pages from Arch Wiki optimized for offline browsing'
   8 arch=('any')
   9 url='https://github.com/lahwaacz/arch-wiki-docs'
  10 license=('FDL')
  11 makedepends=(
  12   'git'
  13   'python'
  14   'python-simplemediawiki'
  15   'python-lxml'
  16   'python-cssselect'
  17   'python-requests'
  18 )
  19 options=('!strip')
  20 _commit='8082524dda618479fca65ab6cb13d69822d444bd'
  21 source=("$pkgname::git+https://github.com/lahwaacz/arch-wiki-docs#commit=$_commit")
  22 b2sums=('SKIP')
  23
  24 pkgver() {
  25   date "+%Y%m%d"
  26 }
  27
  28 prepare() {
  29   cd "$pkgname"
  30
  31   LANG=en_US.UTF-8 python \
  32     arch-wiki-docs.py \
  33     --output-directory "$srcdir/build_wiki" \
  34     --clean \
  35     --safe-filenames
  36 }
  37
  38 package() {
  39   install -vdm755 "$pkgdir/usr/share/doc/arch-wiki/html"
  40   cp -r build_wiki/* "$pkgdir/usr/share/doc/arch-wiki/html"
  41 }