asciidoctor/repos/community-any/PKGBUILD

   1 # Maintainer:  Christian Rebischke <chris.rebischke@archlinux.org>
   2 # Maintainer:  Andreas 'Segaja' Schleifer <segaja at archlinux dot org>
   3 # Contributor: Stefan Tatschner <rumpelsepp@sevenbyte.org>
   4 # Contributor: Nick Østergaard <oe.nick at gmail dot com>
   5 # Contributor: Nicolas Bigaouette <nbigaouette@chemcomp.com>
   6
   7 pkgname='asciidoctor'
   8 pkgver=2.0.18
   9 pkgrel=1
  10 pkgdesc='An implementation of AsciiDoc in Ruby'
  11 arch=('any')
  12 url='https://asciidoctor.org'
  13 license=('MIT')
  14 makedepends=('ruby-rdoc')
  15 depends=('ruby')
  16 options=('!emptydirs')
  17 source=("https://rubygems.org/downloads/${pkgname}-${pkgver}.gem")
  18 noextract=("$pkgname-$pkgver.gem")
  19 sha512sums=('522c0a587a95c7a5c5618f88832c11a547448d12b883ee9a7d9f6e8509b44e2c5c027cf23335790cbc5cd74dc297010141ac535c0ba45622e49eac8d70fe6127')
  20
  21 package() {
  22     local _gemdir="$(ruby -e 'puts Gem.default_dir')"
  23
  24     gem install --ignore-dependencies --no-user-install --verbose \
  25         -i "$pkgdir/$_gemdir" -n "$pkgdir/usr/bin" \
  26         "$pkgname-$pkgver.gem"
  27
  28     install -Dm644 "$pkgdir/$_gemdir/gems/$pkgname-$pkgver/LICENSE" \
  29         "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  30     install -Dm644 "$pkgdir/$_gemdir/gems/$pkgname-$pkgver/man/asciidoctor.1" \
  31         "$pkgdir/usr/share/man/man1/asciidoctor.1"
  32
  33     rm "$pkgdir/$_gemdir/cache/$pkgname-$pkgver.gem"
  34     rm -rf "$pkgdir/$_gemdir/gems/$pkgname-$pkgver/man"
  35 }