at/trunk/PKGBUILD

   1 # Maintainer: Alexander F Rødseth <xyproto@archlinux.org>
   2 # Contributor: Nathan Baum <n@p12a.org.uk>
   3 # Contributor: Judd Vinet <jvinet@zeroflux.org>
   4 # Contributor: Todd Musall <tmusall@comcast.net>
   5
   6 pkgname=at
   7 pkgver=3.2.5
   8 pkgrel=2
   9 pkgdesc='AT and batch delayed command scheduling utility and daemon'
  10 arch=('x86_64')
  11 url='https://salsa.debian.org/debian/at'
  12 license=('GPL')
  13 depends=('pam' 'flex')
  14 makedepends=('smtp-forwarder' 'git' 'systemd')
  15 backup=('etc/at.deny'
  16         'etc/pam.d/atd'
  17         'var/spool/atd/.SEQ')
  18 options=('!makeflags')
  19 validpgpkeys=('464BC7CD439FEE5E8B4098A0348A778D6885EF8F') # Jose M Calhariz (Técnico) <jose.calhariz@tecnico.ulisboa.pt>
  20 source=("http://software.calhariz.com/$pkgname/${pkgname}_${pkgver}.orig.tar.gz"{,.sig}
  21         '80-atd.hook'
  22         'pam.conf')
  23 sha256sums=('bb066b389d7c9bb9d84a35738032b85c30cba7d949f758192adc72c9477fd3b8'
  24             'SKIP'
  25             'a7048d6dbd8aa4d881979716829d16053b5007c2d83eb2167edd5221f9e48a33'
  26             '663cd2f7c5abf56d1ea3f38dfac8d3e64896f1384ca5e97b7ec6d26fd6afafef')
  27
  28 build() {
  29   cd "$pkgname-$pkgver"
  30
  31   ./configure \
  32     --prefix=/usr \
  33     --sbindir=/usr/bin \
  34     --with-jobdir=/var/spool/atd \
  35     --with-atspool=/var/spool/atd \
  36     --with-systemdsystemunitdir=/usr/lib/systemd/system
  37
  38   CFLAGS="$CFLAGS -w" make
  39 }
  40
  41 package() {
  42   make -C "$pkgname-$pkgver" IROOT="$pkgdir" docdir=/usr/share/doc install
  43
  44   install -D -m0644 pam.conf "$pkgdir"/etc/pam.d/atd
  45   install -D -m0644 80-atd.hook "$pkgdir"/usr/share/libalpm/hooks/80-atd.hook
  46 }
  47
  48 # vim:set ts=2 sw=2 et: