cage/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Maintainer: Brett Cornwall <ainola@archlinux.org>
   3
   4 pkgname=cage
   5 pkgver=0.1.4
   6 pkgrel=11
   7 pkgdesc="A kiosk compositor for Wayland"
   8 arch=(x86_64)
   9 url="https://www.hjdskes.nl/projects/cage/"
  10 license=(MIT)
  11 depends=(glibc wayland wlroots0.15)
  12 makedepends=(git libxkbcommon meson pixman scdoc wayland-protocols
  13 xorg-server-xwayland)
  14 optdepends=(
  15   'polkit: System privilege control. Required if not using seatd service'
  16   'xorg-server-xwayland: X11 support'
  17 )
  18 source=("${pkgname}::git+https://github.com/Hjdskes/${pkgname}.git#tag=v${pkgver}?signed")
  19 install=cage.install
  20 sha512sums=('SKIP')
  21 validpgpkeys=('13B6A35E9FD677D02CD68DBE37C445296EBC43B1') # Jente Hidskes <dev@hjdskes.nl>
  22
  23 prepare() {
  24   cd "${pkgname}"
  25   # add support for wlroots 0.15.0
  26   git cherry-pick -n 1a3ab3eb3ad0f4a1addb8f9a9427d8b369b19511
  27   git cherry-pick -n 8385b62a9b31028fa356cc4130baebc8b6f4adec
  28   git cherry-pick -n 388d60d6b88733330fb83dd440051ee805cc7ec7
  29   git cherry-pick -n 395189fb051ed722c7b10b6cb11caa8f6904079c
  30 }
  31
  32 build() {
  33   export PKG_CONFIG_PATH='/usr/lib/wlroots0.15/pkgconfig'
  34   arch-meson -Dxwayland=true build "$pkgname"
  35   ninja -C build
  36 }
  37
  38 check() {
  39   ninja -C build test
  40 }
  41
  42 package() {
  43   depends+=(libwlroots.so=10 libxkbcommon.so libpixman-1.so)
  44
  45   DESTDIR="${pkgdir}" meson install -C build
  46   install -vDm 644 "$pkgname/README.md" -t "${pkgdir}/usr/share/doc/${pkgname}"
  47   install -vDm 644 "$pkgname/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
  48 }