astyle/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: Lukas Fleischer <lfleischer@archlinux.org>
   3 # Contributor: Mateusz Herych <heniekk@gmail.com>
   4 # Contributor: Thomas Mader <thezema@gmail.com>
   5 # Contributor: Vinay S Shastry <vinayshastry@gmail.com>
   6 # Contributor: tardo <tardo@nagi-fanboi.net>
   7
   8 pkgname=astyle
   9 pkgver=3.2.1
  10 pkgrel=1
  11 pkgdesc='A free, fast and small automatic formatter for C, C++, C#, and Java source code.'
  12 arch=('x86_64')
  13 url='http://astyle.sourceforge.net/'
  14 license=('LGPL')
  15 depends=('glibc' 'gcc-libs')
  16 makedepends=('git' 'jdk8-openjdk')
  17 optdepends=('java-environment-openjdk')
  18 _commit='a865024320886da06f38ac090f0fb1325b39f1ab'
  19 source=(
  20   "$pkgname::git+https://gitlab.com/saalen/astyle.git#commit=$_commit"
  21   'simplify-makefile.patch'
  22 )
  23 b2sums=('SKIP'
  24         '155dca3520e1669713efbf42431e4ba2c9c05006dcd2a14f58252d9e6913aab799af7b64c9040201e99ff8d12f953918124c83845fcf64ec025fc131e7acdf1f')
  25
  26 pkgver() {
  27   cd "$pkgname"
  28
  29   git describe --tags | sed 's/^v//'
  30 }
  31
  32 prepare() {
  33   cd "$pkgname"
  34
  35   patch -p1 -i "$srcdir/simplify-makefile.patch"
  36 }
  37 build() {
  38   cd "$pkgname/AStyle/build/gcc"
  39
  40   JAVA_HOME=/usr/lib/jvm/java-8-openjdk make shared release java
  41 }
  42
  43 package() {
  44   cd "$pkgname/AStyle/build/gcc"
  45
  46   DESTDIR="$pkgdir" make install
  47 }