clamtk/repos/community-any/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Blaž Tomažič <blaz.tomazic@gmail.com>
   3
   4 pkgname=clamtk
   5 pkgver=6.14
   6 pkgrel=1
   7 pkgdesc='Easy to use, light-weight, on-demand virus scanner for Linux systems'
   8 url='https://gitlab.com/dave_m/clamtk/-/wikis/home'
   9 arch=('any')
  10 license=('GPL')
  11 depends=('clamav' 'perl' 'perl-gtk3' 'perl-locale-gettext' 'perl-libwww' 'perl-http-message'
  12          'perl-lwp-protocol-https' 'perl-text-csv' 'perl-json' 'python' 'zenity' 'desktop-file-utils'
  13          'cron')
  14 source=(https://github.com/dave-theunsub/clamtk/releases/download/v${pkgver}/clamtk-${pkgver}.tar.xz{,.asc})
  15 sha512sums=('e5fb584f85f7e89eae10ed15ffa0268ecf79d81baf2bbf5d5974c080014d7fe24e4350c0139e8372d0e45a94302a0ec2cd824d05e04fee29dc681cbaf9d0fe14'
  16             'SKIP')
  17 validpgpkeys=('5DD47B3B121EE5C354A20305F51D19546ADA59DE') # Dave Mauroni <dave.nerd@gmail.com>
  18
  19 package() {
  20   cd ${pkgname}-${pkgver}
  21
  22   install -Dm 755 clamtk -t "${pkgdir}/usr/bin"
  23   for f in lib/* ; do
  24     install -Dm 644 "${f}" "${pkgdir}/usr/share/perl5/vendor_perl/ClamTk/$(basename "${f}")"
  25   done
  26
  27   for f in po/*.mo ; do
  28     install -Dm 644 "${f}" "${pkgdir}/usr/share/locale/$(basename "${f}" .mo)/LC_MESSAGES/clamtk.mo"
  29   done
  30
  31   install -Dm 644 clamtk.1.gz -t "${pkgdir}/usr/share/man/man1"
  32   install -Dm 644 CHANGES DISCLAIMER README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  33   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  34
  35   install -Dm 644 images/clamtk.{xpm,png} -t "${pkgdir}/usr/share/pixmaps"
  36   install -Dm 644 clamtk.desktop -t "${pkgdir}/usr/share/applications"
  37 }
  38
  39 # vim: ts=2 sw=2 et: