cargo-supply-chain/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=cargo-supply-chain
   4 pkgver=0.3.2
   5 pkgrel=1
   6 pkgdesc='Gather author, contributor and publisher data on crates in your dependency graph'
   7 arch=('x86_64')
   8 url='https://github.com/rust-secure-code/cargo-supply-chain'
   9 license=('Apache' 'MIT' 'ZLIB')
  10 depends=('gcc-libs')
  11 makedepends=('rust')
  12 options=('!lto')
  13 source=("$pkgname-$pkgver.tar.gz::https://static.crates.io/crates/$pkgname/$pkgname-$pkgver.crate")
  14 sha512sums=('1ae7882db47c1fd2b0cbbfb8bd43b1a571bb72bfd5ba3d113102b1fc56d2f8a7ae79d2b700de0d6435b48b0d553d485dd633240934034e50ee10c817d279875e')
  15 b2sums=('c196e9b8bd6882c6fa4360f27d623ff91275a0209612a1b74043a9869ead3e21557052d107d15d8daa378e35722ead6a519f5969d5882c63622547d467b6a6b4')
  16
  17 prepare() {
  18   cd "$pkgname-$pkgver"
  19
  20   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  21 }
  22
  23 build() {
  24   cd "$pkgname-$pkgver"
  25
  26   cargo build --release --frozen --all-features
  27 }
  28
  29 check() {
  30   cd "$pkgname-$pkgver"
  31
  32   cargo test --frozen --all-features
  33 }
  34
  35 package() {
  36   cd "$pkgname-$pkgver"
  37
  38   # binary
  39   install -vDm755 -t "$pkgdir/usr/bin" "target/release/$pkgname"
  40
  41   # documentation
  42   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
  43
  44   # licenses
  45   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE*
  46 }