binwalk/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Frederik Schwan <freswa at archlinux dot org>
   3 # Contributor: Peter Wu <peter@lekensteyn.nl>
   4 # Contributor: Miguel Revilla <yo@miguelrevilla.com>
   5 # Contributor: s1gma <s1gma@mindslicer.com>
   6
   7 pkgname=binwalk
   8 pkgver=2.3.4
   9 pkgrel=2
  10 pkgdesc='Tool for searching a given binary image for embedded files'
  11 url='https://github.com/ReFirmLabs/binwalk'
  12 arch=('any')
  13 license=('MIT')
  14 depends=('python')
  15 optdepends=(
  16   'python-opengl: binviz module support'
  17   'python-capstone: disassembly support'
  18   'python-matplotlib: entropy plotting'
  19   'python-pyqtgraph: entropy plotting'
  20   'arj: ARJ decompression support'
  21   'cabextract: CAB archive support'
  22   'cpio: CPIO archive support'
  23   'gzip: GZIP decompression support'
  24   'mtd-utils: JFFS filesystem support'
  25   'p7zip: ZIP, LZMA and ISO decompression support'
  26   'squashfs-tools: squashfs support'
  27   'tar: TAR archive support'
  28   'bzip2: BZIP2 archive support'
  29   'unrar: RAR decompression support'
  30   'xz: XZ decompression support'
  31   'lhasa: LHA support'
  32   'sleuthkit: forensic analysis support'
  33 )
  34 source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
  35 sha512sums=('5a5e16035dfc05b94ae4ee3969a337336c550606b71e20fcb1f150c4b38ef2084b6a823ce2a8050f4b41616b7d7c31cfb04bf43e7f2c977ab1a634aba9d67fec')
  36 b2sums=('a5eac4242402c5034c293432131950bed9aff762c5db86b200a1f555bdfeeb1c6fda225393149f7beca2923141f2ae7930738038f2d039513cb06dfae9601b81')
  37
  38 build() {
  39   cd ${pkgname}-${pkgver}
  40   python setup.py build
  41 }
  42
  43 package() {
  44   cd ${pkgname}-${pkgver}
  45   python setup.py install -O1 --prefix="${pkgdir}/usr"
  46   install -Dm 644 *.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  47   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  48 }
  49
  50 # vim: ts=2 sw=2 et: