caja-extensions/trunk/PKGBUILD

   1 # Maintainer: Alexander Epaneshnikov <alex19ep@archlinux.org>
   2 # Contributor: Brad Fanella <cesura@archlinux.org>
   3 # Contributor: Martin Wimpress <code@flexion.org>
   4
   5 pkgbase=caja-extensions
   6 pkgname=(caja-extensions-common caja-image-converter caja-open-terminal caja-sendto caja-share caja-wallpaper caja-xattr-tags caja-audio-video-properties)
   7 pkgver=1.27.0
   8 pkgrel=1
   9 pkgdesc="Caja extensions"
  10 url="https://mate-desktop.org"
  11 arch=('x86_64')
  12 license=('GPL')
  13 depends=('caja' 'gettext' 'dbus-glib' 'imagemagick' 'samba')
  14 makedepends=('python' 'gst-plugins-base')
  15 source=("https://pub.mate-desktop.org/releases/${pkgver%.*}/$pkgbase-$pkgver.tar.xz")
  16 sha256sums=('66651e369f7e266feb317acb68361a4eb5b74210c6e0d0d5a1a5faec4f57180e')
  17
  18 build() {
  19     cd ${pkgbase}-${pkgver}
  20
  21     # UPnP support needs to be ported to GUPnP 1.6
  22     # before it can be activated again
  23     # https://github.com/mate-desktop/caja-extensions/issues/110
  24
  25     ./configure \
  26         --prefix=/usr \
  27         --disable-upnp \
  28         --disable-gksu
  29
  30     #https://bugzilla.gnome.org/show_bug.cgi?id=656231
  31     sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  32
  33     make
  34 }
  35
  36 package_caja-extensions-common() {
  37     pkgdesc="Caja extensions (common files)"
  38     depends=()
  39
  40     cd ${pkgbase}-${pkgver}
  41     make -C po DESTDIR="${pkgdir}" install
  42 }
  43
  44 package_caja-image-converter() {
  45     pkgdesc="A Caja extension for simple image conversions"
  46     depends=('caja' 'caja-extensions-common' 'imagemagick')
  47     groups=('mate-extra')
  48     conflicts=('caja-image-converter-gtk3')
  49     replaces=('caja-image-converter-gtk3')
  50
  51     cd ${pkgbase}-${pkgver}
  52     make -C image-converter DESTDIR="${pkgdir}" install
  53 }
  54
  55 package_caja-open-terminal() {
  56     pkgdesc="A Caja extension for opening terminals in arbitrary local paths"
  57     depends=('caja' 'caja-extensions-common')
  58     groups=('mate-extra')
  59     conflicts=('caja-open-terminal-gtk3')
  60     replaces=('caja-open-terminal-gtk3')
  61
  62     cd "${srcdir}/${pkgbase}-${pkgver}"
  63     make -C open-terminal DESTDIR="${pkgdir}" install
  64 }
  65
  66 package_caja-sendto() {
  67     pkgdesc="A Caja extension for sending files"
  68     depends=('caja' 'caja-extensions-common' 'dbus-glib')
  69     groups=('mate-extra')
  70     optdepends=('pidgin: Support for sending to instant messaging networks.'
  71                 'gajim: Support for sending to XMPP.')
  72     conflicts=('caja-sendto-gtk3')
  73     replaces=('caja-sendto-gtk3')
  74
  75     cd ${pkgbase}-${pkgver}
  76     make -C sendto DESTDIR="${pkgdir}" install
  77 }
  78
  79 package_caja-share() {
  80     pkgdesc="A Caja extension to quickly share a folder"
  81     depends=('caja' 'caja-extensions-common' 'samba')
  82     groups=('mate-extra')
  83     conflicts=('caja-share-gtk3')
  84     replaces=('caja-share-gtk3')
  85
  86     cd ${pkgbase}-${pkgver}
  87     make -C share DESTDIR="${pkgdir}" install
  88 }
  89
  90 package_caja-wallpaper() {
  91     pkgdesc="A Caja extension to quickly set wallpaper"
  92     depends=('caja' 'caja-extensions-common')
  93     groups=('mate-extra')
  94     conflicts=('caja-wallpaper-gtk3')
  95     replaces=('caja-wallpaper-gtk3')
  96
  97     cd ${pkgbase}-${pkgver}
  98     make -C wallpaper DESTDIR="${pkgdir}" install
  99 }
 100
 101 package_caja-xattr-tags() {
 102     pkgdesc="A Caja extension to see tags stored on xattrs"
 103     depends=('caja' 'caja-extensions-common')
 104     groups=('mate-extra')
 105
 106     cd ${pkgbase}-${pkgver}
 107     make -C xattr-tags DESTDIR="${pkgdir}" install
 108 }
 109
 110 package_caja-audio-video-properties() {
 111     pkgdesc="A Caja extension to see information about audio or video files"
 112     depends=('caja' 'caja-extensions-common' 'gst-plugins-base')
 113     groups=('mate-extra')
 114
 115     cd ${pkgbase}-${pkgver}
 116     make -C audio-video-properties DESTDIR="${pkgdir}" install
 117 }