atool/repos/community-any/PKGBUILD

   1 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   2 # Contributor: Jaroslav Lichtblau <svetlemodry@archlinux.org>
   3 # Contributor: leif_thande <leif.thande@gmail.com>
   4 # Contributor: tranquility <trankas@gmail.com>
   5 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   6
   7 pkgname=atool
   8 pkgver=0.39.0
   9 pkgrel=8
  10 pkgdesc='A script for managing file archives of various types'
  11 arch=(any)
  12 url="https://www.nongnu.org/$pkgname"
  13 license=(GPL3)
  14 depends=(file
  15          perl)
  16 optdepends=('bzip2: support bzip2 compression'
  17             'cpio: support cpio archives'
  18             'gzip: support gzip compression'
  19             'lha: support lha, lharc, and similar archives'
  20             'xz: support lzma compressed archives'
  21             'lzop: support lzop compressed archives'
  22             'p7zip: support 7z cpmressed archives'
  23             'tar: support tar archives'
  24             'unace: support ace archives'
  25             'unrar: support rar archives'
  26             'zip: support creating zip archives'
  27             'unzip: support extracting zip archives')
  28 _archive="$pkgname-$pkgver"
  29 source=("https://savannah.nongnu.org/download/$pkgname/$_archive.tar.gz"{,.sig})
  30 validpgpkeys=('4E6E6521EF300E30457D7AFB8AAAC30E7088EFCB') # Oskar Liljeblad <oskar@osk.mine.nu>
  31 sha256sums=('aaf60095884abb872e25f8e919a8a63d0dabaeca46faeba87d12812d6efc703b'
  32             'SKIP')
  33
  34 build() {
  35   cd "$_archive"
  36   ./configure --prefix=/usr
  37 }
  38
  39 package() {
  40   cd "$_archive"
  41   make DESTDIR="$pkgdir" install
  42 }