broot/trunk/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   3 # Contributor: Adam Fontenot <adam.m.fontenot@gmail.com>
   4 # Contributor: Daniel M. Capella <polyzen@archlinux.org>
   5
   6 pkgname=broot
   7 pkgver=1.21.3
   8 pkgrel=1
   9 pkgdesc='Fuzzy Search + tree + cd'
  10 arch=('x86_64')
  11 url=https://github.com/Canop/broot
  12 license=('MIT')
  13 depends=('gcc-libs' 'zlib' 'libgit2' 'libxcb')
  14 makedepends=('rust')
  15 options=('!lto')
  16 source=("https://github.com/Canop/broot/archive/v$pkgver/$pkgname-v$pkgver.tar.gz")
  17 sha256sums=('6c612c596e467e610c7a80b4f086d9443e2b5040edcfa1bdda129aa715bb64d9')
  18
  19 prepare() {
  20   cd $pkgname-$pkgver
  21   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  22 }
  23
  24 build() {
  25   cd $pkgname-$pkgver
  26   cargo build --release --frozen --features clipboard
  27 }
  28
  29 check() {
  30   cd $pkgname-$pkgver
  31   cargo test --frozen
  32 }
  33
  34 package() {
  35   cd $pkgname-$pkgver
  36   install -Dt "$pkgdir"/usr/bin target/release/$pkgname
  37   sed -i "s/#version/$pkgver/" man/page
  38   # Theoretically we could get the date from the CHANGELOG.md but it seems that the
  39   # CHANGELOG.md entry for the current version isn't actually in the current release.
  40   # changelog_date=$(sed -n "s/.*v$pkgver - \(.*\)$/\1/p" CHANGELOG.md)
  41   sed -i "s/#date//" man/page
  42   install -Dm644 man/page "$pkgdir/usr/share/man/man1/$pkgname.1"
  43   install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  44   install -Dm644 resources/icons/vscode/vscode.ttf "$pkgdir/usr/share/fonts/TTF/vscode.ttf"
  45 }
  46
  47 # vim:set ts=2 sw=2 et: