cargo-watch/trunk/PKGBUILD

   1 # Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
   2 # Contributor: Vlad M. <vlad@archlinux.net>
   3
   4 pkgname=cargo-watch
   5 pkgver=8.4.0
   6 pkgrel=1
   7 pkgdesc="Utility for Cargo to compile projects when sources change"
   8 url='https://github.com/passcod/cargo-watch'
   9 arch=('x86_64')
  10 license=('CC0-1.0')
  11 depends=('cargo')
  12 makedepends=('ruby-ronn')
  13 source=("https://github.com/passcod/${pkgname}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
  14 sha256sums=('8da79b5e4606d609af4d995038e9edb2425466bc162f3b0f7f2b2f6133a2e01d')
  15 b2sums=('2ecfe5e6785d71b393a2a5ddb93b59e230d8f7dfa4e6e16f462e8c511c1c8524ef24c0e66ea3d906d12171b5ca0e9ba3a29a1fe09ee89b564d46a1b47b3f8aae')
  16
  17 prepare() {
  18   cd "${pkgname}-${pkgver}"
  19   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  20 }
  21
  22 build() {
  23   cd ${pkgname}-${pkgver}
  24   cargo build --frozen --release
  25   ronn --roff cargo-watch.1.ronn
  26 }
  27
  28 package() {
  29   cd ${pkgname}-${pkgver}
  30   install -Dm 755 "target/release/${pkgname}" -t "${pkgdir}/usr/bin"
  31
  32   install -Dm 644 completions/zsh "${pkgdir}/usr/share/zsh/site-functions/_cargo-watch"
  33   install -Dm 644 cargo-watch.1 -t "${pkgdir}/usr/share/man/man1"
  34
  35   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  36   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  37 }
  38
  39 # vim: ts=2 sw=2 et: