cargo-pgrx/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=cargo-pgrx
   4 pkgver=0.8.3
   5 pkgrel=1
   6 pkgdesc='Build PostgreSQL extensions with Rust'
   7 arch=('x86_64')
   8 url='https://github.com/tcdi/pgrx'
   9 license=('MIT')
  10 depends=('gcc-libs' 'openssl' 'clang' 'llvm' 'bzip2')
  11 makedepends=('git' 'rust')
  12 optdepends=('postgresql: to compile with system postgresql')
  13 replaces=('cargo-pgx')
  14 options=('!lto')
  15 _commit='92750b42529aa5221640823a91e78c34a3821eed'
  16 source=("$pkgname::git+$url.git#commit=$_commit")
  17 b2sums=('SKIP')
  18
  19 pkgver() {
  20   cd "$pkgname"
  21
  22   git describe --tags | sed 's/^v//'
  23 }
  24
  25 prepare() {
  26   cd "$pkgname"
  27
  28   # download dependencies
  29   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  30 }
  31
  32 build() {
  33   cd "$pkgname"
  34
  35   cargo build --release --frozen --package "$pkgname"
  36 }
  37
  38 package() {
  39   cd "$pkgname"
  40
  41   # binary
  42   install -vDm755 -t "$pkgdir/usr/bin" "target/release/$pkgname"
  43
  44   # documentation
  45   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
  46
  47   # license
  48   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  49 }