chezmoi/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Daurnimator <daurnimator@archlinux.org>
   2 # Contributor: Tom Payne <twpayne@gmail.com>
   3 # Contributor:  <godeater@gmail.com>
   4
   5 pkgname=chezmoi
   6 pkgver=1.6.1
   7 pkgrel=2
   8 pkgdesc="Multi-machine dotfile management system"
   9 arch=('x86_64')
  10 url='https://github.com/twpayne/chezmoi'
  11 license=('MIT')
  12 makedepends=('go-pie' 'git')
  13 depends=('glibc')
  14 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/twpayne/chezmoi/archive/v${pkgver}.tar.gz")
  15 sha256sums=('ab315e88cc1740468adac51d0e8e57b6b9553b0668e178b44ef32074b791c8e8')
  16
  17 build() {
  18   cd "$pkgname-$pkgver"
  19
  20   go build \
  21     -gcflags "all=-trimpath=${PWD}" \
  22     -asmflags "all=-trimpath=${PWD}" \
  23     -ldflags "-extldflags ${LDFLAGS}" \
  24     .
  25 }
  26
  27 package() {
  28   cd "$pkgname-$pkgver"
  29
  30   install -D "$pkgname" "$pkgdir/usr/bin/$pkgname"
  31
  32   install -Dm644 completions/chezmoi-completion.bash "$pkgdir/usr/share/bash-completion/completions/chezmoi"
  33   install -Dm644 completions/chezmoi.fish "$pkgdir/usr/share/fish/vendor_completions.d/chezmoi.fish"
  34   install -Dm644 completions/chezmoi.zsh "$pkgdir/usr/share/zsh/site-functions/_chezmoi"
  35
  36   install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  37 }