coeurl/trunk/PKGBUILD

   1 # Maintainer: Leonidas Spyropoulos <artafinde@archlinux.org>
   2 # Contributor: David Runge <dvzrv@archlinux.org>
   3 # Contributor: Luca Weiss <luca (at) z3ntu (dot) xyz>
   4
   5 pkgname=coeurl
   6 pkgver=0.3.0
   7 pkgrel=2
   8 pkgdesc="A simple async wrapper around CURL for C++"
   9 arch=("x86_64")
  10 url="https://nheko.im/nheko-reborn/coeurl"
  11 license=('MIT')
  12 depends=(gcc-libs glibc)
  13 makedepends=(curl fmt libevent meson spdlog)
  14 provides=(libcoeurl.so)
  15 source=("https://nheko.im/nheko-reborn/coeurl/-/archive/v$pkgver/coeurl-v$pkgver.tar.gz")
  16 sha256sums=('48b07482364edcbed03e352f6b8b07e327c331eaa45707ad58e62930fa361382')
  17 b2sums=('44c990a978f5970afacadff858502db5efd6709f8e5dcf43eeecfabda7f93262258a8a9fd7b1b411b8e28156657e02e1ceb532f9675265fe9f8143f4b07d844f')
  18
  19 build() {
  20   arch-meson $pkgname-v$pkgver build
  21   meson compile -C build
  22 }
  23
  24 # Tests fail
  25 # - Needs cmake to properly detect doctest dependency https://github.com/doctest/doctest/issues/742
  26 # - Needs to enable them with `-D tests=true`
  27 # - Needs to execute ./scripts/run_testserver.sh and ./scripts/run_tls_testserver.sh prior to tests
  28 # check() {
  29 #   ninja test -C build
  30 # }
  31
  32 package() {
  33   depends+=(
  34     curl libcurl.so
  35     fmt libfmt.so
  36     libevent libevent_{core,pthreads}-2.1.so
  37     spdlog libspdlog.so
  38   )
  39
  40   meson install -C build --destdir "$pkgdir"
  41   install -vDm 644 $pkgname-v$pkgver/LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
  42 }
  43
  44 # vim:set ft=sh sw=2 sts=2 et: