certbot-nginx/repos/community-any/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: Felix Yan <felixonmars@archlinux.org>
   3 # Contributor: Gordian Edenhofer <gordian.edenhofer[at]yahoo[dot]de>
   4
   5 pkgname=certbot-nginx
   6 pkgver=2.6.0
   7 pkgrel=1
   8 pkgdesc='Nginx plugin for Certbot'
   9 arch=('any')
  10 license=('Apache')
  11 url='https://pypi.python.org/pypi/certbot-nginx'
  12 depends=(
  13   "certbot=$pkgver"
  14   "python-acme=$pkgver"
  15   'python-pyopenssl'
  16   'python-pyparsing'
  17   'python-setuptools'
  18 )
  19 makedepends=(
  20   'git'
  21   'python-build'
  22   'python-wheel'
  23   'python-installer'
  24 )
  25 checkdepends=('python-pytest')
  26 # git repository is used because certbot is a huge monorepo and it's easier to
  27 # share the entire repository across all certbot related packages than a few
  28 # hundred tarballs.
  29 _commit='013621d04ed26377cf6616448b21a4c050683719'
  30 _repo='github.com-certbot-certbot'
  31 source=("$_repo::git+https://github.com/certbot/certbot#commit=$_commit")
  32 b2sums=('SKIP')
  33
  34 pkgver() {
  35   cd "$_repo"
  36
  37   git describe --tags | sed 's/^v//'
  38 }
  39
  40 prepare() {
  41   cd "$_repo/$pkgname"
  42
  43   # nuke setuptools from orbit ^W install_requires
  44   sed \
  45     -e '/setuptools>=/d' \
  46     -i setup.py
  47 }
  48
  49 build() {
  50   cd "$_repo/$pkgname"
  51
  52   python -m build --wheel --no-isolation
  53 }
  54
  55 check() {
  56   cd "$_repo/$pkgname"
  57
  58   # https://github.com/certbot/certbot/issues/9606
  59   pytest -v -W ignore::DeprecationWarning
  60 }
  61
  62 package() {
  63   cd "$_repo/$pkgname"
  64
  65   python -m installer --destdir="$pkgdir" dist/*.whl
  66 }